Makroyu Tekrar Ettirme

[MSCRoMuLuS]

Arkadaşlar merhaba,
Bir firmanın çalışanlarının daha önce hazırlanmış görev formlarının üzerinden güncelleme yapıyorum. Ne yazık ki aynı excel sayfasında onlarca form var ama bazı standart kelimelerde var.

Şimdi amacım aynı kitaptaki onlarca forma aynı ifadeyi ekletmek. Şöyle bir makro yazdım kendimce.

Sub gorevformu()
Range("A:d").Find("şehirdışında").EntireRow.Insert
Range("A:d").Find("şehirdışında").Select
ActiveCell.Offset(-1,0).Resize(1,4).Select
Selection.Merge True
ActiveCell.FormulaR1C1=_
"Amirinin verdiği bütün işleri eksiksiz yapmak"
Selection.Font.Bold = False
End Sub

Bu makrodan sonra 50 tane görev formuda olsa her çalıştırdığımda sadece ilk Şehirdışında kelimesini bulup önün üstünü birleştirip cümlemi ekliyor. Diğer görev formlarına gitmiyor. Diğer formlarda ki kelimeyi bulup nasıl kullanabilirim.

Biliyorum genellikle örnek dosya istiyorsunuz ama İnternete kapalı firmada çalıştığım için telefondan konu açıyorum, gerekirse akşam evimde bir form oluşturup ekleyebilirim. Şimdiden teşekkürler.

 

[yanginci34]

Merhaba her form için ayrı sayfa mı var ?

 

[ÖmerBey]

Merhaba,
Findnext ile sonraki değeri buldurabilirsiniz.
Örnek olarak aşağıdaki kodu deneyiniz. Örnek dosya üzerinde denenmediği için hata oluşma olasılığının yüksek olduğunu unutmayınız.

Sub gorevformu()
Dim bul As Range
Set bul = Range("A:d").Find("şehirdışında")
sat = bul.Row + 1
Do
    bul.EntireRow.Insert
    With bul.Offset(-1, 0).Resize(1, 4)
        .Merge True
        .FormulaR1C1 = "Amirinin verdiği bütün işleri eksiksiz yapmak"
        .Font.Bold = False
    End With
    Set bul = Range("A:D").FindNext(bul)
Loop While bul.Row > sat
End Sub

 

[MSCRoMuLuS]

Merhaba her form için ayrı sayfa mı var ?

Hayır. Aksine her çalışma kitabında 50 60 kadar toplamda 5000 civarında form Var. Benim makromda hep ilk forma istediğim cümleyi yazıyor

 

[HücrelereFısıldayanAdam]

Loop While bul.Row > sat

Ömer üstad, makronun durma koşulu eksik olabilir.

 

[ÖmerBey]

makronun durma koşulu eksik olabilir.

Belki olabilir, kapsamlı test etme imkanım olmadı.
Yaptığım denemede problem olmamıştı, ancak farklı senaryolarda belki olabilir.
Hata denetimi de içermesi açısından aşağıdaki kod kullanılabilir.

Sub gorevformu()
Dim bul As Range, sat As Long
Set bul = Range("A:d").Find("şehirdışında")
If bul Is Nothing Then
    MsgBox "Veri bulunamadı."
    Exit Sub
End If
Do
    bul.EntireRow.Insert
    With bul.Offset(-1, 0).Resize(1, 4)
        .Merge True
        .FormulaR1C1 = "Amirinin verdiği bütün işleri eksiksiz yapmak"
        .Font.Bold = False
    End With
    sat = bul.Row
    Set bul = Range("A:D").FindNext(bul)
Loop While bul.Row > sat
End Sub

 

[MSCRoMuLuS]

Belki olabilir, kapsamlı test etme imkanım olmadı.
Yaptığım denemede problem olmamıştı, ancak farklı senaryolarda belki olabilir.
Hata denetimi de içermesi açısından aşağıdaki kod kullanılabilir.

Sub gorevformu()
Dim bul As Range, sat As Long
Set bul = Range("A:d").Find("şehirdışında")
If bul Is Nothing Then
    MsgBox "Veri bulunamadı."
    Exit Sub
End If
Do
    bul.EntireRow.Insert
    With bul.Offset(-1, 0).Resize(1, 4)
        .Merge True
        .FormulaR1C1 = "Amirinin verdiği bütün işleri eksiksiz yapmak"
        .Font.Bold = False
    End With
    sat = bul.Row
    Set bul = Range("A:D").FindNext(bul)
Loop While bul.Row > sat
End Sub

Elinize sağlık sorunsuz çalıştı.
Çok teşekkür ederim.
Önünüzde saygıyla eğiliyorum.

 

[ÖmerBey]

Rica ederim,
İyi çalışmalar diliyorum.