topla.çarpım gibi liste filtrelemek, hangi fonksiyonun özelliği ?

ermanusta

Altın Üye
Katılım
18 Nisan 2008
Mesajlar
304
Excel Vers. ve Dili
excel 365
Office 365
topla.çarpım fonksiyonundaki gibi
TOPLA.ÇARPIM((F.Tarihi>=G79)*(F.Tarihi<G80)*(Ürün=$P$1);(Adet))
belirli tarihler arasında üründen kaç adet olduğunu gösteren bu formül gibi

Belirli tarihler arasında üründeki adet stünunu değilde açıklama stünundaki metini nasıl alabilirim. ve bunu alt alta sıralı şekilde getirmeliyim. bu hangi fonksiyonun özelliği
 

YUSUF44

Destek Ekibi
Destek Ekibi
Katılım
4 Ocak 2006
Mesajlar
12,084
Excel Vers. ve Dili
İş : Ofis 365 - Türkçe
Ev: Ofis 365 - Türkçe
Bildiğim kadarıyla TOPLA.ÇARPIM formülü toplama ve çarpma yaptığı için metinlerde bu işlemleri yapamıyor ve hata veriyor. Bu nedenle işlem sonucunun sayısal olması gerekiyor. Siz ise sonuçta metin almak istiyorsunuz. Bunun TOPLA.ÇARPIM formülüyle mümkün olduğunu sanmıyorum.

Örnek bir dosya paylaşırsanız farklı çözümler üretilebilir.
 

Korhan Ayhan

Administrator
Yönetici
Admin
Katılım
15 Mart 2005
Mesajlar
41,325
Excel Vers. ve Dili
Microsoft 365 Tr-En 64 Bit
Bu işlemler için arama fonksiyonlarını kullanabilirsiniz.

Tarih aralığına göre işlem yapılacaksa eski sürüm excel versiyonları için İNDİS+KÜÇÜK+EĞER kombinasyonu işinize yarayabilir.

Ofis 365 sürümü içinse FİLTRE fonksiyonu ile çözüme gidilebilir.
 

ermanusta

Altın Üye
Katılım
18 Nisan 2008
Mesajlar
304
Excel Vers. ve Dili
excel 365
Office 365
Şu an dosya yükleyemiyorum telefondan yazdigım icin ama basit bir mantigi var
Bir tablom var 5 sutünlü ana tablo
Başka bir tablo oluşturarak bu ana tabloda filtre süzme işlemiyle manuel olarak yaptığım
1.sütundaki Tarih aralığında
2.sütundaki kategorilerden bir seçimi (ki bu seçimi ikinci tablo sayfasında başka bir hücrede manuel olarak yazacağım ) filtre ederek
3.sütundaki bilgileri aktarmak istiyorum

Ilerde belki 4. Ve 5. Sütunlardaki bilgileri de süzmek/filtrelemek istiyorum.

Bu ana tabloda anlattığım mantıkla topla.carpimla rakamlari alabiliyorum ama metinleri alamiyorum.

Indis komutunu hiç kullanmadım ve küçük, eğeri (eğeri biliyorum) aynı formülde kullanma mantığını anlayamadım. kısaca mantığını söyleyebilir misiniz ?
 

Korhan Ayhan

Administrator
Yönetici
Admin
Katılım
15 Mart 2005
Mesajlar
41,325
Excel Vers. ve Dili
Microsoft 365 Tr-En 64 Bit
Kısaca koşula uyan satırları filtrelemeye yarıyor.

DİZİ formüldür. Söz dizimi aşağıdaki gibidir.

C++:
=EĞERHATA(İNDİS(Tablo_Aralığı;KÜÇÜK(EĞER(Koşul_Alanı=Koşul;SATIR(Koşul_Alanı));SATIR(A1));Sütun_İndis_Sayısı);"")
Formül koşula uyan verilerin listelenmesi bittiğinde hata değeri döndürecektir. Bu sebeple EĞERHATA ile sonucun boş olması sağlanıyor.

Forumda İNDİS+KÜÇÜK+EĞER ifadesi ile arama yaparsanız bolca örneğe ulaşabilirsiniz.

Daha yeni cevapladığım benzer bir soru aşağıdadır.

 

Ali

Uzman
Katılım
21 Temmuz 2005
Mesajlar
7,893
Excel Vers. ve Dili
İş:Excel 2016-Türkçe
237374

F1 ve F2 de tarihler, G1 de kriter var. İki tarih ve kritere göre listelenecek ise

H2 deki formülü yazıp aşağı doğru çekiniz.

Kod:
=EĞERHATA(İNDİS($C$2:$C$20;TOPLAMA(15;6;(SATIR($A$2:$A$20)-SATIR($A$2)+1)/(($B$2:$B$20=$G$1)*(($A$2:$A$20>=$F$1))*(($A$2:$A$20<=$F$2)));SATIRSAY($A$1:$A1)));"")
 

ermanusta

Altın Üye
Katılım
18 Nisan 2008
Mesajlar
304
Excel Vers. ve Dili
excel 365
Office 365
Ekli dosyayı görüntüle 237374

F1 ve F2 de tarihler, G1 de kriter var. İki tarih ve kritere göre listelenecek ise

H2 deki formülü yazıp aşağı doğru çekiniz.

Kod:
=EĞERHATA(İNDİS($C$2:$C$20;TOPLAMA(15;6;(SATIR($A$2:$A$20)-SATIR($A$2)+1)/(($B$2:$B$20=$G$1)*(($A$2:$A$20>=$F$1))*(($A$2:$A$20<=$F$2)));SATIRSAY($A$1:$A1)));"")
bu örnek çok faydalı oldu, en kısa zamanda deneyeceğim. çok teşekkür ederim.
 

ermanusta

Altın Üye
Katılım
18 Nisan 2008
Mesajlar
304
Excel Vers. ve Dili
excel 365
Office 365
Ekli dosyayı görüntüle 237374

F1 ve F2 de tarihler, G1 de kriter var. İki tarih ve kritere göre listelenecek ise

H2 deki formülü yazıp aşağı doğru çekiniz.

Kod:
=EĞERHATA(İNDİS($C$2:$C$20;TOPLAMA(15;6;(SATIR($A$2:$A$20)-SATIR($A$2)+1)/(($B$2:$B$20=$G$1)*(($A$2:$A$20>=$F$1))*(($A$2:$A$20<=$F$2)));SATIRSAY($A$1:$A1)));"")
Teşekkür ederim, istediğim gibi olmuş. Fakat işlemi yapınca şunu farkettim ki LİSTE'de çıkan bilgilerin benzersiz olması gerekiyor. yani Test-4 ten 2 tane varken sadece 1 tane sonuç getirebilirmiyiz. yoksa manuel olarak "yinelenenleri kaldır" mı yapmalıyım
 

Ali

Uzman
Katılım
21 Temmuz 2005
Mesajlar
7,893
Excel Vers. ve Dili
İş:Excel 2016-Türkçe
Liste aşağıdaki gibi olsun.

237576



Bu tarihler arası Beyazı süzüldüğünde benzersiz listede Test 1, Test3 ve Test 14 olması lazım


237575

Bu durumda

I3 hücresine

Kod:
=TOPLA(EĞER(SIKLIK(EĞER($C$2:$C$25<>"";EĞER($A$2:$A$25>=F1;EĞER($A$2:$A$25<=$F2;EĞER($B$2:$B$25=$G1;KAÇINCI("~"&$C$2:$C$25;$C$2:$C$25&"";0)))));SATIR($C$2:$C$25)-SATIR($C$2)+1);1))
yazıp CTRL+SHIFT+ENTER tuşuna basarak dizi formülü oluşturun.

H2 hücresine de

Kod:
=EĞER(SATIRSAY(H$2:H2)<=I$1;İNDİS($C$2:$C$40;KÜÇÜK(EĞER(SIKLIK(EĞER($A$2:$A$40>=$F$1;EĞER($A$2:$A$40<=$F$2;EĞER($B$2:$B$40=$G$1;KAÇINCI($C$2:$C$40;$C$2:$C$40;0))));SATIR($C$2:$C$40)-SATIR($C$2)+1);SATIR($C$2:$C$40)-SATIR($C$2)+1);SATIRSAY(H$2:H2)));"")
yazıp CTRL+SHIFT+ENTER tuşuna basarak dizi formülü oluşturup aşağı doğru çekiniz.
 
Üst