Soru Sayfada oluşturulan komut butonunu silme.

[kar67970]

Hayırlı günler. Bu forumda dün verilen önerilerden yola çıkarak komut butonu oluşturdum. İçine makro atamadığım için silmem gerek. Ancak silemiyorum. Dosyayı ekliyorum. Allah rızası için yardımcı olun. Yapmak istediğim, bulunduğum sayfa içindeki bütün formülleri bir seferde kilitlemek. Yani formül bulunan her hücreye tek tek girip ( =Kesin!$21$ ) şeklinde $ (dolar) işareti koymak yerine, bir seferde hepsine birden $ (dolar) işareti koymak istiyorum. Ama maalesef yüzüme gözüme bulaştırdım sanırım. Bana yardımcı olursanız çok sevineceğim. Bu arada komut butonunu, hem " Köy001" sayfasındaki formül içeren hücrelerdeki formülleri, hem Kesin-Yatay" sayfasındaki formül içeren hücrelerdeki formülleri kiliitleyecek şekilde ve yazdırma alanlarının dışına koymak istiyorum. Yada en soldaki " Kesin " sayfasına, " Kesin-Yatay " sayfasındakileri, " Busene " sayfasına da " Köy001 " sayfasındakileri çalıştıracak şekilde buton koymak istiyorum. Dosya ekte. Hocam lütfen yardım edin.

 

[Korhan Ayhan]

Siz sayfanıza CommandButton eklemişsiniz. Bu butonu silebilmeniz için görselde ki işaretli seçeneğe tıklamanız gerekiyor.




Bu butonu sildikten sonra aynı görselde solda bulunan EKLE menüsünden sayfanıza bir dikdörtgen ekleyip buton gibi kullanabilirsiniz. Rengini, üstündeki yazıyı falan ayarlayabilirsiniz. Bu ayarları yaptıktan sonra eklediğiniz şekil üzerinde sağ tıklayıp makro ata komutunu çalıştırırsanız karşınıza bir menü gelir. Bu menüden çalıştırmak istediğiniz makronun adına çift tıklayıp butona tanımlama işlemini yapabilirsiniz.

Benim önerdiğim kodu kullanmak isterseniz önce sayfada bu işlemi yapmak istediğiniz alanı seçmeniz gerekir. Yok ben seçmekle uğraşmak istemiyorum derseniz kodu aşağıdaki gibi revize etmek gerekir.

Kendiniz uygulamaya çalışın takıldığınız yerde yine destek oluruz. Ama ben yapacağınıza eminim.

Option Explicit

Sub Relative_to_Absolute()
    Dim My_Cell As Range, Formullu_Alan As Range
    
    Application.Calculation = xlCalculationManual
    
    On Error Resume Next
    Set Formullu_Alan = Cells.SpecialCells(xlFormulas)
    On Error GoTo 0
    
    If Formullu_Alan Is Nothing Then
        MsgBox "Seçtiğiniz alanda formül içeren hücre bulunamadı!", vbCritical
        Exit Sub
    End If
    
    For Each My_Cell In Formullu_Alan
        My_Cell.Formula = Application.ConvertFormula(My_Cell.Formula, xlA1, xlA1, xlAbsolute)
    Next

    Application.Calculation = xlCalculationAutomatic
    
    MsgBox "İşleminiz tamamlanmıştır."
End Sub

 

[kar67970]

Siz sayfanıza CommandButton eklemişsiniz. Bu butonu silebilmeniz için görselde ki işaretli seçeneğe tıklamanız gerekiyor.

Ekli dosyayı görüntüle 229353


Bu butonu sildikten sonra aynı görselde solda bulunan EKLE menüsünden sayfanıza bir dikdörtgen ekleyip buton gibi kullanabilirsiniz. Rengini, üstündeki yazıyı falan ayarlayabilirsiniz. Bu ayarları yaptıktan sonra eklediğiniz şekil üzerinde sağ tıklayıp makro ata komutunu çalıştırırsanız karşınıza bir menü gelir. Bu menüden çalıştırmak istediğiniz makronun adına çift tıklayıp butona tanımlama işlemini yapabilirsiniz.

Benim önerdiğim kodu kullanmak isterseniz önce sayfada bu işlemi yapmak istediğiniz alanı seçmeniz gerekir. Yok ben seçmekle uğraşmak istemiyorum derseniz kodu aşağıdaki gibi revize etmek gerekir.

Kendiniz uygulamaya çalışın takıldığınız yerde yine destek oluruz. Ama ben yapacağınıza eminim.

Option Explicit

Sub Relative_to_Absolute()
    Dim My_Cell As Range, Formullu_Alan As Range
   
    Application.Calculation = xlCalculationManual
   
    On Error Resume Next
    Set Formullu_Alan = Cells.SpecialCells(xlFormulas)
    On Error GoTo 0
   
    If Formullu_Alan Is Nothing Then
        MsgBox "Seçtiğiniz alanda formül içeren hücre bulunamadı!", vbCritical
        Exit Sub
    End If
   
    For Each My_Cell In Formullu_Alan
        My_Cell.Formula = Application.ConvertFormula(My_Cell.Formula, xlA1, xlA1, xlAbsolute)
    Next

    Application.Calculation = xlCalculationAutomatic
   
    MsgBox "İşleminiz tamamlanmıştır."
End Sub

Korhan Hocam Allah razı olsun. Şu an için butonu oluşturdum ancak makro ataması yapmadım. Önce formüllerin tümünü gireyim, ondan sonra önerdiğiniz makroyu butona atayacağım. Ancak bu kod, içinde bulunduğu sayfayı mı değiştiriyor bütün çalışma kitabını mı? Ayrıca hücre seçmek zorunda olacak mıyım? Çünkü ben hücre seçmeden içinde bulunduğum sayfadaki formüllerin tamamını veya çalışma kitabındaki formüllerin tamamını kilitlemek istiyorum. Yardımlarınız için tekrar çok teşekkür ederim.

 

[Korhan Ayhan]

İçinde bulunduğu sayfada işlem yapar.

Ayrıca formüllere dolar işareti eklemek istiyorum ifadesi daha doğru olacaktır. Zira "Kilitlemek" ifadesinden farklı yorumlar çıkabilir.

Tüm dosyadaki formüllere topluca dolar işareti eklemek için kodu aşağıdaki gibi değiştirmelisiniz.

Option Explicit

Sub Relative_to_Absolute()
    Dim Sh As Worksheet, My_Cell As Range, Formullu_Alan As Range
    
    Application.Calculation = xlCalculationManual
    
    For Each Sh In ThisWorkbook.Worksheets
        On Error Resume Next
        Set Formullu_Alan = Sh.Cells.SpecialCells(xlFormulas)
        On Error GoTo 0
        
        If Not Formullu_Alan Is Nothing Then
            For Each My_Cell In Formullu_Alan
                My_Cell.Formula = Application.ConvertFormula(My_Cell.Formula, xlA1, xlA1, xlAbsolute)
            Next
        End If
    Next

    Application.Calculation = xlCalculationAutomatic
    
    MsgBox "İşleminiz tamamlanmıştır."
End Sub

 

[kar67970]

İçinde bulunduğu sayfada işlem yapar.

Ayrıca formüllere dolar işareti eklemek istiyorum ifadesi daha doğru olacaktır. Zira "Kilitlemek" ifadesinden farklı yorumlar çıkabilir.

Tüm dosyadaki formüllere topluca dolar işareti eklemek için kodu aşağıdaki gibi değiştirmelisiniz.

Option Explicit

Sub Relative_to_Absolute()
    Dim Sh As Worksheet, My_Cell As Range, Formullu_Alan As Range
   
    Application.Calculation = xlCalculationManual
   
    For Each Sh In ThisWorkbook.Worksheets
        On Error Resume Next
        Set Formullu_Alan = Sh.Cells.SpecialCells(xlFormulas)
        On Error GoTo 0
       
        If Not Formullu_Alan Is Nothing Then
            For Each My_Cell In Formullu_Alan
                My_Cell.Formula = Application.ConvertFormula(My_Cell.Formula, xlA1, xlA1, xlAbsolute)
            Next
        End If
    Next

    Application.Calculation = xlCalculationAutomatic
   
    MsgBox "İşleminiz tamamlanmıştır."
End Sub

Korhan Hocam hayırlı sabahlar. Yardımlarınız için çok teşekkür ederim. Allah hepinizden razı olsun. Haklarınızı helal edin. Allah'a emanet olun.

 

[kar67970]

Korhan Hocam hayırlı sabahlar. Yardımlarınız için çok teşekkür ederim. Allah hepinizden razı olsun. Haklarınızı helal edin. Allah'a emanet olun.

Korhan Hocam hayırlı akşamlar. Çalışma sayfasındaki bütün hücrelerdeki formüllere bu kod ille $ dolar işareti koyduk. Eğer ben çalışma sayfasındaki bütün $ dolar işaretlerini kaldırmak istersem, $ dolar işaretlerinin tümünü bir kod ile nasıl kaldırabilirim? Bu konuda da bana yardım eder misiniz? Zaten dosya sizde mevcut.

Birde Korhan Hocam; ekte gönderdiğim dosyada, " Demirbaşlar " sayfasındaki bütün demirbaşları olduğu gibi " Teslim Etme " ve " Teslim Alma " sayfalarına atmak istiyorum. Ancak bu iki sayfada sadece " Demirbaşlar " sayfasının ( G ) sütunundaki " NEREYE VERİLDİĞİ " sütunundaki verilerden, O2 " sütununa girilen SEÇİM' deki veriler yer alacak. Diğerleri ile ( A ) sütunundaki " DÜŞÜM YAPILAN " sütununda " Düşüm " bilgisi yer alan satırlar bu iki sayfada yer almayacak.

Şu da bir gerçek; bu dosyalardaki kodların tümünü bu sitedeki değerli hocalarımız verdi. Yani hiç birini kendim oluşturmadım. Hepsinden, hepinizden ve bu siteyi kurup benim gibi yardıma ihtiyacı insanların yararına hayata geçiren herkesten Allah razı olsun.

Not: Hocam ekteki dosyanın Excel logosuna dikkat ederseniz, kocaman bir ( ! ) ünlem işareti var. Bunun anlamı ne oluyor, dosyanın formatında hataya mı işaret ediyor? Ancak çalışma sayfalarında veya dosyanın içeriğinde herhangi bir hata mesajı da verilmiyor. Bu konuda bir bilginiz yada fikriniz var mı?

 

[Korhan Ayhan]

Merhaba,

Dosya sembolündeki ünlem işareti için linki inceleyiniz.

dosya ikonunda ünlem

dosya ikonunda ünlem işareti var ne anlama geliyor.

www.excel.web.tr

Tüm sayfalardaki "$" sembollerini kaldırmak için aşağıdaki kodu kullanabilirsiniz.

Option Explicit

Sub Dolar_Symbol_Remove()
    Dim Sh As Worksheet
   
    Application.Calculation = xlCalculationManual
   
    For Each Sh In ThisWorkbook.Worksheets
        Sh.Cells.Replace What:="$", Replacement:="", LookAt:=xlPart, _
        SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
        ReplaceFormat:=False
    Next

    Application.Calculation = xlCalculationAutomatic
   
    MsgBox "Your transaction is complete."
End Sub