İşlem Sayısı, tekrar sayısı ilk ve son işlem saati döngüsü

[aktarmamd]

Merhabalar;

Müşteriden siparişi alma ve işleme amacıyla oluşturduğum taslak bir çalışmam var, DETAY sayfasında sahada yapılan sipariş toplama işlemlerine yönelik;
1- kaç iştirakçiyle muhatap olunduğu
2-Kaçına gün içinde tekrarlı ziyaret yapılmış
3-En küçük ziyaret saati nedir?
4-En büyük Ziyaret saati nedir? kısımlarına pratik formül yazmam gerekiyor, birçok kombinasyon denedim ama "G sütunu boşsa F sütununa bak döngüsü" beni zorladı açıklamalarıyla birlikte örnek ektedir. Desteğinizi bekliyorum.

 

[Korhan Ayhan]

Deneyiniz.

DİZİ formüllerdir.

M3;

=SUM(IF(FREQUENCY(IF('02'!$A$2:$A$1000=I3;IF('02'!$B$2:$B$1000=J3;MATCH('02'!$F$2:$F$1000&'02'!$G$2:$G$1000;'02'!$F$2:$F$1000&'02'!$G$2:$G$1000;0)));ROW('02'!$G$2:$G$1000)-1)>0;1))

O3;

=SUM(IF(FREQUENCY(IF('02'!$A$2:$A$1000=I3;IF('02'!$B$2:$B$1000=J3;MATCH('02'!$F$2:$F$1000&'02'!$G$2:$G$1000;'02'!$F$2:$F$1000&'02'!$G$2:$G$1000;0)));ROW('02'!$G$2:$G$1000)-1)>1;1))

P3;

=MIN(IF('02'!$A$2:$A$1000=I3;--'02'!$I$2:$I$1000))

Q3;

=MAX(IF('02'!$A$2:$A$1000=I3;--'02'!$I$2:$I$1000))

 

[aktarmamd]

Deneyiniz.

DİZİ formüllerdir.

M3;

=SUM(IF(FREQUENCY(IF('02'!$A$2:$A$1000=I3;IF('02'!$B$2:$B$1000=J3;MATCH('02'!$F$2:$F$1000&'02'!$G$2:$G$1000;'02'!$F$2:$F$1000&'02'!$G$2:$G$1000;0)));ROW('02'!$G$2:$G$1000)-1)>0;1))

O3;

=SUM(IF(FREQUENCY(IF('02'!$A$2:$A$1000=I3;IF('02'!$B$2:$B$1000=J3;MATCH('02'!$F$2:$F$1000&'02'!$G$2:$G$1000;'02'!$F$2:$F$1000&'02'!$G$2:$G$1000;0)));ROW('02'!$G$2:$G$1000)-1)>1;1))

P3;

=MIN(IF('02'!$A$2:$A$1000=I3;--'02'!$I$2:$I$1000))

Q3;

=MAX(IF('02'!$A$2:$A$1000=I3;--'02'!$I$2:$I$1000))

Üstadım merhaba;

Çok teşekkürler, kaçıncı işlevinin hep indis ile bağlı olduğunu düşünürdüm, hiç diğer işlevlerle beraber kullanmayı düşünmemiştim. Ama buradaki çözüm tam anlamıyla mükemmel...

Bir durum daha var, ilave bir sayfa daha eklendi (01) bu sayfada plasiyerlerin alması gereken toplam sipariş sayıları iştirakçi kırılımıyla yer alıyor...yapmak istediğim şu;

Hiçbir yardımcı kolon veya sayfa eklemeden DETAY sayfasındaki 2015 ID li plasiyerin alması gereken sipariş toplam sayısını DETAY =S3 hücresinde toplatmak istiyorum? Burda sıkıntı 01,02 ve DETAY sayfasında üçünde de var sorguda kullanılacak olan ortak tek bir kriter yok.. Önce 02 deki iştirakçileri DETAY daki ID ile eşleştirmeli sonrasında ise bu eşleşmeye karşılık gelen 01 sayfasındaki iştirakçi ve toplam sipariş sayısını =S3 hücresine toplatılmalı.

Bunun olabilirliği ne derecedir? Örneği Ek te yeniliyorum..

 

[Korhan Ayhan]

Merhaba,

Ofis 365 için aşağıdaki formül işe yarıyor.

=TOPLA.ÇARPIM(ETOPLA('01'!C:C;BENZERSİZ('02'!F:G);'01'!D:D))

Eski sürümler için 02 sayfasındaki G sütununda tekrar eden verileri benzersiz liste yapmak gerekiyor.

 

[Ömer]

Merhaba,

Detaylı deneme yapmadım. Doğru anladıysam eski sürümler için aşağıdaki gibi kullanabilirsiniz.

Dizi formülüdür.

=TOPLA(EĞER(ESAYIYSA(KAÇINCI('01'!$C$2:$C$95;EĞER('02'!$A$2:$A$100=I3;'02'!$F$2:$F$100&'02'!$G$2:$G$100);0));'01'!$D$2:$D$95))

 

[aktarmamd]

Merhaba,

Detaylı deneme yapmadım. Doğru anladıysam eski sürümler için aşağıdaki gibi kullanabilirsiniz.

Dizi formülüdür.

=TOPLA(EĞER(ESAYIYSA(KAÇINCI('01'!$C$2:$C$95;EĞER('02'!$A$2:$A$100=I3;'02'!$F$2:$F$100&'02'!$G$2:$G$100);0));'01'!$D$2:$D$95))

Üstad Merhaba,

Formülün mantığı evet istediğim gibi, çok doğru bir çözüm olmuş emeğine sağlık.. Üzerine çalıştıkça yeni bir şey çıkıyor..
Şöyle olsa nasıl yapardık?
Formülün "'02'!$F$2:$F$100&'02'!$G$2:$G$100)" kısmında G sütununda boş hücre var ise F sütunundaki karşılığını alıyor ve tabloda sadece boş hücrenin karşısı dolu.
Eğer F sütunu tamamen dolu olsaydı, orda birde üst yüklenici firma isi olsaydı? nasıl yapardık?
Yani G ye bak doluysa okey, boşsa git F deki veriyi al gibi.. mevcut formülleri çalıştırarak Örneği yeniliyorum..

 

[Ömer]

Öncelikle formülün sonundaki sayfayı yanlış yazmışsınız. ;'02'!D2: D100)) buradaki '02'! değil '01'! olmalı.


Veri yapınıza göre aranan değer bölümüne * ilave edilerek formülü bozmadan aşağıdaki gibi yazılabilir.

=TOPLA(EĞER(ESAYIYSA(KAÇINCI("*"&'01'!C2:C100&"*";EĞER('02'!A1:A100=I3;'02'!F1:F100&'02'!G1:G100);0));'01'!D2:D100))

Yani G ye bak doluysa okey, boşsa git F deki veriyi al gibi..

Soru cümlenize göre yazmak gerekirse aşağıdaki gibi yazılabilir.

=TOPLA(EĞER(ESAYIYSA(KAÇINCI('01'!C2:C100;EĞER('02'!A1:A100=I3;EĞER('02'!G1:G100="";'02'!F1:F100;'02'!G1:G100));0));'01'!D2:D100))

Dizi formülleridir.

 

[aktarmamd]

Öncelikle formülün sonundaki sayfayı yanlış yazmışsınız. ;'02'!D2: D100)) buradaki '02'! değil '01'! olmalı.


Veri yapınıza göre aranan değer bölümüne * ilave edilerek formülü bozmadan aşağıdaki gibi yazılabilir.

=TOPLA(EĞER(ESAYIYSA(KAÇINCI("*"&'01'!C2:C100&"*";EĞER('02'!A1:A100=I3;'02'!F1:F100&'02'!G1:G100);0));'01'!D2:D100))

Soru cümlenize göre yazmak gerekirse aşağıdaki gibi yazılabilir.

=TOPLA(EĞER(ESAYIYSA(KAÇINCI('01'!C2:C100;EĞER('02'!A1:A100=I3;EĞER('02'!G1:G100="";'02'!F1:F100;'02'!G1:G100));0));'01'!D2:D100))

Dizi formülleridir.

Üstad;

Mükemmel sonuç ve mükemmel çözüm çok teşekkürler..