Tarih yada sayı içeren sabit hücreye ek koşul koyma sorunu

canburak · 15 Haziran 2020

Korhan Ayhan' Alıntı:
Sanırım rapor sayfasının formatını değiştirmişsiniz. Satır eklemişsiniz.

Evet rapora 2 satir ekledim ama eski sekli ilede denedim hata veriyor

Korhan Ayhan · 15 Haziran 2020

#15 nolu mesajımdaki kodu revize ettim. Tekrar deneyiniz.

canburak · 15 Haziran 2020

Korhan Ayhan' Alıntı:
Sanırım rapor sayfasının formatını değiştirmişsiniz. Satır eklemişsiniz.

Evet Hocam rapora 3 satir ekledim, ama dosayanin eski sekli ile denedigimde de calismiyor

canburak · 15 Haziran 2020

canburak' Alıntı:
Evet Hocam rapora 3 satir ekledim, ama dosayanin eski sekli ile denedigimde de calismiyor

Evet Hocam Tamda istedigim gibi Olmus Elilinize yureginize saglik

Cok Tesekkur ederim

canburak · 9 Eylül 2020

Korhan Ayhan' Alıntı:
#15 nolu mesajımdaki kodu revize ettim. Tekrar deneyiniz.

Merhabalar Hocam , Nasilsiniz ? yine bir sorunum olustu mizan icin yaptiginiz , kodlari maliyet kar/zarar tablosuna uyarlamaya calistim ama birturlu beceremedim, acaba bir baka bilirmisiniz ornek dosyanin adresini assagida belirttim ilginiz icin cok tesekkur ederim.
Saygilar,

dosya adresi

Ornek kar zarar.xlsm

drive.google.com

Korhan Ayhan · 9 Eylül 2020

Ne nereye gelecek tarif eder misiniz?

canburak · 10 Eylül 2020

Korhan Ayhan' Alıntı:
Ne nereye gelecek tarif eder misiniz?

Simdi Hocam, FINAL sayfasi raporlama yeri olacak
buna istinaden;
1- Final sayfasindaki B sutunun daki GROUP un altina , Stokliste yasfasindaki D sutundaki bilgi gelecek
2- Final Sayfasindaki C sutununa (tarih) ,Stokliste sindeki C sutundakitarihler gelecek,
3-Final D sutununa (Shipment) , Stoklistesindeki V sutunundaki (LOT) Gelecek (Not Benzersiz olan yani mukerrer olmayacak)
4- Final E sutununa (Firma adi) , Stokliste deki F sutunundaki Bilgiler gelecek
5-Final F sutununa , Stoklistede H sutunundaki Mal ismi gelecek,
6-Final H sutununa , Stoklisteden J sutunundaki Satis miktarini getirmesi lazim assagidaki kosullara gore
Tabi bunlarin asil kosulu Eger Stokdaki G sutununda SATIS yaziyorsa Finaldeki de sutununa Stokdaki V sutunundaki Shipment yani LOT numaralarini getirecek ve diger leri icinde D sutununda SATIS ve V sutunun Shipment(LOT) numarasi olan Firma,mal gibi diger bilgileri usteki sekilde getirmesi lazim Stokliste;den
bundan sonraki islemler ,Liste yani para hareketinin oldugu veri sayfasindanolacak soyleki;
1- Final Sayfasindaki H Sutununa = Eger Final sayfasinda ki D sutunundaki (Shipment) = ise Liste sayfasindaki T sutununa ve Final sayfasindaki H1 hucresi Liste Sayfasindaki G sutununa esit ise ,Liste sayfasindaki N sutundaki toplami getir
2- Final Sayfasindaki "I" sutununa = Eger Final sayfasinda ki D sutunundaki (Shipment) = ise Liste sayfasindaki T sutununa ve Final sayfasindaki "I1" hucresi esitse ,Liste sayfasindaki H sutununa ve Final sayfasindaki H2 hucresi esitse Liste sayfasindaki G sutununa ,Liste sayfasindaki N sutunundaki rakamlarin toplamini getir
3- 2ci maddedekinin aynisi "I" sutunundan Q sutununa kadar her sutunustun kendi harfine ait 1 ci satirindaki hucrelere gore kosullandirilacak H2 hucresindeki kosul sabit kalacak cunku ortak isim, yada onuda ben 2 ci satira yazabilirm ugrastirirsa,
4- Final deki R Sutununa, Eger Final sayfasinda ki D sutunundaki (Shipment) esit ise Liste sayfasindaki T sutununa ve Final sayfasindaki R2 hucresi esit ise Liste sayfasindaki G sutununa Liste sayfasindaki N sutunun toplamini getirecek
5 - Son olarak , Final deki S sutununa H sutundan R sutununa kadarki rakamlari toplayip buraya yani S sutununa yazmasi lazim
umarim karistirmamisimdir yardimlariniz icin simdiden
Cok Tesekkurler

canburak · 11 Eylül 2020

Hocam ben bu sekilde birsey yapmistim, 2 ayri makro ile cunku 1 ci makroda hepsini cozemedim 1 ci makroda miktarlari hatali, onu getirmedim, 2 ci makroda hesaplamalari yaptirdim ama 3-5 dakka suruyor, tabi assagidaki makrolar gercek tabloma gore uyarli , Burda yazdigim ornek tablo Ornek olsun diye daha basitlestirip gondermistim belki size bu makrolar da bir fikir vere bilir

Sub FNL_2() 'stokdan ceklemli
Dim s1 As Worksheet, S2 As Worksheet, S3 As Worksheet, Dizi As Object
Dim Son As Long, Veri As Variant, X As Long, Say As Long
Dim Aranan As String, Tarih1 As Date, Tarih2 As Date, Zaman As Double

Zaman = Timer

Set s1 = Sheets("FINAL") ' MIZAN DI
Set S2 = Sheets("Liste")
Set S3 = Sheets("Stokliste") ' KARTDI
Set Dizi = CreateObject("Scripting.Dictionary")

Tarih1 = s1.Range("A1")
Tarih2 = s1.Range("B1")

s1.Range("A4:C" & s1.Rows.Count).Clear

Son = S3.Cells(S3.Rows.Count, 22).End(3).Row
Veri = S3.Range("A2:X" & Son).Value

Son = S2.Cells(S2.Rows.Count, 3).End(3).Row

ReDim Liste(1 To Son, 1 To 3)

For X = LBound(Veri) To UBound(Veri)
If Veri(X, 22) <> "" And Veri(X, 7) = "Sales" Then ' STOKDAN
Aranan = Veri(X, 22) & "|" & Veri(X, 6) & "|" & Veri(X, 8)
If Not Dizi.Exists(Aranan) Then
Say = Say + 1
Dizi.Add Aranan, Say
Liste(Say, 1) = Split(Aranan, "|")(0)
Liste(Say, 2) = Split(Aranan, "|")(1)
Liste(Say, 3) = Split(Aranan, "|")(2)
'Liste(Say, 4) = Split(Aranan, "|")(3)

End If
End If
Next

If Say > 0 Then
s1.Range("A4").Resize(Say, 5) = Liste
s1.Range("D4").Resize(Say, 2).Style = "Comma"
' s1.Range("A3:E3").Resize(Say).Sort s1.Range("A3"), xlAscending, s1.Range("B3"), , xlAscending, s1.Range("C3"), xlAscending
End If

Set s1 = Nothing
Set S2 = Nothing
Set Dizi = Nothing
Call Fnl_Bakiye

MsgBox "Veri aktarimi tamamlanmistir." & Chr(10) & Chr(10) & _
"Islem süresi ; " & Format(Timer - Zaman, "0.00") & " Saniye", vbInformation
End Sub

canburak · 11 Eylül 2020

2 ci Makro

Sub Fnl_Bakiye()
Dim satir As Long
Set Data = Sheets("liste")
Set Final = Sheets("FINAL")

Final.Range("D4:Z" & Rows.Count).ClearContents

sonA = Data.Cells(Rows.Count, "U").End(3).Row
SonB = Final.Cells(Rows.Count, "A").End(3).Row

For satir = 4 To SonB

Final.Cells(satir, "D") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("G2:G" & sonA), _
Final.Range("D1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "E") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("E1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "F") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("F1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "G") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("G1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "H") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("H1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "I") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("I1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "J") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("J1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "K") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("K1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "L") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("L1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "M") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("M1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "N") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("N1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "O") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("O1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "P") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("P1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "Q") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("Q1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "R") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("R1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "S") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("S1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "T") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("T1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "U") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("U1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "V") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("V1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "W") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("W1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "X") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("X1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "Y") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("H2:H" & sonA), _
Final.Range("Y1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

Final.Cells(satir, "Z") = WorksheetFunction.SumIfs(Data.Range("N2:N" & sonA), Data.Range("G2:G" & sonA), _
Final.Range("Z1"), Data.Range("T2:T" & sonA), Final.Cells(satir, "A"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(Final.Range("A1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(Final.Range("B1"))))

'FINAL.Cells(satir, "e") = WorksheetFunction.SumIfs(Data.Range("k2:k" & sonA), Data.Range("g2:g" & sonA), _
'FINAL.Cells(satir, "b"), Data.Range("H2:H" & sonA), FINAL.Cells(satir, "C"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(FINAL.Range("L1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(FINAL.Range("L2"))))

'FINAL.Cells(satir, "g") = WorksheetFunction.SumIfs(Data.Range("n2:n" & sonA), Data.Range("g2:g" & sonA), _
'FINAL.Cells(satir, "b"), Data.Range("H2:H" & sonA), FINAL.Cells(satir, "C"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(FINAL.Range("L1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(FINAL.Range("L2"))), Data.Range("N2:N" & sonA), ">" & "0")

'FINAL.Cells(satir, "h") = WorksheetFunction.SumIfs(Data.Range("n2:n" & sonA), Data.Range("g2:g" & sonA), _
'FINAL.Cells(satir, "b"), Data.Range("H2:H" & sonA), FINAL.Cells(satir, "C"), Data.Range("c2:c" & sonA), ">=" & CDbl(CDate(FINAL.Range("L1"))), Data.Range("c2:c" & sonA), "<=" & CDbl(CDate(FINAL.Range("L2"))), Data.Range("N2:N" & sonA), "<" & "0")

Next satir

End Sub

canburak · 13 Eylül 2020

Korhan Ayhan' Alıntı:
Ne nereye gelecek tarif eder misiniz?

Merhaba
Hocam acaba tam olarak anlata bilmismiyim, yoksa cokmu karisik anlatmisim ?

Korhan Ayhan · 13 Eylül 2020

Paylaştığınız kodlara uygun örnek dosya paylaşır mısınız?

canburak · 13 Eylül 2020

Korhan Ayhan' Alıntı:
Paylaştığınız kodlara uygun örnek dosya paylaşır mısınız?

Merhaba hocam, Calisir haldeki ornek dosyayi ekledim, asil dosyada sayfa 17 bin satirdan fazla oldugu icin ve rapor bolumunde 6-7 sutun daha fazla oldugu icin cok kasiyor 3-5 dakika suruyor
Tesekkurler,

Korhan Ayhan · 14 Eylül 2020

Deneyin bakalım olmuş mu?

C++:

Option Explicit

Sub Analiz()
    Dim S1 As Worksheet, S2 As Worksheet, S3 As Worksheet, Dizi As Object
    Dim Son As Long, Veri As Variant, X As Long, Say As Long
    Dim Aranan As String, Tarih1 As Date, Tarih2 As Date, Zaman As Double
   
    Zaman = Timer
   
    With Application
        .ScreenUpdating = False
        .Calculation = xlCalculationManual
    End With
   
    Set S1 = Sheets("FINAL")
    Set S2 = Sheets("Liste")
    Set S3 = Sheets("Stokliste") '
    Set Dizi = CreateObject("Scripting.Dictionary")
   
    Tarih1 = S1.Range("A1")
    Tarih2 = S1.Range("B1")
   
    S1.Range("A6:S" & S1.Rows.Count).Clear
   
    Son = S3.Cells(S3.Rows.Count, 22).End(3).Row
    Veri = S3.Range("A2:X" & Son).Value
   
    ReDim Liste(1 To Son, 1 To 18)
   
    For X = LBound(Veri) To UBound(Veri)
        If Veri(X, 22) <> "" And Veri(X, 7) = "SATIS" Then
            Aranan = Veri(X, 22)
            If Not Dizi.Exists(Aranan) Then
                Say = Say + 1
                Dizi.Add Aranan, Say
                Liste(Say, 1) = Veri(X, 4)
                Liste(Say, 2) = Veri(X, 3)
                Liste(Say, 3) = Veri(X, 22)
                Liste(Say, 4) = Veri(X, 6)
                Liste(Say, 5) = Veri(X, 8)
                Liste(Say, 6) = Veri(X, 10)
            Else
                Liste(Dizi.Item(Aranan), 6) = Liste(Dizi.Item(Aranan), 6) + Veri(X, 10)
            End If
        End If
    Next
      
    Son = S2.Cells(S2.Rows.Count, 20).End(3).Row
    Veri = S2.Range("A2:U" & Son).Value

    For X = LBound(Veri) To UBound(Veri)
        If Veri(X, 3) >= Tarih1 And Veri(X, 3) <= Tarih2 Then
            Aranan = Veri(X, 20)
            If Dizi.Exists(Aranan) Then
                If Veri(X, 7) = S1.Range("H1") Then
                    Liste(Dizi.Item(Aranan), 7) = Liste(Dizi.Item(Aranan), 7) + Veri(X, 14)
                End If
                If Veri(X, 7) = S1.Range("I2") And Veri(X, 8) = S1.Range("I1") Then
                    Liste(Dizi.Item(Aranan), 8) = Liste(Dizi.Item(Aranan), 8) + Veri(X, 14)
                End If
                If Veri(X, 7) = S1.Range("J2") And Veri(X, 8) = S1.Range("J1") Then
                    Liste(Dizi.Item(Aranan), 9) = Liste(Dizi.Item(Aranan), 9) + Veri(X, 14)
                End If
                If Veri(X, 7) = S1.Range("K2") And Veri(X, 8) = S1.Range("K1") Then
                    Liste(Dizi.Item(Aranan), 10) = Liste(Dizi.Item(Aranan), 10) + Veri(X, 14)
                End If
                If Veri(X, 7) = S1.Range("L2") And Veri(X, 8) = S1.Range("L1") Then
                    Liste(Dizi.Item(Aranan), 11) = Liste(Dizi.Item(Aranan), 11) + Veri(X, 14)
                End If
                If Veri(X, 7) = S1.Range("M2") And Veri(X, 8) = S1.Range("M1") Then
                    Liste(Dizi.Item(Aranan), 12) = Liste(Dizi.Item(Aranan), 12) + Veri(X, 14)
                End If
                If Veri(X, 7) = S1.Range("N2") And Veri(X, 8) = S1.Range("N1") Then
                    Liste(Dizi.Item(Aranan), 13) = Liste(Dizi.Item(Aranan), 13) + Veri(X, 14)
                End If
                If Veri(X, 7) = S1.Range("O2") And Veri(X, 8) = S1.Range("O1") Then
                    Liste(Dizi.Item(Aranan), 14) = Liste(Dizi.Item(Aranan), 14) + Veri(X, 14)
                End If
                If Veri(X, 7) = S1.Range("P2") And Veri(X, 8) = S1.Range("P1") Then
                    Liste(Dizi.Item(Aranan), 15) = Liste(Dizi.Item(Aranan), 15) + Veri(X, 14)
                End If
                If Veri(X, 7) = S1.Range("Q2") And Veri(X, 8) = S1.Range("Q1") Then
                    Liste(Dizi.Item(Aranan), 16) = Liste(Dizi.Item(Aranan), 16) + Veri(X, 14)
                End If
                If Veri(X, 7) = S1.Range("R1") Then
                    Liste(Dizi.Item(Aranan), 17) = Liste(Dizi.Item(Aranan), 17) + Veri(X, 14)
                End If
                Liste(Dizi.Item(Aranan), 18) = Liste(Dizi.Item(Aranan), 7) + Liste(Dizi.Item(Aranan), 8) + _
                                               Liste(Dizi.Item(Aranan), 9) + Liste(Dizi.Item(Aranan), 10) + Liste(Dizi.Item(Aranan), 11) + _
                                               Liste(Dizi.Item(Aranan), 12) + Liste(Dizi.Item(Aranan), 13) + Liste(Dizi.Item(Aranan), 14) + _
                                               Liste(Dizi.Item(Aranan), 15) + Liste(Dizi.Item(Aranan), 16) + Liste(Dizi.Item(Aranan), 17)
            End If
        End If
    Next
    
    If Say > 0 Then
        S1.Range("B6").Resize(Say, 18) = Liste
        S1.Range("G6").Resize(Say, 13).Style = "Comma"
        S1.Columns.AutoFit
    End If
   
    Set S1 = Nothing
    Set S2 = Nothing
    Set S3 = Nothing
    Set Dizi = Nothing
   
    With Application
        .ScreenUpdating = True
        .Calculation = xlCalculationAutomatic
    End With
   
    MsgBox "Veri aktarımı tamamlanmıştır." & Chr(10) & Chr(10) & _
           "İşlem süresi ; " & Format(Timer - Zaman, "0.00") & " Saniye", vbInformation
End Sub

canburak · 14 Eylül 2020

Hocam Kendi asil dosyama uyarladim, cok guzel calisiyor, Elinize saglik, Cok tesekkur ediyorum.
Saygilar,

Korhan Ayhan · 14 Eylül 2020

Fazla veride işlem ne kadar sürüyor?

canburak · 27 Ocak 2021

Korhan Hocam tekrar merhaba, ekte gonderdigim dosyada bilgi hesaplama ve getirme sorunum var bir turlu beceremedim, acaba yardimci ola bilirmisiniz ekdeki dosya da ne yapmaya calistigimi anlatmaya calistim ve bazilarini exlel formulleri ile yaparak gostermeye calistim, umarim anlasilir olmustur, rapordaki bazi makrolar duzgun calisiyor kirmizi ile isaretli olanlar alttakiler makrosuz olarak anlasilmasi icin formuller le gosterdim nerden ne cekecegini.
Simdiden Cok tesekkurler
Saygilar

Tarih yada sayı içeren sabit hücreye ek koşul koyma sorunu

canburak

Korhan Ayhan

Administrator

canburak

canburak

canburak

Ornek kar zarar.xlsm

Korhan Ayhan

Administrator

canburak

canburak

canburak

canburak

Korhan Ayhan

Administrator

canburak

Ekli dosyalar

Korhan Ayhan

Administrator

canburak

Korhan Ayhan

Administrator

canburak

Ekli dosyalar