sütun eklemek hızlı yolu

[modoste]

merhaba sayın hocalarım
1 yıllık 365 sütun eklemek için hızlı bir yöntem var mı
şu an yaptığım;
ADR sütununu mouse ın sol tuşuna basılı halde sağa doğru 365 sütun çekip CTRL+1 yada sütun ekle işlemi yapmaktayım

daha kolay yolu yada kısayolu nasıl olur

 

[volki_112]

sütunu solu ve sağı dolu siz araya mı 365 sütun eklemek istiorsunuz.

 

[Biolightant]

Merhaba,

ADR sütununu mouse ın sol tuşuna basılı halde sağa doğru 365 sütun çekip

esas uğraştıran kısmı hızlandırmak için.
Ad Kutusuna (Seçtiğiniz hücrenin adresini yazan yer ) R1C1:R1C365 Enter tıklayın
E Sütunundan sonra ekliyecekseniz C lere 5 ve 4 ekleyin R1C5:R1C369

 

[modoste]

2 nolu mesaja cevabım
evet sağı solu dolu ben araya 365 sütun eklemek istiyorum

 

[Muzaffer Ali]

Alternatif.
Formül çubuğuna K:NK yazıp entere basarsanız 11. sütun dahil 365 sütun seçmiş olursunuz.
Sürekli aynı sütunlara ekliyorsanız bu yöntemi kullanabilirsiniz.

Diğer bir yöntem kod ile olabilir.
Aşağıdaki kod otomatik sütun ekler.
Dilerseniz kısayol ekleyerek kodu çalıştırabilirsiniz.

Sub test()
    Columns("K:NK").Insert Shift:=xlToRight
End Sub

 

[modoste]

anladığım kadarıyla mouse ile seçip sol tuşa basıp sürüklemekten başka yolu yok gibi

enranın sağındaki gibi 1048576R x 12 C, 1048576R x 365 C görene kadar parmaklar mouse sol tuşta çekmeye devam gibi

 

[volki_112]

@modoste istediğin şekilde 365 sütun ekleyecek kod. Kod hangi sayfa açık ise o sayfada işlem yapar. İstersen kodu bir butona atayabilirsin. Kodu çalıştırınca hangi sütundan başlayacağını sen seçeceksin. seçip tamam dedikten sonra 365 sütun ekler. Kod çalışıyor. Sizni ihtiyacınızı karşılıyor mu deneyip geri dönüş yaparsanız sevinirim.

Sub Add365Columns()

    Dim startColumn As Long
    Dim i As Long
    Dim columnLetter As String
   
    ' Kullanıcıdan sütun ismini alıyoruz (örneğin "Q")
    columnLetter = InputBox("Başlangıç sütununu girin (örneğin: Q):", "Başlangıç Sütunu")
   
    ' Eğer kullanıcı hiçbir şey girmezse, işlemi durduruyoruz
    If columnLetter = "" Then
        MsgBox "Geçerli bir sütun harfi girmeniz gerekiyor!"
        Exit Sub
    End If
   
    ' Sütun harfini sayısal değere dönüştürmek için
    startColumn = Range(columnLetter & "1").Column
   
    ' 365 sütun ekliyoruz
    For i = 1 To 365
        Columns(startColumn + i).Insert Shift:=xlToRight
    Next i

    MsgBox "365 sütun başarıyla eklendi!"
   
End Sub

 

[Biolightant]

sürüklemekten başka yolu yok gibi

R1C1:R1C365
ben mi yanlış anladım, benim yazdığımı denediniz mi ?

L Sütunundan itibaren R1C12:R1C376
seçimi yaptıktan sonra Sütun ekle tıklayınız

Sütun eklemek için ille de tüm Satırları seçmenize gerek varmı ?
Herhangi bir Satırda hücreleri seçmeniz yeterli diye biliyorum ben.

 

[volki_112]

R1C1:R1C365
ben mi yanlış anladım, benim yazdığımı denediniz mi ?

L Sütunundan itibaren R1C12:R1C377
seçimi yaptıktan sonra Sütun ekle tıklayınız

Sütun eklemek için ille de tüm Satırları seçmenize gerek varmı ?
Herhangi bir Satırda hücreleri seçmeniz yeterli diye biliyorum ben.

hocam dediğiniz şekilde yapınca seçim yapılıyor ama mouse sağ tikine basınca yapılan seçim kayboluyor. sadece tek sütun ekliyor.

 

[Biolightant]

mouse sağ tikine basınca yapılan seçim kayboluyor

Fare imleci Seçili kısmın üzerinde iken sağ tıklayıp denermisiniz.
veya CTRL+ veya Menüden Sütun ekle de olabilir.

 

[volki_112]

Fare imleci Seçili kısmın üzerinde iken sağ tıklayıp denermisiniz.

yine olmadı.

 

[Biolightant]

yine olmadı.

teşekkürler test ettiğin için.

 

[Muzaffer Ali]

Seçili olan hücreden itibaren 365 sütun ekler.

Sub Test()
    ActiveCell.Resize(1, 365).EntireColumn.Insert
End Sub

 

[Korhan Ayhan]

En pratik yöntem makro gibi görünüyor...

Aşağıdaki kod biraz daha esneklik sağlar.. (Geliştirilebilir..)

Option Explicit

Sub Insert_Column()
    Dim No As Variant
    
    No = Application.InputBox("Eklemek istediğiniz sütun sayısını giriniz!", "Sütun Sayısı", 365, Type:=1)
    
    If No = False Then MsgBox "İşleminiz iptal edilmiştir!", vbExclamation: Exit Sub
    If No <= 0 Then MsgBox "Lütfen sıfırdan büyük pozitif değer giriniz!", vbExclamation: Exit Sub
    
    On Error Resume Next
    ActiveCell.Resize(, No).EntireColumn.Insert
    If Err.Number <> 0 Then
        MsgBox "Bir hata oluştu!" & vbCrLf & vbCrLf & Err.Description, vbCritical
    End If
    On Error GoTo 0
End Sub

 

[modoste]

şu an için beni en çok yavaşlatan bu gibi şeyler;
mouse sol tuşuna basılı halde iken satır ayda sütun ilerleme, satır sütun ekleme
ileride bunlara kolaylık getirirler inşallah

 

[volki_112]

şu an için beni en çok yavaşlatan bu gibi şeyler;
mouse sol tuşuna basılı halde iken satır ayda sütun ilerleme, satır sütun ekleme
ileride bunlara kolaylık getirirler inşallah

Hocam yukarda kod verdik onu kullan bundan sonra. Kod eklemeyi excelde module e eklemeyi biliyor musun

 

[Biolightant]

Makro ile çözüm isrenirse
Sütun Ekle veya Satır Ekle VBA kodları.

SutunSatirEkle.xlsm

Sub SutunEkle()
    Dim SutunBasla As Range
    Dim KacSutun As Long
   
    On Error Resume Next
        Set SutunBasla = Application.InputBox( _
        Title:="SÜTUN BAŞLANGIÇ hücresi", _
        Default:=ActiveCell.Address, _
        Prompt:="Eklemek istediğiniz SÜTUN BAŞLANGIÇ hücresini seçiniz." & vbCrLf & vbCrLf & _
        "1 (Bir) adet hücre seçiniz" & vbCrLf & vbCrLf & _
        "İstediğiniz satırda olabilir." & vbCrLf & vbCrLf, _
        Type:=8)
    On Error GoTo 0
   
    If SutunBasla Is Nothing Then Exit Sub
   
    Set SutunBasla = Range(Split(SutunBasla.Address, ",")(0))
   
    KacSutun = Application.InputBox(Prompt:="Kaç ADET Sütun Eklenecek ?", Type:=1, Title:="KAÇ ADET SÜTUN", Default:=1)
    If KacSutun <> False And KacSutun <> 0 Then
        SutunBasla.Resize(1, KacSutun).EntireColumn.Insert
    End If
End Sub

Sub SatirEkle()
    Dim SatirBasla As Range
    Dim KacSatir As Long
   
    On Error Resume Next
        Set SatirBasla = Application.InputBox( _
        Title:="SATIR BAŞLANGIÇ hücresi", _
        Default:=ActiveCell.Address, _
        Prompt:="Eklemek istediğiniz SATIR BAŞLANGIÇ hücresini seçiniz." & vbCrLf & vbCrLf & _
        "1 (Bir) adet hücre seçiniz" & vbCrLf & vbCrLf & _
        "İstediğiniz Sütunda olabilir." & vbCrLf & vbCrLf, _
        Type:=8)
    On Error GoTo 0
   
    If SatirBasla Is Nothing Then Exit Sub

    Set SatirBasla = Range(Split(SatirBasla.Address, ",")(0))
   
    KacSatir = Application.InputBox(Prompt:="Kaç ADET Satır Eklenecek ?", Type:=1, Title:="KAÇ ADET SATIR", Default:=1)
    If KacSatir <> False And KacSatir <> 0 Then
        SatirBasla.Resize(KacSatir, 1).EntireRow.Insert
    End If
End Sub

 

[Biolightant]

Makrosuz bir yöntemle hızlı bir şekilde yapmak isterseniz.

@modoste Örnek olarak gösterdiğim yöntemi test edip, geri dönüş yapabilirmisiniz ?



R1C3:R1C12 yerine

R değerlerini değiştirseniz de aynı sonucu alırsınız

Örnek01: R2C3:R2C12
Örnek02: R1C3:R1048576C12 (Sütunun Tüm Satırlarını seçer)

hepsinde aynı sonucu alacaksınız.

 

[modoste]

sayın volki_112 ancak şimdi bakabildik malum yılsonu hesapları derken şimdi maili farkettim
hocam makrolu çözüm gerekmiyo, çünkü az önce kullanmadığım başka bir dosyayı açtım ve ordada lazım oldu aniden 120 sütunluk ekleme yapmam gerekti, makrolu çözümü arşivlerime aldım teşekkür ederim
sayın Biolightant hocam, sizin dediğiniz yöntemi deneyecem hocam anladım mantığını en kısa zamanda deneyecem
çok teşekkürler

 

[modoste]

sayın Biolightant hocam
şimdi deneme yaptım hocam bunu kullanıcam