Birden fazla kritere göre benzersizleri saydırma

[Suddedly]

Herkese merhabalar hayırlı işler dilerim. Sorunumu ekteki dosyamda anlatmaya çalıştım. Yardım ve görüşleriniz için şimdiden çok teşekkür ederim.

 

[Suddedly]

Forumda araştırdım yine birden fazla kritere göre saydırma var ancak üzerine bir de iki tarih aralığında olanları saydırmam gerektiği için örneklerine uyduramadığımdan dolayı yardımlarınızı bekliyorum.

 

[Suddedly]

Baya uğraştım ama maalesef çözemedim. Yardımlarınızı bekliyorum.

 

[Erdal]

Merhabalar
M3 hücresine aşağıdaki formülü yazıp dener misiniz?
=TOPLA.ÇARPIM((E2:E10=K3)*(F2:F10=L3)*(A2:A10>=I3)*(A2:A10<=J3))

 

[Suddedly]

Merhabalar.

Formül ürün nolarını sayıyor 9 adet doğru. Ancak benzersiz olarak saydırmam gerekiyor. Yani toplamda 5 farklı ürün girmiş üretime. Sonucu 5 bulmamız gerekiyor. Yine de teşekkürler ilginize.

Merhabalar
M3 hücresine aşağıdaki formülü yazıp dener misiniz?
=TOPLA.ÇARPIM((E2:E10=K3)*(F2:F10=L3)*(A2:A10>=I3)*(A2:A10<=J3))

 

[Erdal]

Merhabalar.

Formül ürün nolarını sayıyor 9 adet doğru. Ancak benzersiz olarak saydırmam gerekiyor. Yani toplamda 5 farklı ürün girmiş üretime. Sonucu 5 bulmamız gerekiyor. Yine de teşekkürler ilginize.

Eki inceler misiniz?

 

[Suddedly]

Hocam elinize sağlık formül çalışıyor ancak benim örnekteki hatamdan dolayı kendi dosyama uyarlayamadım. Çünkü örnekte tek bir firma ve tek bir kalite vardı. Kendi dosyamda ise bir çok firma ve buna bağlı kalite var. Bu yüzden formül çalışmadı. Şimdi aynı dosyaya sayfa2 de çeşitlendirmeye çalıştım. Tekrar kusura bakmayın.

Eki inceler misiniz?

 

[Levent Menteşoğlu]

Dosyanızdaki N3 hücresinde aşağıdaki fonksiyonu deneyin.

=ÇOKEĞERSAY(A:A;">="&J3;A:A;"<="&K3;E:E;L3;F:F;M3)

 

[Suddedly]

Hocam ilginize teşekkürler ancak benim bu kriterlere göre benzersiz olanların sayısını almam gerekiyor. Örneğin A firma Moloz 9 satır olmasına rağmen benzersiz olanların sayısı 8 adettir. Çok teşekkür ederim yine de.

Dosyanızdaki N3 hücresinde aşağıdaki fonksiyonu deneyin.

=ÇOKEĞERSAY(A:A;">="&J3;A:A;"<="&K3;E:E;L3;F:F;M3)

 

[Ömer]

Merhaba,

Dizi formülüdür.

=BAĞ_DEĞ_SAY(1/SIKLIK(EĞER(E$1:E$150=L3;EĞER(F$1:F$150=M3;EĞER(A$1:A$150>=J3;EĞER(A$1:A$150<=K3
;KAÇINCI(D$1:D$150;D$1:D$150;0)))));SATIR(F$1:$F$150)-SATIR(F$1)+1))

 

[tsoyts]

Dizi Formülüdür ctrl + shift + enter yapmanız gerekir.

=TOPLA(EĞER(SIKLIK(EĞER((($D$2:$D$1000<>"")*($A$2:$A$1000<=J3)*($A$2:$A$1000>=I3)*($E$2:$E$1000=K3)*($F$2:$F$1000=L3));KAÇINCI($D$2:$D$1000;$D$2:$D$1000;0));SATIR($D$2:$D$1000)-SATIR($D$2)+1);1))

 

[Levent Menteşoğlu]

N3 hücresine aşağıdaki yazarak deneyin.

=TOPLA(EĞER(SIKLIK(SATIR($D$1:$D$123);KAÇINCI($D$1:$D$123;$D$1:$D$123;0)*($A$1:$A$123>=J3)*($A$1:$A$123<=K3)*($E$1:$E$123=L3)*($F$1:$F$123=M3))>0;1;0))

 

[Suddedly]

Günaydın arkadaşlar. Akşam dışarıda olduğum için cevap yazamadım kusura bakmayın. Ekte dosyada gönderdiğiniz son 3 formülü de denedim. Yanlış uygulamadıysam eğer @tsoyts un formülü olması gerektiği gibi sonuç verdi. Hepinize çok teşekkür ederim.

 

[Ömer]

Kullanılan tüm formüllerin mantığı aynı zaten. Sorunuz çözülmüş, sadece uygulamadaki hatanızı belirtlemek için yazıyorum.

N4 deki formülü yanlış uygulamışsınız. Formül ölçütlerinde kullandığınız L3, M3, J3 ve K3 hücreleri yerine L4, M4,J4 ve K4 yazmanız gerekirdi.
Formülün sonundaki dizinin SATIR(F$1:$F$150)-SATIR(F$1)+1, +1 değerini silerek uygulamışsınız.
Ayrıca verileriniz 2. satırdan başladığı için aralıkları 1 den değil 2 den başlatmanız daha doğru olacaktır.
Son hali:

=BAĞ_DEĞ_SAY(1/SIKLIK(EĞER(E$2:E$150=L4;EĞER(F$2:F$150=M4;EĞER(A$2:A$150>=J4;EĞER(A$2:A$150<=K4
;KAÇINCI(D$2:D$150;D$2:D$150;0)))));SATIR(F$2:$F$150)-SATIR(F$2)+1))

 

[Suddedly]

Uyarılarınız için teşekkür ederim. Formülü çalıştıramayınca kendimce bir şeyler denedim hata yapmış olabilirim. Tekrar sağ olun

 

[cakto]

kolay gelsin bende ekli tabloda sevk durumu geç,erken,zamanında,sevkedilmedi durumlarının ayrı ayrı sipariş sayısını almak istiyorum.
Teşekkürler

 

[Ömer]

kolay gelsin bende ekli tabloda sevk durumu geç,erken,zamanında,sevkedilmedi durumlarının ayrı ayrı sipariş sayısını almak istiyorum.
Teşekkürler

Merhaba,

Stok kodu hesaplamaya etken değil sanırım.
"sevk edilmedi" için örnek formül:

Dizi formülüdür.

=BAĞ_DEĞ_SAY(1/SIKLIK(EĞER(C$2:C$1100="sevk edilmedi";KAÇINCI(A$2:A$1100;A$2:A$1100;0));SATIR(A$2:$A$1100)-SATIR(A$2)+1))

 

[cakto]

Teşekkür ederim işimi gördü

 

[Haluk]

Alternatif olarak, Pivot Tablo ile basitçe elde edilebilir.




.

 

[cakto]

Teşekkür ederim işimi gördü

Alternatif olarak, Pivot Tablo ile basitçe elde edilebilir.


Ekli dosyayı görüntüle 242220

.

FORMÜLLE HALLETMEM LAZIMDI TŞK EDERİM pivot table ile kaç farklı sipariş nasıl alırım