satırda dolu olan hücrelerdeki verileri sütuna alt alta yazdırma yardımı hk

[chemesk]

Merhabalar,

Aşağıdaki gibi bir tablom var
burada herkes aynı eğitimi almıyor (eğitim alanlara 1 olarak işaretliyorum)

Adı Soyadı	Eğitim 1	Eğitim 2	Eğitim 3	Eğitim 4
AYŞE		1​
AHMET			1​
ALİ		1​		1​
VELİ
FATMA

Başka bir listede de kişi bazlı takip etmek istiyorum.

Yani
Ali şeçtiğimde
Eğitimler alt alta sıralansın istiyorum ama beceremedim. Yardımcı olursanız sevinirim.
teşekkürler

Sıra	Tarih	Eğitim Konusu	Eğitimi Veren Kişi / Kurum	Süre
		Eğitim 2
		Eğitim 4

 

[chemesk]

forumda yeni olunca
tablo eklemiştim ama biçimsiz olmuş tabi bir şey anlaşılmıyor :/

 

[YUSUF44]

Foruma hoş geldiniz.

Örnek excel dosyanızı imzamda belirttiğim gibi dosya paylaşım sitelerinden birine ekleyip linki paylaşırsanız hızlı çözüm bulursunuz.

 

[chemesk]

Foruma hoş geldiniz.

Örnek excel dosyanızı imzamda belirttiğim gibi dosya paylaşım sitelerinden birine ekleyip linki paylaşırsanız hızlı çözüm bulursunuz.

Çok teşekkürler Yusuf Bey

tekrar merhaba,
Dosya aşağıdaki linktedir.
eğitim takip dosyası yapmak istiyorum. açıklamayı sekmeye yazmıştım.
yardımcı olursanız çok sevinirim

eğitim test

 

[ÖmerFaruk]

Merhaba, Eğitimciler sayfasındaki son eğitime doğru değerler girilmelidir. Yada katılımcılar kısmındaki gri bölgedeki formüllerinizi gözden geçirmelisiniz.

Devamında FORM sayfasında aşağıdaki formülleri girmelisiniz.

A14 için
=EĞER(KAYDIR(Katılımcılar!$G$7;KAÇINCI($C$7;Katılımcılar!$B$8:$B$19;0);0;1;1)>SATIR()-14;SATIR()-13;"")

B14 için
=EĞERHATA(KAYDIR(Katılımcılar!$A$1;1;KÜÇÜK(SÜTUN(KAYDIR(Katılımcılar!$I$7:$L$7;KAÇINCI($C$7;Katılımcılar!$B$8:$B$19;0);0;1;MAK(Eğitimciler!A:A)));A14)-1;1;1);"")
Ayrıca B sütunundaki tarih bölgesinin formatını gg.aa.yyyy şeklinde biçimlendirin.

C14 için
=EĞER(A14="";"";KAYDIR(Eğitimciler!$A$1;KÜÇÜK(SÜTUN(KAYDIR(Katılımcılar!$I$7:$L$7;KAÇINCI($C$7;Katılımcılar!$B$8:$B$19;0);0;1;MAK(Eğitimciler!A:A)));A14)-8;2;1;1))

G14 için
=EĞER(A14="";"";KAYDIR(Eğitimciler!$A$1;KÜÇÜK(SÜTUN(KAYDIR(Katılımcılar!$I$7:$L$7;KAÇINCI($C$7;Katılımcılar!$B$8:$B$19;0);0;1;MAK(Eğitimciler!A:A)));A14)-8;3;1;1))

J14 için
=EĞER(A14="";"";KAYDIR(Eğitimciler!$A$1;KÜÇÜK(SÜTUN(KAYDIR(Katılımcılar!$I$7:$L$7;KAÇINCI($C$7;Katılımcılar!$B$8:$B$19;0);0;1;MAK(Eğitimciler!A:A)));A14)-8;4;1;1))

 

[ÖmerFaruk]

Düzeltme,
A14 için önceki formül doğru, diğer formülleri unutunç

B14 için aşağıdaki formülü kullanın,
C,G,J sütunları için Ctr+C / Ctrl+V ile çoğaltın.
Sütunlarınızın biçimlendirmeleri bozulabilir düzeltin

=EĞERHATA(KAYDIR(Eğitimciler!$A$1;KÜÇÜK(EĞER(KAYDIR(Katılımcılar!$H$7;KAÇINCI($C$7;Katılımcılar!$B$8:$B$19;0);1;1;MAK(Eğitimciler!$A:$A))<>"";SÜTUN(KAYDIR(Katılımcılar!$H$7;KAÇINCI($C$7;Katılımcılar!$B$8:$B$19;0);1;1;MAK(Eğitimciler!$A:$A))));$A14)-8;BAĞ_DEĞ_DOLU_SAY($A$13:B$13)-1;1;1);"")

 

[chemesk]

Düzeltme,
A14 için önceki formül doğru, diğer formülleri unutunç

B14 için aşağıdaki formülü kullanın,
C,G,J sütunları için Ctr+C / Ctrl+V ile çoğaltın.
Sütunlarınızın biçimlendirmeleri bozulabilir düzeltin

=EĞERHATA(KAYDIR(Eğitimciler!$A$1;KÜÇÜK(EĞER(KAYDIR(Katılımcılar!$H$7;KAÇINCI($C$7;Katılımcılar!$B$8:$B$19;0);1;1;MAK(Eğitimciler!$A:$A))<>"";SÜTUN(KAYDIR(Katılımcılar!$H$7;KAÇINCI($C$7;Katılımcılar!$B$8:$B$19;0);1;1;MAK(Eğitimciler!$A:$A))));$A14)-8;BAĞ_DEĞ_DOLU_SAY($A$13:B$13)-1;1;1);"")

Yardımınız için çok çok teşekkür ederim Ömer Faruk bey çok saolun
söylediklerinizi uyguladım ve çok güzel oldu

 

[ÖmerFaruk]

Eyvallah.
O formül yapısını anlamaya çalışın. Formül Değerlendir menüsünden nasıl sonuçlar oluşuyor izleyin.

 

[chemesk]

Eyvallah.
O formül yapısını anlamaya çalışın. Formül Değerlendir menüsünden nasıl sonuçlar oluşuyor izleyin.

evet, çok faydalı olacak bu site bu konuda, tekrar teşekkürler