Fiyat Listesinden, aynı ürünün, farklı iki tarih arasındaki geçerli fiyatını getirmek.

[besen]

Merhaba, iki tarih arasındaki tüm sorulara baktım ama benzer bir soru bulamadım.
Sorumu içeren örnek dosya ekte.
Teşekkür ederim

Stok Kodu	Geçerlilik Tarihi Başlangıcı	Geçerlilik Tarihi Bitişi	Fiyat
XYZ	8.06.2020​	1.04.2021​	85​
XYZ	2.04.2021​	31.07.2021​	95​
XYZ	1.08.2021​		122​

 

[hamitcan]

Bu şekilde dener misiniz ?

=ARA(F2;$B$2:$C$4;$D$2:$D$4)

 

[besen]

Merhaba, evet doğru çalışıyor, ancak sanırım bir şeyi unuttum, Ürün kodu da dikkate alınmalı.
Örnek Dosyayı tekrar ekledim.

Bu şekilde dener misiniz ?

=ARA(F2;$B$2:$C$4;$D$2:$D$4)

 

[besen]

=LOOKUP(2;1/($A$2:$A$15=$E2)/($B$2:$B$15<=$F2)/($C$2:$C$15>=$F2);$D$2:$D$15)
Bu formülle bir çözüm oluşturdum ama, en son veride bitiş tarihi henüz olmadığı için bu hücreyi dikkate almıyor. Hücreye ileri bir tarih girince formül doğru. Tarih alanı boş olduğu durumuna göre bir çözüm varmı?

 

[ÖmerFaruk]

=TOPLA.ÇARPIM(($A$2:$A$14=$E2)*($B$2:$B$14<=$F2)*(EĞER($C$2:$C$14="";1;$C$2:$C$14>=F2))*($D$2:$D$14))

 

[besen]

=TOPLA.ÇARPIM(($A$2:$A$14=$E2)*($B$2:$B$14<=$F2)*(EĞER($C$2:$C$14="";1;$C$2:$C$14>=F2))*($D$2:$D$14))

Sadece ilk satırın bilgisi doğru geliyor.
Diğerlerinde toplam alıyor.

 

[ÖmerFaruk]

formülün içine @ işaretini siz mi koyuyorsunuz?

 

[besen]

formülün içine @ işaretini siz mi koyuyorsunuz?

Ekli dosyayı görüntüle 230754

Özür dilerim anlayamadım. Formülde o işaret yok. Aşağıya yazdım.

=SUMPRODUCT(($A$2:$A$13=$E2)*($B$2:$B$13<=$F2)*(IF($C$2:$C$13="";1;$C$2:$C$13>=F2))*($D$2:$D$13))

 

[ÖmerFaruk]

Özürlük bir durum yok. Lütfen

Bu @ işareti sebep oluyor ama sebebini bilmiyorum. Sizdeki dosyayı açınca ben böyle görüyorum.
Ben size bendeki dosyayı göndereyim. Oradan bakın

 

[besen]

Özürlük bir durum yok. Lütfen

Bu @ işareti sebep oluyor ama sebebini bilmiyorum. Sizdeki dosyayı açınca ben böyle görüyorum.
Ben size bendeki dosyayı göndereyim. Oradan bakın

Anladım. Sorun @ işareti değil, dizi formülüymüş, ondan dolayı olmuş.
Teşekkür ederim.

 

[52779]

Selamlar,

formülün içine @ işaretini siz mi koyuyorsunuz?

Sn @ÖmerFaruk
Bilgi amaçlı olarak yazıyorum...

@ işareti, özellikle Office 365 ile görünmeye başlayan bir işaret olup Örtük Kesişim İşleci olarak adlandırılır.
Konu ile ilgili Microsoft makalesi aşağıdadır.

Örtük kesişim işleci: @ - Microsoft Desteği

Örtük kesişim olarak bilinen bir mantık kullanarak tek bir değer veren örtük kesişim işleci (@) hakkında bilgi edinin. Örtük kesişim işleci (@) tek bir değer, tek bir hücre aralığı ya da bir hata verebilir. Örtük kesişim işleci (@) dinamik diziler adlı bir işlevler sınıfıdır.

support.microsoft.com

=LOOKUP(2;1/($A$2:$A$15=$E2)/($B$2:$B$15<=$F2)/($C$2:$C$15>=$F2);$D$2:$D$15)
Bu formülle bir çözüm oluşturdum ama, en son veride bitiş tarihi henüz olmadığı için bu hücreyi dikkate almıyor. Hücreye ileri bir tarih girince formül doğru. Tarih alanı boş olduğu durumuna göre bir çözüm varmı?

Sn @besen
Dosyanızı göremem...
4 no lu mesajınızdan anladığım kadarıyla, (eğer yanlış anlamıyorsam)
Koşulları sağlayan, D2 : D15 arasında (BOŞ olmayan) en son DOLU olan hücredeki değeri arıyorsunuz...

Formülünüze D2 : D15<>"" koşulunu da ekleyerek deneyebilirsiniz...
Yani
=LOOKUP(2;1/($A$2:$A$15=$E2)/($B$2:$B$15<=$F2)/($C$2:$C$15>=$F2)/($D$2:$D$15<>"");$D$2:$D$15)

Ya da alternatif olarak
=İNDİS($D$2:$D$15;TOPLAMA(14;6;(SATIR($A$2:$A$15)-SATIR($A$2)+1)/($A$2:$A$15=$E2)/($B$2:$B$15<=$F2)/($C$2:$C$15>=$F2)/($D$2:$D$15<>"");1))

Burada
İNDİS = INDEX
TOPLAMA = AGGREGATE
SATIR = ROW

 

[52779]

Belki de
C2 : C15 Bitiş Tarihleri kolonu olabilir. Bu durumda
=LOOKUP(2;1/($A$2:$A$15=$E2)/($B$2:$B$15<=$F2)/(IF($C$2:$C$15="";1;$C$2:$C$15>=$F2));$D$2:$D$15)
şeklinde denersiniz...