İki Hücredeki Veriye Göre Değer Atasın

[poetika]

Ekteki excel dosyasında, E2 ve F2 deki değerlere göre I1 sütununa ilgili katsayı değerini atasın istiyorum. Yardımcı olur musunuz?

 

[relaxim]

Merhaba
Deneyebilir misiniz?
=TOPLA.ÇARPIM((A2:A25=$F$2)*(B2:B25=$E$2)*(C2:C25))

 

[poetika]

Merhaba
Deneyebilir misiniz?
=TOPLA.ÇARPIM((A2:A25=$F$2)*(B2:B25=$E$2)*(C2:C25))

Teşekkür ederim, çalıştı.

 

[Korhan Ayhan]

Merhaba,

Küçük ama faydalı ve önemli bir bilgiyi paylaşmak isterim...

Arama işlemlerinde TOPLA.ÇARPIM fonksiyonu "Hedef Tablo" tarafında aynı veriden birden fazla olması durumu varsa kullanımı risklidir.

Örneklersek;

Dosyanızda OCAK ve 2024 kriterleri seçilmiş. Bu haliyle formül size doğru sonucu veriyor gibi görünüyor.

A14 hücresindeki 2025 değerini 2024 olarak değiştirirseniz formül hatalı sonuç döndürecektir. Çünkü aynı kriterden birden fazla olduğunda önerilen formül bunların toplamını size döndürecektir.

Diyebilirsiniz ki benim hedef tablomda her veri tekil olacak. Bu sebeple böyle bir riskim yok.

Bu durumda alternatif olarak aşağıdaki formülde aynı sonucu verecektir.

=ÇOKETOPLA(C:C;A:A;F2;B:B;E2)

Ama ben olsam aşağıdaki formülü tercih ederdim.

Eski sürümler için;

=İNDİS(C2:C25;TOPLA.ÇARPIM(KAÇINCI(F2&E2;A2:A25&B2:B25;0)))

Ofis 365 için alternatifler (daha fazla seçenek eklenebilir...) ;

=ÇAPRAZARA(1;(A2:A25=F2)*(B2:B25=E2);C2:C25)

=@FİLTRE(C2:C25;(A2:A25=F2)*(B2:B25=E2))

=İNDİS(FİLTRE(C2:C25;(A2:A25=F2)*(B2:B25=E2));1)

=İNDİS(C2:C25;KAÇINCI(F2&E2;A2:A25&B2:B25;0))

=İNDİS(C2:C25;ÇAPRAZEŞLEŞTİR(1;(A2:A25=F2)*(B2:B25=E2);0))

 

[relaxim]

Korhan Hocam merhaba

Detaylı açıklama için teşekkürler. Aynı veriden birden fazla olmayacağını düşünerek bu şekilde bıraktım.
İndis ve kaçıncı ile yapılması daha sağlıklı olacaktır.

 

[poetika]

Merhaba,

Küçük ama faydalı ve önemli bir bilgiyi paylaşmak isterim...

Arama işlemlerinde TOPLA.ÇARPIM fonksiyonu "Hedef Tablo" tarafında aynı veriden birden fazla olması durumu varsa kullanımı risklidir.

Örneklersek;

Dosyanızda OCAK ve 2024 kriterleri seçilmiş. Bu haliyle formül size doğru sonucu veriyor gibi görünüyor.

A14 hücresindeki 2025 değerini 2024 olarak değiştirirseniz formül hatalı sonuç döndürecektir. Çünkü aynı kriterden birden fazla olduğunda önerilen formül bunların toplamını size döndürecektir.

Diyebilirsiniz ki benim hedef tablomda her veri tekil olacak. Bu sebeple böyle bir riskim yok.

Bu durumda alternatif olarak aşağıdaki formülde aynı sonucu verecektir.

=ÇOKETOPLA(C:C;A:A;F2;B:B;E2)

Ama ben olsam aşağıdaki formülü tercih ederdim.

Eski sürümler için;

=İNDİS(C2:C25;TOPLA.ÇARPIM(KAÇINCI(F2&E2;A2:A25&B2:B25;0)))

Ofis 365 için alternatifler (daha fazla seçenek eklenebilir...) ;

=ÇAPRAZARA(1;(A2:A25=F2)*(B2:B25=E2);C2:C25)

=@FİLTRE(C2:C25;(A2:A25=F2)*(B2:B25=E2))

=İNDİS(FİLTRE(C2:C25;(A2:A25=F2)*(B2:B25=E2));1)

=İNDİS(C2:C25;KAÇINCI(F2&E2;A2:A25&B2:B25;0))

=İNDİS(C2:C25;ÇAPRAZEŞLEŞTİR(1;(A2:A25=F2)*(B2:B25=E2);0))

Teşekkür ederim.