TEXTBOX çoklu görev

[sirkülasyon]

Sayfa2' nin
C3 sütunundan itibaren T.C kimlik numarası (Textbox2)
D3 sütunundan itibaren Adı Soyadı (Textbox3)
E3 sütunundan itibaren GSM numarası (Textbox4)
F3 sütunundan itibaren IBAN numarası (Textbox5)
G3 sütunundan itibaren İl Adı (Textbox6)
H3 sütunundan itibaren İlçe Adı verileri mevcut (Textbox7)

form üzerinde Textbox2' ye T.C kimlik numarası girilince Sayfa2' nin C sütununa bakacak Aynı T.C mevcut ise textboxları pasif edecek "12345678911 T.C kimlik numarası mevcut. Bilgileri getireyim mi? " uyarısı gelecek. EVET ise bilgileri textboxlara getirecek. Eğer Sayfa2' nin C sütununda T.C mevcut değil ise ya da çıkan uyarıya hayır denilirse textboxları aktif edecek textboxlara veri girişine müsaade edecek.

Böyle bir kriteri sağlayacak kod için yardımcı olabilir misiniz?

 

[Ömer]

Merhaba,

Pasif olmasını ne için kullanacaksınız anlayamadım. Sonuçta evet denirse veri geliyor, hayır denirse gelmiyor yani aktif oluyor. O yüzden pasifi eklemedim? İsterseniz eklenebilir fakat pasif olması işinize yaramaz diye düşünüyorum.

Private Sub TextBox2_Change()

    Dim S1 As Worksheet, c As Range, i As Byte, sor As String
   
    Set S1 = Sheets("Sayfa2")
   
    If TextBox2 = "" Then Exit Sub
       
    Set c = S1.[C:C].Find(TextBox2, , xlValues, xlWhole)
    If Not c Is Nothing Then
        sor = MsgBox(TextBox2 & " T.C kimlik numarası mevcut. Bilgileri getireyim mi? ", vbYesNo, "Sorgu")
        If sor = vbYes Then
            For i = 3 To 7
                Controls("TextBox" & i) = S1.Cells(c.Row, i + 1)
            Next i
        End If
    End If
   
End Sub

 

[veyselemre]

Private Sub TextBox2_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    Set s2 = Sheets("Sayfa2")
    son = s2.Cells(Rows.Count, 3).End(3).Row
    Data = s2.Range("C3:H" & son).Value
    For i = LBound(Data) To UBound(Data)
        If Data(i, 1) = TextBox2.Text Then
            If vbYes = MsgBox("Daha önce kayıtlı olan TC ye ait bilgileri getirmek " & vbCr & _
                              "İstiyor musunuz?", vbYesNo, "TC Bulundu..") Then
                For ii = 3 To 7
                    With Me.Controls("TextBox" & ii)
                        .Text = Data(i, ii - 1)
                        .Enabled = False
                    End With
                Next ii
                bulundu = True
                Exit For
            End If
        End If
    Next i
    If bulundu = False Then
        For ii = 3 To 7
            With Me.Controls("TextBox" & ii)
                .Text = ""
                .Enabled = True
            End With
        Next ii
    End If
End Sub

 

[sirkülasyon]

Ömer Abime, Veysel Abime
Yardımlarını esirgemediği için çok teşekkür ederim.