tarih ve metin içeren hücreleri sayma

[hsynygn]

01.01.2021 var

24.01.2021 var

01.02.2021 var

03.02.2021 var

03.02.2021 var

09.02.2020 var

09.02.2020 var

10.02.2020 var

23.02.2020 var

01.03.2022 var

09.03.2022 var

23.03.2022 var

09.05.2022 var

A sutununda bu veriler var. her hücrede tarih ve var yazısı bulunuyor. örneğin 2021 yılına ait var yazan kaç tane hücre olduğunu saydırmak istiyorum( sadece yıla göre). yardımcı olursanız sevinirim.

 

[Haluk]

Veriler A2:A14 aralığındaysa;

-İngilizce Excel için:

=SUMPRODUCT((YEAR(DATEVALUE(LEFT(A2:A14;10)))=2021)*(RIGHT(A2:A14;3)="var"))

-Türkçe Excel için:

=TOPLA.ÇARPIM((YIL(TARİHSAYISI(SOLDAN(A2:A14;10)))=2021)*(SAĞDAN(A2:A14;3)="var"))

.

 

[hsynygn]

Veriler A2:A14 aralığındaysa;

-İngilizce Excel için:

=SUMPRODUCT((YEAR(DATEVALUE(LEFT(A2:A14;10)))=2021)*(RIGHT(A2:A14;3)="var"))

-Türkçe Excel için:

=TOPLA.ÇARPIM((YIL(TARİHSAYISI(SOLDAN(A2:A14;10)))=2021)*(SAĞDAN(A2:A14;3)="var"))

.

Üstat elinize sağlık, teşekkür ederim. Formül sutunda boş satırlar olduğu zaman hata veriyor. Hatayı almamak için ne yapabilirim ?

 

[YUSUF44]

Yerinizde olsam metni sütunlara dönüştürür ve tarihi ayrı metni ayrı sütuna alırdım. Böylece daha kolay çözümler bulunabilir.

 

[hsynygn]

Yerinizde olsam metni sütunlara dönüştürür ve tarihi ayrı metni ayrı sütuna alırdım. Böylece daha kolay çözümler bulunabilir.

onu düşündüm ama bütün kayıtlar karışır. tarihlerin yanında 4-5 çeşit bilgi var. birbirinden çok farklı bilgiler. eğer karışırsa büyük kriz olur.

 

[YUSUF44]

Nasıl bir karışıklık olabileceğini anlayamıyorum, sonuçta çalışmanızı siz daha iyi bilirsiniz. O zaman o sütun aynı kalsın ama içindeki veriyi başka sütunlarda göstermeyi deneyin. Yani A sütununda tarih ve metin birlikte, B sütununda tarih C sütununda metin olarak kullanabilirsiniz.

 

[Haluk]

İngilizce Excel için; (Dizi formülüdür .... Ctrl+Shift+Enter)

=SUMPRODUCT(IF(A2:A14<>"";(YEAR(DATEVALUE(LEFT(A2:A14;10)))=2021)*(RIGHT(A2:A14;3)="var");0))

.

 

[Korhan Ayhan]

Alternatifler;

=COUNTIF(A:A;"*2021 var*")

=COUNTIFS(A:A;"*2021*";A:A;"*var*")

=SUMPRODUCT((YEAR(RIGHT(LEFT(0&A1:A1000;11);10))=2021)*(RIGHT(A1:A1000;3)="var"))

 

[Haluk]

Basit düşünmek her zaman iyidir.... Korhan Beyin cevabı mükemmel olmuş.

.

 

[hsynygn]

ilgilenen, yardımcı olan arkadaşlara teşekkür ederim. Emeğinize sağlık.