sık kullanılanları yedekleme

[Yüksel Varlı]

Merhaba,
Bilgisayarı formatladığımız zaman Sık kullanılanlar listesi de siliniyor." Sık kullanılanlar"ı kaybetmemek için ne yapmalıyım.

 

[efeboral]

C:\Documents and Settings\sizin bilgisayariniz\Sık Kullanılanlar
burdaki dosyalari yedekleyin.

 

[Yüksel Varlı]

Teşekkürler efeboral,
Aslında iş bu kadar basit. Ama tembellik insanlara bazen buluşlar yaptırır.
Örneğin excelde bir dosya hazırlasam, yedekle düğmesine bassam, benim C:\Documents and Settings\sizin bilgisayariniz\Sık Kullanılanlar 'ı D:\ bölümüne sık kullanılanlar adıyla yedeklese... :wink:

 

[efeboral]

Evet excelde böyle bir program olsa gerçekten iyi olurdu.Belki forumdaki arkadaşlardan bir tanesi yapar bellimi olur.Ancak excel de değil ama bilgisayarındaki dosyaların yedeğini alan onlarca program var bence sen şimdilik onları kullan.

 

[Yüksel Varlı]

k::

 

[Haluk]

'************************************************************************
'*             Bilgisayardaki Favorites - Sık kullanilanlar klasörünü   *
'*             [D:\Favorites - GüncelTarih] olarak yedekleme işlemini   *
'*             yapan bir kod çalışmasıdır.                              *
'*                                                                      *
'*                        Burası Excel Vadisi ...                       *
'*                             Nisan 2006                               *
'*                              Haluk ®                                 *
'*                                                                      *
'************************************************************************
'
Private Type SHITEMID
    cb As Long
    abID As Byte
End Type

Private Type ITEMIDLIST
    mkid As SHITEMID
End Type

Private Declare Function SHGetSpecialFolderLocation Lib "shell32.dll" _
    (ByVal hwndOwner As Long, ByVal nFolder As Long, pidl As ITEMIDLIST) As Long
    
Private Declare Function SHGetPathFromIDList Lib "shell32.dll" Alias "SHGetPathFromIDListA" _
    (ByVal pidl As Long, ByVal pszPath As String) As Long

Const CSIDL_FAV = &H6
'
Private Function GetSpecialFolder(CSIDL As Long) As String
    Dim r As Long
    Dim Path$
    Dim IDL As ITEMIDLIST
    r = SHGetSpecialFolderLocation(100, CSIDL, IDL)
    If r = 0 Then
        Path$ = Space$(512)
        r = SHGetPathFromIDList(ByVal IDL.mkid.cb, ByVal Path$)
        GetSpecialFolder = Left$(Path$, InStr(Path$, Chr$(0)) - 1)
        Exit Function
    End If
    GetSpecialFolder = ""
End Function
'
 Sub DoBackUP()
    Dim FSO As Object
    Dim MyFavPath As String, BackUpFolder As String
    MyFavPath = GetSpecialFolder(CSIDL_FAV)
    BackUpFolder = "D:\Favorites - " & Date
    Set FSO = CreateObject("Scripting.FileSystemObject")
    If FSO.FolderExists(BackUpFolder) Then FSO.DeleteFolder BackUpFolder, True
    MkDir BackUpFolder
    FSO.CopyFolder MyFavPath, BackUpFolder
End Sub

 

[Yüksel Varlı]

Sevgili Haluk,
Mesajını ancak bugün görebildim. (Özür ) Bu konuda, yine senin yardımınla çözdüğüm "Dosya yedeklemek" adlı çalışmaya benzer bir çalışma yapmaya başlamıştım. Fakat her zamanki gibi Klasını konuşturup işi kökten halletmişsin.
Lütfen teşekkürlerimi kabul et. Saygılarımla