Sürekli bir şekilde girdiğim son 4 verinin ortalamasını alma

[amriwnl]

Merhaba, excel'de aynı satırda sürekli olarak gireceğim son 4 verinin (her hafta yeni veri gireceğim ve bu yüzden ortalama değişecek), ortalamasını nasıl alabilirim ?

 

[sward175]

Merhaba, amriwnl,
A1:A50 aralığındaki verilerin son 4 tanesinin ortalamasını almak için aşağıdaki formülü kullanabilirsiniz.
Kolay gelsin.

=ORTALAMA(KAYDIR(A1;KAÇINCI(9,99999999999999E+307;A1:A50)-1;;-4))

 

[amriwnl]

Merhaba tekrardan, öncelikle teşekkür ederim yanıt verdiğiniz için. Verdiğiniz formülü kendi tabloma uyarladığımda (A1:A50 kısmını B2'den V2'Ye olacak şekilde değiştirdim ve A1'i B2 olarak değiştirdim) '#YOK' diye bir hata alıyorum. Bazı haftalardaki veriler boş, girilmemiş (ki bazı haftalara veri girilmeyecek ve dolayısıyla boş veri kümesi olacak) bundan dolayı mıdır acaba hata ? Bundan kaynaklıysa çözüm olarak önerebileceğiniz bir şey var mıdır acaba ?

 

[sward175]

Merhaba , amriwnl,
Dosyanızın küçük bir örneğini eklerseniz yardın almanız kolaylaşacaktır.
İyi Günlere,
sward175

 

[amriwnl]

	1. hafta	2.hafta	3.hafta	4.hafta	5.hafta	6.hafta	7.hafta	8.hafta
MATEMATİK	85		85		95	86	90		ortalama

Veri aralıklarım B2:V2 arasında olacak şimdiden teşekkürler. belki de boş veri oluyor olması fonksiyonun doğru çalışmasına engel oluyordur. Mesela bu varyasyonda 1. haftayı işleme almadan 3. hafta 5. hafta 6. hafta ve 7.haftayı toplayıp 4e bölecek

 

[52779]

B2:V2 aralığı için W2 hücresine yazın.

Excel versiyonunuzda Excel2023 yazdığından hangi versiyonu kullandığınızı bilemedim. O nedenle

Excel 2010 ve üzeri versiyonlar için

=EĞERHATA(ORTALAMA(İNDİS(B2:V2;TOPLAMA(14;6;(SÜTUN($B$1:$V$1)-SÜTUN($B$1)+1)/(B2:V2<>"");MİN(BAĞ_DEĞ_SAY(B2:V2);4))):V2);"")

Excel2021 ve üzeri versiyonlar için

=LET(a;B2:V2;b;FİLTRE(a;a<>"");c;SÜTUNSAY(b);EĞERHATA(ORTALAMA(FİLTRE(b;c-SIRALI(;c)<4));""))

Excel 2024 ve Excel365 için

=EĞERHATA(ORTALAMA(AL(FİLTRE(B2:V2;B2:V2<>"");;-4));"")

Çalışması :
B2:V2 aralığında SAYI olarak verileriniz var. Aralarda boş hücreler de var. (Ama ""(BOŞ) haricinde Metin ifadeler yok)

• 4 veya daha fazla olduğunda, Son yazılan 4 adet değerin ortalaması hesaplanır.
• 4 den az sayısal verinin olması durumunda, kaç adet veri varsa onların ortalaması hesaplanır.
• Hiç bir sayısal veri yoksa ortalama olarak ""(BOŞ) yazılır.

İhtiyaç halinde, W2 hücresine yazılacak bu formül W kolonunda aşağıya doğru kopyalanır.

 

[amriwnl]

B2:V2 aralığı için W2 hücresine yazın.

Excel versiyonunuzda Excel2023 yazdığından hangi versiyonu kullandığınızı bilemedim. O nedenle

Excel 2010 ve üzeri versiyonlar için

=EĞERHATA(ORTALAMA(İNDİS(B2:V2;TOPLAMA(14;6;(SÜTUN($B$1:$V$1)-SÜTUN($B$1)+1)/(B2:V2<>"");MİN(BAĞ_DEĞ_SAY(B2:V2);4))):V2);"")

Excel2021 ve üzeri versiyonlar için

=LET(a;B2:V2;b;FİLTRE(a;a<>"");c;SÜTUNSAY(b);EĞERHATA(ORTALAMA(FİLTRE(b;c-SIRALI(;c)<4));""))

Excel 2024 ve Excel365 için

=EĞERHATA(ORTALAMA(AL(FİLTRE(B2:V2;B2:V2<>"");;-4));"")

Çalışması :
B2:V2 aralığında SAYI olarak verileriniz var. Aralarda boş hücreler de var. (Ama ""(BOŞ) haricinde Metin ifadeler yok)

• 4 veya daha fazla olduğunda, Son yazılan 4 adet değerin ortalaması hesaplanır.
• 4 den az sayısal verinin olması durumunda, kaç adet veri varsa onların ortalaması hesaplanır.
• Hiç bir sayısal veri yoksa ortalama olarak ""(BOŞ) yazılır.

İhtiyaç halinde, W2 hücresine yazılacak bu formül W kolonunda aşağıya doğru kopyalanır.

Size nasıl teşekkür ederim bilmiyorum gerçekten çok ama çok sağ olun. Son Attığınız formül işimi çözdü çok teşekkür ederim, iyi günler dilerim.

 

[52779]

Ben teşekkür ediyorum.
Yardımcı olabildiğime çok sevindim.