Soru Tarih Hesabını 360 Olarak aldırma

[dengeceteris]

Herkese merhabalar; emeklilik hesabın da bir tarih fonksiyonu yazmaya çalışırken sonuç ile ilgili bir sıkıntı yaşıyorum. Bunu aşabilmek için yardımınıza ihtiyacım olacak.

Mesela A1 hücresine bir rakam giriyorum bu 4.000 gün olsun. Bunu Yıl-Ay-Gün ifade ederken 10 Yıl 11 Ay 12 Gün çıkıyor bunun için aşağıda ki formülü kullanıyorum. Ama her bir yılı 360 gün olarak her bir ay'ı ise 30 gün kabul etmek durumundayım. Bu durum da Bu formülü nasıl revize edebilirim. Yani amacım: 11 Yıl 1 Ay 10 Gün'e nasıl ulaşabilirim.

Yardımlarınız için tşk ederim.

=ETARİHLİ(1;A1;"y")&" "&"YIL"&" "&ETARİHLİ(1;A1;"ym")&" "&"AY"&" "&ETARİHLİ(1;A1;"md")&" "&"GÜN"

 

[muygun]

Merhaba;
A1 hücresine 4000 yazın.
B1 hücresine;
=TAMSAYI(A1/360)& " YIL " &TAMSAYI((A1-(TAMSAYI(A1/360)*360))/30)& " AY " & A1-((TAMSAYI(A1/360)*360)+(TAMSAYI((A1-(TAMSAYI(A1/360)*360))/30)*30)) & " GÜN"

Formülünü uygulayarak deneyin.
İyi çalışmalar.

 

[52779]

Selamlar,
Alternatif olarak

=EĞERHATA(KIRP(EĞER(TAMSAYI(A1/360)=0;"";TAMSAYI(A1/360)&" YIL ")&EĞER(TAMSAYI((A1-TAMSAYI(A1/360)*360)/30)=0;"";TAMSAYI((A1-TAMSAYI(A1/360)*360)/30)&" AY ")&EĞER(MOD(A1;30)=0;"";MOD(A1;30)&" GÜN"));"")

A1 : 3990 ise sonuç : 11 YIL 1 AY
A1 : 3982 ise sonuç : 11 YIL 22 GÜN
A1 : 4000 ise sonuç : 11 YIL 1 AY 10 GÜN

 

[dengeceteris]

Sevgili Uzman arkadaşlarım her ikinize de ayrı ayrı tşk ederim. Formüller tam istediğim gibi çalıştı. Yalnız mümkünse buradan bağlantılı bir soru daha sormak istiyorum. Mesela ben yine A1 hücresine 4.000 gibi bir tam sayı yazdım A2 hücresine de 500 yazdığım zaman bunları da toplatarak sonuca problemsiz ulaştım. Peki A1 Hücresin de bir tarih olsa 01.01.2001 gibi A2 hücresinde ise bir tam sayı olsa yine örnekte ki gibi 4.000 buradan gene yılı 360 ve ay'ı 30 gün saydırarak sonucu örneğin 05.02. 2012 gibi yazdırmak olası dahilinde mi ?

 

[52779]

Selamlar,
A1 : 01.01.2001
A2 : 4000
(4000 için yıl = 360 a göre 11 yıl 1 ay 10 gün)

=EĞERHATA(TARİH(YIL(A1)+TAMSAYI(A2/360);AY(A1)+TAMSAYI((A2-TAMSAYI(A2/360)*360)/30);GÜN(A1)+MOD(A2;30));"")

Sonuç : 11.02.2012 (05.02.2012 yazmışsınız ama sonuç 11.02.2012 olmalı)

 

[52779]

Üstteki mesajda verilen formülde şöyle bir hata var.
A1 de yazılan tarihin günü ile A2 de verilen gün adedinin Gün kısmını topladığımızda 30 dan büyük çıkma durumunda,bir sonraki ayın 30 , 31 ,28 ya da 28 gün olması durumuna göre değişkenlik gösterebilir.

o nedenle formülde revize edilerek, gün toplamı değerlendirmeye alındı.

=TARİH(YIL(A1)+TAMSAYI(A2/360);AY(A1)+TAMSAYI((A2-TAMSAYI(A2/360)*360)/30)+TAMSAYI((GÜN(A1)+MOD(A2;30))/30);MOD(GÜN(A1)+MOD(A2;30);30))

Deneyiniz.....

 

[dengeceteris]

Hocam tamamdır çok tşk ederim, çok sağolun