Kapalı dosyanın son boş satırana kaytedmek

[tahsinanarat]

Değerli hocalarım; Açık olan_veriler adlı çalışma kitabının Alınanveriler sayfasındaki C,F,G,H,J.K,M,N,R ve S sutunlarında bulunan 4.satırdan itibaren son dolu satıra kadar olan hücreler aynı kalasördeki kapalı olan (veya; belirticeğim yoldaki) kapali.xlsx adlı çalışma kitabının C,F,G,H,J.K,M,N,R ve S sutunlarının en son boş (örnekte c sutunundaki sarı ile boyadığım hücre) hücresinden itibaren eklemek istiyorum.
Yardımcı olacak hocalarıma şimdiden teşekkür ederim.

 

[veyselemre]

Sub test()
    Application.ScreenUpdating = False
    
    Dim kapali As Object, sh As Worksheet, _
        sh2 As Worksheet, lRow&, lRow2&, adr, adr2, i%
    
    Set sh = Sheets("Alınanveriler")
    lRow = sh.Cells(Rows.Count, 3).End(3).Row
    
    Set kapali = Workbooks.Open(ActiveWorkbook.Path & "\kapali.xlsx")
    Set sh2 = kapali.Sheets("Veri Girisi")
    lRow2 = sh2.Cells(Rows.Count, 3).End(3).Row + 1
    
    adr = Array("C4:C" & lRow, "F4:I" & lRow, "K4:K" & lRow, "M4:P" & lRow, "R4:S" & lRow)
    adr2 = Array("C" & lRow2, "F" & lRow2, "K" & lRow2, "M" & lRow2, "R" & lRow2)

    For i = 0 To UBound(adr)
        sh.Range(adr(i)).Copy sh2.Range(adr2(i))
    Next i
    
    Windows("kapali.xlsx").Visible = True
    kapali.Close True
    Set kapali = Nothing
    Application.ScreenUpdating = True
End Sub

 

[tahsinanarat]

Sn. @veyselemre hocam, çok teşekkür ederim, tam istediğim şekilde olmuş. Elinize sağlık. Orjinal dosyama uyarlayıp bir terslik olursa bilgi vereceğim. Örnek dosya üzerinde denedim sonuç mükemmel.

 

[tahsinanarat]

Sn. @veyselemre hocam, kapalı olan dosyaya kayıt yaptıktan sonra kaydetmeden açık kalmasını sağlayabilirbiyiz. Teşekkürler

 

[veyselemre]

    kapali.Close True
    Set kapali = Nothing

Satırlarını iptal edin.

 

[tahsinanarat]

Sn. @veyselemre hocam, tamamdır. Çok teşekkürler. Hakkınızı helal edin.

kapali.Close True Set kapali = Nothing