İnternetten Veri Alma

mekist · 30 Haziran 2024

Merhaba

Şirketlere ait mali tablolar, fiyatları ve hedef fiyatları @Haluk Bey' in yönlendirmesiyle Json yöntemiyle çekiyorum
Aşağıdaki alanları da aynı yöntemle alınabiliyor mu diye epeyce baktım ama sitenin arka planında bunların tutulduğu yeri göremedim, sadece dış veri al yöntemiyle aldırıyor
Bu alanları tablo haricinde alma yöntemi var mıdır

ADEL - Adel Kalemcilik Hisse Senedi | İş Yatırım

Adel Kalemcilik Hisse Senedi fiyatları, yorumları ve değişimlerini grafiklerle anlık olarak takip edip, güncel ve geriye dönük verilere ulaşmak için tıklayın!

www.isyatirim.com.tr

Haluk · 30 Haziran 2024

Size 100 $ değerinde bilgi;

- Aşağıdaki kodda belirtilen URL ile sözkonusu veriler JSON formatında alınabilir,

- Burada önemli olan URL'in kendisi ve bu URL'e yine kodda belirtilen JSON formatındaki "PayLoad" verisini "POST" metoduyla sunucuya "JSON Formatında" bir istek gönderileceği hususunu da belirterek gönderip, geri dönen cevabı (koddaki strJSON değişkeninin içeriği) ayıklayarak, sayfaya istediğiniz gibi yazdırmaktır.

Aşağıdaki kod, verileri "MsgBox" fonksiyonuyla göstermektedir, ayıklayıp sayfaya yazdırma kısmını da siz yaparsınız artık....

C#:

Sub Test()
'   Haluk - 30/06/2024
'
    Dim objHTTP As Object, strURL As String, PayLoad As String, strJSON As String
  
    Set objHTTP = CreateObject("MSXML2.XMLHTTP.6.0")
  
    strURL = "https://www.isyatirim.com.tr/_layouts/15/IsYatirim.Website/StockInfo/CompanyInfoAjax.aspx/GetSermayeArttirimlari"
  
  
    PayLoad = "{""hisseKodu"": ""ADEL"", ""hisseTanimKodu"": """", ""yil"":2024, ""zaman"":""HEPSI"", ""endeksKodu"":""09"",""sektorKodu"":""""}"
  
    objHTTP.Open "POST", strURL, False
    objHTTP.SetRequestHeader "content-type", "application/json"
    objHTTP.send PayLoad
  
    strJSON = objHTTP.responseText
  
    MsgBox strJSON
  
    Set objHTTP = Nothing
End Sub

.

mekist · 30 Haziran 2024

@Haluk Bey

Teşekkür ederim
Ancak sizin paylaştığınız sermaye artırımı sayfası için, "Temettü Gerçekleşen/Planlanan " ve "Yabancı Oranları" sayfalarındaki veriler lazım

Yabacı oranlar için bu link var istenen veri gelmiyor

/_layouts/15/IsYatirim.Website/StockInfo/CompanyInfoAjax.aspx/GetYabanciOranlarXHR

Haluk · 30 Haziran 2024

Eğer yine yanlış anlamadıysam, aradığınız veriler bu kodla alınabiliyor......

C#:

Sub Test3()
'   Haluk - 30/06/2024
    
    Dim xmlHTTPReq As Object
    Dim HTMLdoc As Object
    Dim strURL As String
    Dim noRows As Integer, i As Integer, j As Integer
    
    Set xmlHTTPReq = CreateObject("MSXML2.XMLHTTP.6.0")
    Set HTMLdoc = CreateObject("HTMLFILE")

    strURL = "https://www.isyatirim.com.tr/tr-tr/analiz/hisse/Sayfalar/sirket-karti.aspx?hisse=ADEL"
    xmlHTTPReq.Open "GET", strURL, False
    xmlHTTPReq.send
   
    If xmlHTTPReq.Status = 200 Then
        Range("A1:H" & Rows.Count) = ""
        HTMLdoc.body.innerHTML = xmlHTTPReq.responseText
        HTMLdoc.Close
        
        Set Tables = HTMLdoc.getElementsByTagName("tbody")
        Set myTable = Tables(12)

        noRows = myTable.Rows.Length
        
        For j = 0 To myTable.Rows(0).Cells.Length - 1
            If j >= 2 And j < 7 Then
                Cells(1, j + 1) = Tables(11).Rows(i).Cells(j).innerText + 0
            Else
                Cells(1, j + 1) = Tables(11).Rows(i).Cells(j).innerText
            End If
        Next
        
        For i = 0 To noRows - 1
            For j = 0 To myTable.Rows(i).Cells.Length - 1
                If j >= 2 And j < 7 Then
                    Cells(i + 2, j + 1) = myTable.Rows(i).Cells(j).innerText + 0
                Else
                    Cells(i + 2, j + 1) = myTable.Rows(i).Cells(j).innerText
                End If
            Next
        Next
    End If
    
    Set Tables = Nothing
    Set myTable = Nothing
    Set HTMLdoc = Nothing
    Set xmlHTTPReq = Nothing
End Sub

.

mekist · 30 Haziran 2024

çok teşekkür ederim, evet istediğim buydu
Allah razı olsun

Haluk · 30 Haziran 2024

O zaman, yukarıda 4. No'lu mesajda elini yüzünü biraz önce düzelttiğim revize şeklini kullanın bence...

Not: Aşağıdaki linkte yer alan konu da size mi ait?

vba - How do I pull data from a website to excel? - Stack Overflow

.

mekist · 30 Haziran 2024

12 tabloyu son verdiğinizden aldım
17 tablo için önceden verdiğiniz koddan aldım, son verdiğinizde değiştirdim ama beceremedim

Belirttiğiniz linkteki konu bana ait değil

mekist · 5 Temmuz 2024

@Haluk Bey Merhaba

Verdiğiniz kodlarla veriyi alıyorum, Başlık kısmında bulunan tarih alanı sitede seçilebilir durumda, bunu kod içerisinde yapmak mümkün müdür

EREGL - Ereğli Demir Çelik Hisse Senedi | İş Yatırım

Ereğli Demir Çelik Hisse Senedi fiyatları, yorumları ve değişimlerini grafiklerle anlık olarak takip edip, güncel ve geriye dönük verilere ulaşmak için tıklayın!

www.isyatirim.com.tr

Haluk · 5 Temmuz 2024

Aşağıdaki kodla verileri aldıktan sonra ayıklarsınız...

C#:

Sub Tes4()
'   Haluk - 05/07/2024
'
    Dim objHTTP As Object, strURL As String, PayLoad As String, strJSON As String

    Set objHTTP = CreateObject("MSXML2.XMLHTTP.6.0")

    strURL = "https://www.isyatirim.com.tr/_layouts/15/IsYatirim.Website/StockInfo/CompanyInfoAjax.aspx/GetYabanciOranlarXHR"

    PayLoad = "{""baslangicTarih"":""02-07-2024"",""bitisTarihi"":""04-07-2024"",""sektor"":null,""endeks"":""09"",""hisse"":""EREGL""}"

    objHTTP.Open "POST", strURL, False
    objHTTP.SetRequestHeader "content-type", "application/json"
    objHTTP.send PayLoad

    strJSON = objHTTP.responseText

    MsgBox strJSON

    Set objHTTP = Nothing
End Sub

.

Haluk · 5 Temmuz 2024

Verilerin ayıklanmasını yapamadıysanız, daha önceki konu için aşağıdaki linkte yer alan dosyayı kullanın.

webde tablo gibi görünen yerdeki verileri aktarma

Dosyanız ektedir.... eklediğiniz modulleri silip, tekrar ekledim. Başka da birşey yapmadım, şimdi çalışıyor...... .

www.excel.web.tr

Orada, "Module2" içindeki kodları silin ve aşağıdakini kullanın....

C#:

Sub Test5()
    Dim objHTTP As Object, strURL As String, PayLoad As String
    Dim Json As Object, Item As Object, i As Integer
 
    Set objHTTP = CreateObject("MSXML2.XMLHTTP.6.0")
 
    strURL = "https://www.isyatirim.com.tr/_layouts/15/IsYatirim.Website/StockInfo/CompanyInfoAjax.aspx/GetYabanciOranlarXHR"
 
    PayLoad = "{""baslangicTarih"":""02-07-2024"",""bitisTarihi"":""04-07-2024"",""sektor"":null,""endeks"":""09"",""hisse"":""EREGL""}"
 
    objHTTP.Open "POST", strURL, False
    objHTTP.SetRequestHeader "content-type", "application/json"
    objHTTP.send PayLoad
      
    Set Json = ParseJson(objHTTP.responseText)
    i = 2
    
    For Each Item In Json("d")
        Range("A" & i) = Item("HISSE_KODU")
        Range("B" & i) = Item("PRICE_TL")
        Range("C" & i) = Item("DEGISIM")
        Range("D" & i) = Item("ETKI")
        Range("E" & i) = Trim(Item("HISSE_TANIM"))
        i = i + 1
    Next
End Sub

.

mekist · 5 Temmuz 2024

Teşekkür ederim, bende ona bakıyordum
Muhtemelen yapamazdım

mekist · 6 Temmuz 2024

@Haluk Bey Merhaba

Hisse isimin değişken yapmak istedim, Normalde sayfa ismi ve hücre adresi " " içerisinde yazılır, burada hata veriyor
Aşağıdaki gibi yapınca makro çalışıyor, diğer yandan muhtemelen hücreyi göremediği için birşey getirmiyor
Şirket ismini değişken nasıl yapılabilir

Kod:

Sub Yabancı_Oranı_1()
    Dim objHTTP As Object, strURL As String, PayLoad As String
    Dim JSon As Object, Item As Object, i As Integer
    
    tStart = Timer
    
    Set objHTTP = CreateObject("MSXML2.XMLHTTP.6.0")
 
    strURL = "https://www.isyatirim.com.tr/_layouts/15/IsYatirim.Website/StockInfo/CompanyInfoAjax.aspx/GetYabanciOranlarXHR"
 
    PayLoad = "{""baslangicTarih"":""03-07-2024"",""bitisTarihi"":""04-07-2024"",""sektor"":null,""endeks"":""09"",""hisse"":""Sheets(Sayfa1).Range(H1)""}"
    
    objHTTP.Open "POST", strURL, False
    objHTTP.SetRequestHeader "content-type", "application/json"
    objHTTP.send PayLoad
      
    Set JSon = ParseJson(objHTTP.responseText)
    i = 2
    
    For Each Item In JSon("d")
        Range("A" & i) = Item("HISSE_KODU")
        Range("B" & i) = Item("YAB_ORAN_START")
        Range("C" & i) = Item("YAB_ORAN_END")
        Range("D" & i) = Item("DEGISIM")
        Range("E" & i) = Item("ETKI")
        i = i + 1
    Next
    
    tEnd = Timer
    
    myMsg = "Veriler " & Format(tEnd - tStart, "0.00") & " saniyede alınmıştır..."
            
    MsgBox myMsg, vbInformation, "Bilgi..."
    
End Sub

Haluk · 6 Temmuz 2024

Kusura bakmayın, bu kadarını yapabilmeniz gerekir diye düşünüyorum....

.

mekist · 6 Temmuz 2024

internet sitelerine baktım, PayLoad için değişken yapmayı bulamadım
Önceki süreçler için teşekkür ederim

Haluk · 6 Temmuz 2024

Örneğin aktif sayfanın K2 hücresinde hisse kodu olarak EREGL yazıyorsa;

C#:

    PayLoad = "{""baslangicTarih"":""02-07-2024"",""bitisTarihi"":""04-07-2024"",""sektor"":null,""endeks"":""09"",""hisse"":""" & Range("K2") & """}"

Eğer K2 hücresi boşsa, bütün şirketlere ait veriler alınır...

.

mekist · 6 Temmuz 2024

Yardımınız için teşekkür ederim
Aşağıdaki gibi hata verdi

Haluk · 6 Temmuz 2024

Sunucudan JSON değil de HTML formatında bir cevap aldığınıza göre muhtemelen bir hata mesajı içeriyordur aldığınız cevap.

Belki sunucuya çok fazla istek yolladıysanız, IP adresiniz belli bir süreliğine yasaklanmış olabilir.... ya da başka bir hata yapıyorsunuz. Ben size bendeki çalışan dosyayı vereyim, deneyin. Eğer yine hata alırsanız büyük ihtimalle dediğim gibi IP adresiniz yasaklanmıştır.

.

Haluk · 7 Temmuz 2024

Bu arada, şimdi dikkatimi çekti.... 16 No'lu mesaja eklediğiniz ekran görüntüsünde;

Kod:

Payload = PayLoad .....

yazmışsınız, muhtemelen hata nedeni bu yazım hatasıdır..

.

mekist · 7 Temmuz 2024

@Haluk Bey

bende onu sonradan fark ettim, çok soğolun

Ekteki gibi döngü kurdum, daha kısa yolu var mıdır bilemedim

Haluk · 7 Temmuz 2024

C#:

Sub Test7()
    Dim objHTTP As Object, strURL As String, PayLoad As String
    Dim Json As Object, Item As Object, j As Integer
        
    Set objHTTP = CreateObject("MSXML2.XMLHTTP.6.0")
 
    strURL = "https://www.isyatirim.com.tr/_layouts/15/IsYatirim.Website/StockInfo/CompanyInfoAjax.aspx/GetYabanciOranlarXHR"
    
    For j = 2 To Range("F" & Rows.Count).End(xlUp).Row
        PayLoad = "{""baslangicTarih"":""" & Range("F" & j) & """,""bitisTarihi"":""" & Range("G" & j) & """,""sektor"":null,""endeks"":""09"",""hisse"":""" & Range("I1") & """}"
        
        objHTTP.Open "POST", strURL, False
        objHTTP.SetRequestHeader "content-type", "application/json"
        objHTTP.send PayLoad
          
        Set Json = ParseJson(objHTTP.responseText)
        
        For Each Item In Json("d")
            Range("A" & j) = Item("HISSE_KODU")
            Range("B" & j) = Item("YAB_ORAN_START")
            Range("C" & j) = Item("YAB_ORAN_END")
            Range("D" & j) = Item("DEGISIM")
            Range("E" & j) = Item("ETKI")
        Next
    Next
End Sub

.

İnternetten Veri Alma

mekist

ADEL - Adel Kalemcilik Hisse Senedi | İş Yatırım

Haluk

Özel Üye

mekist

Haluk

Özel Üye

mekist

Haluk

Özel Üye

mekist

Ekli dosyalar

mekist

EREGL - Ereğli Demir Çelik Hisse Senedi | İş Yatırım

Haluk

Özel Üye

Haluk

Özel Üye

webde tablo gibi görünen yerdeki verileri aktarma

mekist

mekist

Haluk

Özel Üye

mekist

Haluk

Özel Üye

mekist

Haluk

Özel Üye

Ekli dosyalar

Haluk

Özel Üye

mekist

Ekli dosyalar

Haluk

Özel Üye