tabloda 2 veri karşılaştırarak veri getirme nasıl yapılır

[vakyn]

Merhabalar aynı anda 2 veriyi eşleştirmek eşit olmaları durumunda paket numaralarını getirmek istiyorum ekte bulunan excel içerisinde anlattım yardımcı olabilirseniz çok sevinirim.

 

[Ali]

DK2 hücresine

=EĞER(D2="";"";DÜŞEYARA(D2;Sayfa2!$D$2:$DK$500;112;0))

yazıp aşağı doğru çekiniz.

 

[vakyn]

bu formül tam verim vermiyor hocam değer hatası alıyorum çaprazara ile haletmemiz mümkün olur mu öyle düşünüyorum da.

 

[vakyn]

güncel

 

[relaxim]

Merhaba, Deneyebilir misiniz?

=EĞER(D2="";"";DÜŞEYARA(D2;Sayfa2!D2:K500;112;0))

 

[Ali]

Tekrar kontrol ediniz D1 hücresine sütun formülü yazmıştım onu değiştirdim.

 

[vakyn]

Deneme listemi paylaşsam uygulama ihtimaliniz olurmu acaba 2. sekmedeki eski listedeki verileri A:A VE B:B sütunları eşleştirerek çekmek istiyorum.

 

[Ali]

Sayfa1 C2 hücresine

=EĞERHATA(İNDİS('eski liste'!$B$2:$B$8000;KAÇINCI(1;EĞER('eski liste'!$A$2:$A$8000=A2;EĞER('eski liste'!$C$2:$C$8000=D2;1));0));"")

yazıp CTRL+SHIFT+ENTER tuşuna basarak dizi formülü oluşturup aşağı doğru çekiniz.

Office 365 olmadığı için dizi formülsüz alternatif veremedim.

 

[Korhan Ayhan]

"eski liste" sayfasında iki kritere göre filtre uyguladım. Siz arama yaptığınızda görseldeki B sütunundaki hangi değere ulaşmak istiyorsunuz. Çünkü aynı kriterlere ait birden fazla eşleşme var..

 

[vakyn]

"eski liste" sayfasında iki kritere göre filtre uyguladım. Siz arama yaptığınızda görseldeki B sütunundaki hangi değere ulaşmak istiyorsunuz. Çünkü aynı kriterlere ait birden fazla eşleşme var..

Ekli dosyayı görüntüle 249735

Merhabalar Korhan hocam öncelikle konuma uğradığınız için teşekkür ederim.
özetle problemim şu şekildedir, A:A sütunu (birden fazla aynı isim olabiliyor marka ismi gibi düşünelim) ile "eski liste" de bulunan A:A sütununu
B:B sütunu (markanın alt dalı model gibi düşünelim) ile "eski liste" de bulunan B:B sütunumu
Karşılaştırma yapacağım ve karşılaştırma sonucunda aynı olan değerlere karşılık olarak "eski liste" de bulunan xxxxx yani DD sütunundaki verileri "sayfa1" re almak istiyorum fakat yapamadım Korhan hocam birkaç formül denedim ama tutarsızlık sağladı istediğim verimi alamadım sizin önerilerinizi bekliyorum teşekkürler.

 

[Korhan Ayhan]

Paylaştığım görsele göre 2 kritere göre (A ve C sütunları) B sütunundaki hangi değere ulaşmak istiyorsunuz?

Kritere uyan birden fazla satır var. Yani eski listede mükerrer veriler var..

 

[vakyn]

Paylaştığım görsele göre 2 kritere göre (A ve C sütunları) B sütunundaki hangi değere ulaşmak istiyorsunuz?

Kritere uyan birden fazla satır var. Yani eski listede mükerrer veriler var..

Korhan hocam C sütununu getirmek istiyorum örnek bir çalışma yaptım formül üzerinden ama formülde bir sorun var sanırım aşağı çekince bozuluyor sorun varmı diye bakabilir misiniz veya oraya altarnatif bir formük öneriniz olur mu.

 

[Korhan Ayhan]

Deneyiniz.

=EĞERHATA(ÇAPRAZARA(1;('eski liste'!$A$2:$A$10000=A2)*('eski liste'!$B$2:$B$10000=B2);'eski liste'!$C$2:$C$10000)&"";"")

Ya da;

=EĞERHATA(@FİLTRE('eski liste'!$C$2:$C$10000;('eski liste'!$A$2:$A$10000=A2)*('eski liste'!$B$2:$B$10000=B2))&"";"")

 

[vakyn]

Deneyiniz.

=EĞERHATA(ÇAPRAZARA(1;('eski liste'!$A$2:$A$10000=A2)*('eski liste'!$B$2:$B$10000=B2);'eski liste'!$C$2:$C$10000)&"";"")

Ya da;

=EĞERHATA(@FİLTRE('eski liste'!$C$2:$C$10000;('eski liste'!$A$2:$A$10000=A2)*('eski liste'!$B$2:$B$10000=B2))&"";"")

Hocam elinize sağlık formülleriniz her zamanki gibi mükemmel