verileri hücreye otomatik kopyalama

[gkhn82]

Merhaba arkadaşlar.
Forumda yeniyim ve yardıma ihtiyacım var. İş yerinde kontrol amaçlı bir şablon hazırlıyorum. Beni hızlandıracak bir bir şeyler deniyorum ama aşağıdaki konu da takıldım fikir üretemiyorum. Aşağıdaki örnekte barkod sütunu altında (kt)kutular ve altında (ks)klasörler mevcut. her klasörün solunda ait olduğu kutunun ana barkodu yazılıyor. Amacım parent barcode sütunu altındaki barkodların otomatik gelmesi. Kutu barkodu değiştikçe oda değişecek ve bizim her seferinde acaba fazla sıfır varmı yada hatalı yazılmış mı diye kontrol etmemize gerek kalmayacak. klasör sayıları değişkendir.
=EĞER(A2="RW";C2;B1) şeklinde formül kullandığımda barkodların solunda da kopya oluşturduğundan istediğim şey olmuyor.
Forum kurallarını bilmediğimden hatam varsa affola. Herkese kolay gelsin.

Item Type.............Parent Barcode.................Barcode
KT.............................................................TKS0001
KS...........................TKS0001.....................R0001200
KS...........................TKS0001.....................R0001201
KS...........................TKS0001.....................R0001202
KS...........................TKS0001.....................R0001203
KT............................................................TKS0002
KS...........................TKS0002.....................R0001204
KS...........................TKS0002.....................R0001205
KS...........................TKS0002.....................R0001206
KS...........................TKS0002.....................R0001207
KT............................................................TKS0003
KS............................TKS0003....................R0001207
KS............................TKS0003....................R0001208
KS............................TKS0003....................R0001209
KS............................TKS0003....................R0001210
KS............................................................TKS0004
KS............................TKS0004....................R0001211
KS........................... TKS0004....................R0001212

 

[gkhn82]

merhaba arkadaşlar ,
önceki mesajımda derdimi anlatamadığımı düşünüyorum. Bu yüzden bir örnek excel ekliyorum. İstediğim şeyi özetlemeye çalışıyim.
Kutu içinde klasörler ve klasör içinde de dosyalar var. malzemelerin barkodlarını alt alta yazdığımda sol tarafında bağlı olduğu bir üstündeki malzemenin barkod numarası gelsin. ben ekte formül ile bir yere kadar getirdim. Yalnız düşey ara formülü kullandığımdan klasörlerin karşılığında her seferinde ilk kutunun numarasını getiriyor. Kutular ana malzeme olduğundan ana barkodu boş görünecek onu yapabildim. dosyalarda da sorun yok. Sadece klasörlerin ana malzeme barkodları hep ilk kutunun barkodu görünmektedir.
ilk sütündaki rakamlar mantıksal sorgulama da yardımcı olması açısından yazdım. Ks ve Ds tanımları değişmezken kutu isimleri farklı olabiliyor ekte belirttim. Yardımlarınızı rica ediyorum.

 

[gkhn82]

Arkadaşlar tekrar merhaba.

Konuyla ilgili önerisi olan yok mudur. Yardıma ihtiyacım var. Bir fikir alabilirsem en azından oradan ilerlemeye çalışıyim.

Herkese kolay gelsin.

 

[YUSUF44]

İsteğiniz bizim için biraz anlaşılmaz olmuş. Anlatımımınızı excel dosyası üzerinden ve excel verilerine göre (satır, sütun belirterek) yaparsanız anlamamıza yardımcı olursunuz. Tam olarak ne yaptığınızda tam olarak hangi hücre ya da hücrelerde nasıl bir değişiklik olmasını istiyorsunuz? Bu değişikliğin kuralı nedir?

 

[gkhn82]

verileri otomatik doldurma

Yusuf Bey merhaba ,

Dönüşünüz için teşekkürler. Ekte açıklamaya çalıştım. Umarım anlaşılır olmuştur.

iyi akşamlar.

 

[sakman26]

selamlar,
dosyanızdan anladığım kadarıyla
item type olarak KT (Kutu) , RHK (Başka tip Kutu) , KS (Klasör) ve DS (Dosya) kısaltmaları kullanılıyor.
Buna göre, C2 hücresine

=EĞER(YADA($B2="";$B2="KT";$B2="RHK");"";EĞER($B2="DS";ARA(2;1/(SOLDAN($D$1:D1;1)="R");$D$1:D1);EĞER($B2="KS";ARA(2;1/(SOLDAN($D$1:D1;3)="TKS");$D$1:D1);"")))

formülünü yazıp aşağıya doğru kopyalayın. Deneyin...

Formüle göre , item type de bir şey yazmıyorsa, ya da item type olarak KT veya RHK yazıyorsa BOŞ değerini verecektir. Ayrıca item type olarak KT, RHK, DS ve KS haricinde bir şey yazıyorsa da BOŞ değerini verecektir.

 

[gkhn82]

verileri otomatik doldurma

sakman26 hocam merhaba ,

teşekkür ederim emeğiniz için formül çalışıyor. Yalnız benim konuyu eksik anlatmamdan dolayı sizi yanlış yönlendirmiş oldum.

Müşterilerin barkodları değişken. Her müşterinin farklı. hane sayısı da değişebiliyor. Genelde 12 haneli barkod kullanıyoruz ama müşterinin kendi barkodunu da kullanabiliyoruz.

Kutu barkodları KT,RHK vb. olabilir.
kesin olan klasör "KS" , dosya "DS" dir.

Benim kafamdaki sorgu şöyleydi.

B2 hücresi ks ve ds dışında bir şey varsa boş görünsün. ks yazıyorsa ait olduğu bir üst malzeme "kutu barkodu" , ds yazıyorsa ait olduğu bir üst malzeme "klasör barkodu " gelsin C2 hücresine.

Yazdığınız formülde benim için çok faydalı olacak. Bu şekilde bakabilirseniz çok sevinirim.

Teşekkürler.

 

[sakman26]

selam,
KS ve DS dışındakilerde BOŞ görünsün derseniz
formülün başlangıcındaki
=EĞER(YADA($B2="";$B2="KT";$B2="RHK");""; kısmını

=EĞER(YADA($B2="";$B2<>"KS";$B2<>"DS");""; şeklinde düzenleyin...

 

[gkhn82]

verileri otomatik doldurma

Sakman26 hocam tekrar merhaba.

Formülü değiştirdim ama hücreler boş olarak geldi bir yerde yanlış mı yaptım anlayamadım.

Yalnız formülün devamında kelimeler içinden karakterleri arıyor anladığım kadarıyla.Yalnız barkodlar değişebiliyor. TKS ile başlayan barkod başka müşteride PLS ile başlar. Bu durumda hücreler boş görünecektir.

Ben sizin formülde gösterdiğiniz ara komutuyla bir yere kadar sonuç aldım ama
bir yerde yok hatası veriyor formül. Yöntem uzun ya da yanlış olabilir.
sizden ricam vaktiniz varsa kontrol edebilir misiniz.

 

[sakman26]

selam,
dosyanızdan hareketle, formülü A kolonundaki değerlere göre oluşturacaksanız eğer,
C2 hücresi için , formülü

=EĞER(A2=1;"";EĞERHATA(ARA(2;1/($A$1:A1=A2-1);$D$1:D1);""))

şeklinde yazabilirsiniz...

Not : kullandığınız ARA fonksiyonu ile, önerilen formüllerdeki ARA fonksiyonları arasındaki farka dikkat ediniz..Önerilen ARA fonksiyonlarının kullanım amacı , en son değerin getirilmesine yöneliktir.

 

[gkhn82]

verileri otomatik doldurma

Sakman26 hocam ,

Son verdiğiniz formül istediğim gibi çalışıyor.Çok teşekkür ederim. Ben eğer kullanarak bir şey yapmaya çalıştım hem uzun oldu hemde eksik kaldı. Bu formül çok kısa ve şık olmuş ama pek bir şey anlayamadım.
Formülünüzün çalışma mantığını kısaca özetleyebilir misiniz. Çok sağolun.

 

[sakman26]

selam,
dosyanızdan örnek vererek anlatmaya çalışacağım.
örnek dosyayı (açıklamalarla) hazırlayınca eklerim..

 

[gkhn82]

verileri otomatik doldurma

teşekkürler iyi akşamlar.

 

[sakman26]

selam,

Formülün Açıklaması :
Öncelikle ARA fonksiyonundan bahsetmek gerekir. ARA fonksiyonu DİZİ formül mantığında çalışır.
ARA fonksiyonunun söz dizimi ARA(aranan değer ; aranan vektör ;sonuç vektörü) şeklindedir.

Örnek olarak C13 hücresindeki formülü ele alalım....

=EĞER(A13=1;"";EĞERHATA(ARA(2;1/($A$1:A12=A13-1);$D$112);""))

Burada ; A kolonundaki değerlere baktığımızda DS : 3 ve KS : 2 olmaktadır. Bunun haricindekiler ise 1 değerini alıyor.
1 - EĞER(A13=1;""; ile A13 te 1 değeri varsa BOŞ bırakacak. ( Bunu zaten siz yazmıştınız)
2 - B 13 de DS yazdığında (ki A kolonunda bunun karşılığı DS : 3 ) D kolonunda , 13. den bir önceki satıra kadar yani, D1 : D12 aralığında en son KS (ki A kolonunda KS nin karşılığı KS : 2 ) ye karşılık gelen değeri arayacağız. (Örnekte 12. satırda ( B12 hücresinde ) KS var. Bunun D kolonundaki karşılık değeri ise (D12 hücresinde) R0001202 dir)
Aynı mantıkla B13 de KS yazıyorsa da D kolonunda D1 : D12 aralığında en son TKS gibi ( ki TKS , RHK ... lerin , A kolonundaki karşılığı ise 1 olmakta) değerleri arayacağız....
Bunun kısaca anlamını şöyle kurabiliriz. A kolonunda kaç yazıyorsa , yazanın 1 eksiğini arattıracağız... Yani DS : 3 için en son 2 yi , KS : 2 için ise en son 1 arattıracağız... Bu ARA formülü içerisindeki A13-1 olmaktadır.
3 - Açıklaması en zor kısım ARA fonksiyonu....

Aranan vektörden başlayalım.
a - ($A$1:A12=A13-1) ile , ARA fonksiyonu ile A13 te yazan değer = 3 bunun bir eksiği A13-1 : 3 - 1 = 2 yani A1:A12 aralığında 2 ye eşit olanlara bakılacak. ARA fonksiyonu DOĞRU , YANLIŞ şeklinde değer üretir. Bunların da matematiksel olarak karşılığı DOĞRU = 1 , YANLIŞ = 0... şimdi değerlere bakalım... (DOĞRU için D , YANLIŞ için Y yazıyorum)
A1 ≠ 2 (Y) , A2 ≠ 2 (Y) , A3 = 2 (D) , A4 ≠ 2 (Y) , A5 ≠ 2 (Y) , A6 ≠ 2 (Y) , A7 ≠ 2 (Y) , A8 ≠ 2 (Y) , A9 ≠ 2 (Y) , A10 ≠ 2 (Y) , A11 = 2 (D) , A12 = 2 (D) ve sonuçta {Y;Y;D;Y;Y;Y;Y;Y;Y;Y;D;D} dizisi ve matematiksel olarak da {0;0;1;0;0;0;0;0;0;0;1;1} dizisi üretilecektir.
b - 1 / ($A$1:A12=A13-1) ile , ($A$1:A12=A13-1) için elde edilmiş olan {0;0;1;0;0;0;0;0;0;0;1;1} dizisi nin 1 bölü şeklindeki dizisi elde edilecek... 1 / 0 = #SAYI/0! hatası verecektir. (Bir sayının SIFIRA bölünmesi ∞ olduğundan ) Sonuç olarak elde edilecek dizi {#SAYI/0!;#SAYI/0!;1;#SAYI/0!;#SAYI/0!;#SAYI/0!;#SAYI/0!;#SAYI/0!;#SAYI/0!;#SAYI/0!;1;1} şeklinde olacaktır.

Aranan değere bakalım.
ARA(2;1/.... formülünde aranan değerimiz 2 dir...
Bu arada şunu da söylemek gerekir ki , ARA fonksiyonunda, aranan değeri aranan vektörde arattırırken HATA (#SAYI/0!) değerleri fonksiyon tarafından YOK sayılacaktır.
ARA(2 ; 1 / ($A$1:A12=A13-1 ifadesi ARA(2 ;1 /{#SAYI/0!;#SAYI/0!;1;#SAYI/0!;#SAYI/0!;#SAYI/0!;#SAYI/0!;#SAYI/0!;#SAYI/0!;#SAYI/0!;1;1} şeklinde olacaktır. Burada aranan değer olan 2 değerini arattırıyoruz.. Maalesef YOK. Bu durumda en son 1 e eşit olan ı bize sıra numarası olarak verecektir... (Örnekte 12. sırada en son 1 var)
Burada aranan değer olan 2 için bir şeyler söyleyecek olursak.... aranan vektörde ya #SAYI/0! ya da 1 vardır. 2 yerine 1 den büyük bir değer yazıldığında aynı sonuç üretilecektir. Önemli olan 1 den büyük bir sayıyı arattırmak... Genelde 2 kullanıldığından hep 2 yazılmaktadır.

Sonuç vektöründe sonuca bakalım...
ARA(2;1/($A$1:A12=A13-1);$D$112) de sonuç vektörü $D$112
{"Barcode"\"TKS0001"\"R0001200"\"DS000001900"\"DS000001901"\"DS000001902"\"DS000001903"\"DS000001904"\"DS000001905"\"DS000001906"\"R0001201"\"R0001202"} olmakta ve 12. sıradaki değer olan R0001202 değeri sonuç olarak gelmektedir...

EĞERHATA(ARA(.......);"") ile de örneğin A13 hücresinde bir şey yamıyorsa , ya da METİN ise ARA fonksiyonu #YOK hatası verecektir. Böyle bir durumda ise hücrede #YOK yazmasın ve BOŞ bıraksın istedik...

 

[gkhn82]

verileri otomatik doldurma

sakman26 hocam merhaba ,

Yoğunluktan sakin kafayla şimdi bakabildim. Konuyu anladım bir kaç benzer örnekle pekiştireceğim. Çok faydalı oldu benim açımdan. Diğer arkadaşlarında faydalanabileceği bir çözüm olduğuna inanıyorum. Üşenmeyip zaman ayırdığınız için çok teşekkür ederim. Emeğinize sağlık.

 

[sakman26]

rica ediyorum...
kolaylar gelsin..

 

[halil_ibo]

Merhaba,
Peki benim başka bir sorum olacak. sütunda bulunan sayıları yandaki sütuna metin olarak kuruşları dahil yazdırmak istiyorum. Ama sıkıntı şu ki; 2542,25 yazan hücreyi birleştir formülüyle
" ' " yazıyorum başına metin oluyor otomatik olarak ('2542,25). 5000 yazan hücre ise ('5000) oluyor. benim sorunum kuruşu ayıran (,)virgülü (.)nokta yapacağım Ctrl+F ile yapıyorum ama '5000 olan hücre yine aynı kalıyor (,)virgül olmadığı için. bunu nasıl çözebiliriz? Yardımcı olursanız memnun olurum.