Toggle Button ile koşullu satır gizleme ve gösterme

[Believing]

Sayın Formdaş ARkadaşlar,

Tüm formdaş arkadaşların Kurban bayramını kutlar, hayırlara vesile olarak bayramların tekrarlarını yaşamayı cümlemize nasip etmesini dilerim.
Ekteki örnek çalışmanı "A" sütununa formül ile 1 veya 0 değerlerini yazdırıyorum. "A" sütunu değerlerini koşul olarak alarak sayfada bulunan Toggle Button yardımı ile satır gizlemek ve göstermek istiyorum.
"A" sütunu her daim gizli kalacaktır.
Toggle button ile "A" sütununda "1" rakamı içerenleri gösterecek "A6:"100" aralığında "1" rakamına eşit olamaya ile boş satırlar gizlenecek.
Toggle button tekrar basıldığında "A" sütununda "0" sıfır rakamı içerenleri gösterecek "A6:"100" aralığında "0" rakamına eşit olamayanlar ile boş satırlar gizlenecek.
Bu koşuları sağlayacak nasıl kod kullanmalıyım?
Değerli yardımlarınızı rica ediyorum.

Saygılarımla,

 

[Ömer]

Merhaba,

Deneyiniz.

Private Sub ToggleButton1_Click()

    Dim i As Integer, c As Range
    
    Application.ScreenUpdating = False
    Range("A6:A100").EntireRow.Hidden = False
    
    With ToggleButton1
        If .Value Then
            For i = 6 To 100
                If Cells(i, "A") <> 1 Or Cells(i, "A") = "" Then
                    If c Is Nothing Then
                        Set c = Rows(i)
                    Else
                        Set c = Application.Union(c, Rows(i))
                    End If
                End If
            Next i
            c.EntireRow.Hidden = True
            .Caption = "Sıfır Göster"
        Else
            For i = 6 To 100
                If Cells(i, "A") <> 0 Or Cells(i, "A") = "" Then
                    If c Is Nothing Then
                        Set c = Rows(i)
                    Else
                        Set c = Application.Union(c, Rows(i))
                    End If
                End If
            Next i
            c.EntireRow.Hidden = True
            .Caption = "Bir Göster"
        End If
    End With
    Application.ScreenUpdating = True
    
End Sub

 

[Believing]

Ömer bey merhaba,

Ellerinize ve emeğinize sağlık. Çok teşekkür ederim.
ALLAH sizden ve sevdiklerinizden şu mübarek günde razı olsun.

Saygılarımla,