İki tarih arasında istenilen aydan kaç gün olduğunu bulma

[SERVET AKY]

Herkese merhaba,A1 ve B1 hücrelerinde iki tarih olsun. Ben bir açılır liste ile örneğin OCAK seçtiğimde bu tarihler arası ocak ayının kaç günü var veya mart seçtiğimde ilgili ayın kaç günü var getirmek istiyorum. Yardımınızı rica ederim.

 

[catalinastrap]

A1= 01.01.2025 B=11.03.2025 C=MART E= ?

E Hücresine ne yazsın mantığı anlamadım

 

[Korhan Ayhan]

Deneyiniz.

Eğer Türkçe sürüm kullanıyorsanız formülü çevirirsiniz.

=SUMPRODUCT(--(TEXT(ROW(INDIRECT(A1&":"&B1));"aaaa")=C1))

 

[yyhy]

@Korhan Ayhan hocam formülü Türkçeye çevirdim çalıştıramadım. Acaba Türkçe olarak ekleyebilir misiniz?

 

[mustafa1205]

=TOPLA.ÇARPIM(--(METNEÇEVİR(SATIR(DOLAYLI(A1&":"&B1));"gggg")=C1))
Deneyiniz

 

[Ali]

@Korhan Ayhan hocam formülü Türkçeye çevirdim çalıştıramadım. Acaba Türkçe olarak ekleyebilir misiniz?

Fonksiyonları aşağıdaki linkten Türkçeye otomatik çevirebilirsiniz.

Bİrçok dil desteği vardır.

Translator

The online tool for the translation of Excel formulas and functions from one language to another. Supports the replacement of argument separators, 35 languages and much more.

en.excel-translator.de

 

[SERVET AKY]

A1= 01.01.2025 B=11.03.2025 C=MART E= ?

E Hücresine ne yazsın mantığı anlamadım

Örnek verecek olursam 17/01/2025-08/02/2025 tarihleri arası işçi izin kullanmış .Bunun kaç günü ocak ayının kaç günü şubat ayının bunu bulmak istiyorum.

 

[SERVET AKY]

Deneyiniz.

Eğer Türkçe sürüm kullanıyorsanız formülü çevirirsiniz.

=SUMPRODUCT(--(TEXT(ROW(INDIRECT(A1&":"&B1));"aaaa")=C1))

Korhan bey sonuç 0 dönüyor.

 

[Ali]

Bu da uzun versiyonu

=MAK(0; MİN(B1; TARİH(YIL(B1); AY(TARİHSAYISI("1 " & C1 & " " & YIL(B1))); GÜN(SERİAY(TARİHSAYISI("1 " & C1 & " " & YIL(B1)); 0)))) - MAK(A1; TARİH(YIL(A1); AY(TARİHSAYISI("1 " & C1 & " " & YIL(A1))); 1)) + 1)

 

[Ali]

Korhan Bey'in verdiğini

=TOPLA.ÇARPIM(--(METNEÇEVİR(SATIR(DOLAYLI(A1&":"&B1));"aaaa")=C1))

şeklinde kullanacaksınız. gggg gün demek olur sıfır döndürür.

 

[yyhy]

Tüm arkadaşlara teşekkür ederim. Güzel bir yöntem.

 

[SERVET AKY]

Ekli dosyayı görüntüle 255989

Bu da uzun versiyonu

=MAK(0; MİN(B1; TARİH(YIL(B1); AY(TARİHSAYISI("1 " & C1 & " " & YIL(B1))); GÜN(SERİAY(TARİHSAYISI("1 " & C1 & " " & YIL(B1)); 0)))) - MAK(A1; TARİH(YIL(A1); AY(TARİHSAYISI("1 " & C1 & " " & YIL(A1))); 1)) + 1)

Metin olarak yazınca doğru sonuç veriyor,tüm arkadaşlara teşekkür ederim.
Başlangıç ve bitiş ayı aynı seçilirse hesaplama yapmıyor,küçük bir ekleme yaptım

=EĞER(AY(B1)=AY(A1);B1-A1+1;(MAK(0;MİN(B1;TARİH(YIL(B1);AY(TARİHSAYISI("1 "&C1&" "&YIL(B1)));GÜN(SERİAY(TARİHSAYISI("1 "&C1&" "&YIL(B1));0))))-MAK(A1;TARİH(YIL(A1);AY(TARİHSAYISI("1 "&C1&" "&YIL(A1)));1))+1)))

 

[yyhy]

Sayın @SERVET AKY Vermiş olduğunuz formülleri inceledim bir örnek dosya hazırladım 2. ve son formülde hatalı çıkarıyor. Örnek dosyayı ekliyorum. İnceleyebilir misiniz?
Örneğin İki tarih arası 3 ayı buluyorsa Ocaktan 20 gün Şubattan 28 gün Marttan 10 gün şeklinde nasıl bir tablo şablon çıkarılabilir?

 

[Korhan Ayhan]

Bu da ofis 365 için alternatif olsun...

=SUM(--(TEXT(SEQUENCE(D4-C4+1;;C4);"aaaa")=E4))

 

[52779]

Örneğin İki tarih arası 3 ayı buluyorsa Ocaktan 20 gün Şubattan 28 gün Marttan 10 gün şeklinde nasıl bir tablo şablon çıkarılabilir?

İstenilen, aşağıdaki tablodaki gibi olabilir. (Başlangıç ve Bitiş Günleri sayıma dahildir.)

	A​	B​	C​	D​	E​	F​	G​	H​	I​	J​	K​
1​	12.01.2022​	17.08.2023​	​	Ocak.22​	20​	​	Ocak.22​	20​		Ocak.22​	20​
2​	​	​	​	Şubat.22​	28​	​	Şubat.22​	28​		Şubat.22​	28​
3​	​	​	​	Mart.22​	31​	​	Mart.22​	31​		Mart.22​	31​
4​	​	​	​	Nisan.22​	30​	​	Nisan.22​	30​		Nisan.22​	30​
5​	​	​	​	Mayıs.22​	31​	​	Mayıs.22​	31​		Mayıs.22​	31​
6​	​	​	​	Haziran.22​	30​	​	Haziran.22​	30​		Haziran.22​	30​
7​	​	​	​	Temmuz.22​	31​	​	Temmuz.22​	31​		Temmuz.22​	31​
8​	​	​	​	Ağustos.22​	31​	​	Ağustos.22​	31​		Ağustos.22​	31​
9​	​	​	​	Eylül.22​	30​	​	Eylül.22​	30​		Eylül.22​	30​
10​	​	​	​	Ekim.22​	31​	​	Ekim.22​	31​		Ekim.22​	31​
11​	​	​	​	Kasım.22​	30​	​	Kasım.22​	30​		Kasım.22​	30​
12​	​	​	​	Aralık.22​	31​	​	Aralık.22​	31​		Aralık.22​	31​
13​	​	​	​	Ocak.23​	31​	​	Ocak.23​	31​		Ocak.23​	31​
14​	​	​	​	Şubat.23​	28​	​	Şubat.23​	28​		Şubat.23​	28​
15​	​	​	​	Mart.23​	31​	​	Mart.23​	31​		Mart.23​	31​
16​	​	​	​	Nisan.23​	30​	​	Nisan.23​	30​		Nisan.23​	30​
17​	​	​	​	Mayıs.23​	31​	​	Mayıs.23​	31​		Mayıs.23​	31​
18​	​	​	​	Haziran.23​	30​	​	Haziran.23​	30​		Haziran.23​	30​
19​	​	​	​	Temmuz.23​	31​	​	Temmuz.23​	31​		Temmuz.23​	31​
20​	​	​	​	Ağustos.23​	17​	​	Ağustos.23​	17​		Ağustos.23​	17​
21​	​	​	​	​	​	​	​	​		​	​
22​	​	​	​	​	​	​	​	​		​	​
23​	​	​	​	​	​	​	​	​		​	​

D1 formül yazılır aşağıya doğru kopyalanır.

=EĞER(SERİAY($A$1;-2+SATIRSAY($A$1:$A1))+1>SERİAY($B$1;-1)+1;"";METNEÇEVİR(SERİAY($A$1;-2+SATIRSAY($A$1:$A1))+1;"aaaa.yy"))

E1 formül yazılır ve aşağıya doğru kopyalanır.

=EĞER(D1="";"";TOPLA.ÇARPIM(--(METNEÇEVİR(SATIR(DOLAYLI($A$1&":"&$B$1));"aaaa.yy")=D1)))

ya da alternatif olarak
G1 hücresine yazılır ve aşağıya doğru kopyalanır. G kolonu Sayı biçimi "aaaa.yy" olarak biçimlendirilir.

=EĞER(SERİAY($A$1;-2+SATIRSAY($A$1:$A1))+1>SERİAY($B$1;-1)+1;"";SERİAY($A$1;-2+SATIRSAY($A$1:$A1))+1)

H1 hücresine yazılır aşağıya doğru kopyalanır.

=EĞER(G1="";"";TOPLA.ÇARPIM(--(SERİAY(SATIR(DOLAYLI($A$1&":"&$B$1));-1)+1=G1)))

Excel365 ile tek hücrede dökülmeli çözüme örnek
J1 hücresine yazılır. Sonuçlar dökülmeli olarak gelecektir.

=LET(a;METNEÇEVİR(SERİAY(A1;-2+SIRALI(1+ETARİHLİ(SERİAY(A1;-1)+1;SERİAY(B1;-1)+1;"m")))+1;"aaaa.yy");b;BYROW(a;LAMBDA(x;TOPLA(--(--x=SERİAY(SIRALI(B1-A1+1;;A1);-1)+1))));EĞER({1;0};a;b))

 

[SERVET AKY]

Sayın @SERVET AKY Vermiş olduğunuz formülleri inceledim bir örnek dosya hazırladım 2. ve son formülde hatalı çıkarıyor. Örnek dosyayı ekliyorum. İnceleyebilir misiniz?
Örneğin İki tarih arası 3 ayı buluyorsa Ocaktan 20 gün Şubattan 28 gün Marttan 10 gün şeklinde nasıl bir tablo şablon çıkarılabilir?

Merhaba,üstte Korhan Bey'in paylaşmış olduğu formül doğru sonuç veriyor,
yine Ali Bey'in formülü de çalışıyor.

 

[yyhy]

Sayın @52779 öncelikle ilginiz için teşekkür ederim.
Vermiş olduğunuz kodları yukarıya eklemiş olduğum Excel çalışma sayfasında yeni bir sayfa açmak suretiyle oluşturdum.
Formül sonucu hata vermektedir. Dosyayı da ekliyorum. Acaba bakma imkanınız var mıdır? teşekkür ederim.

Sayın @52779 harici site dosya linki: https://dosya.co/5gi6hu81x7wb/İki_Tarih_Arasında_İstenilen_Aydan_Kaç_Gün_Olduğunu_Bulma_-_2.xlsx.html

 

[52779]

Sayın @52779 öncelikle ilginiz için teşekkür ederim.
Vermiş olduğunuz kodları yukarıya eklemiş olduğum Excel çalışma sayfasında yeni bir sayfa açmak suretiyle oluşturdum.
Formül sonucu hata vermektedir. Dosyayı da ekliyorum. Acaba bakma imkanınız var mıdır? teşekkür ederim.

Dosyanızı maalesef göremem.
Dosyanızı harici dosya yükleme sitesi kullanarak yükleyebilirseniz bakmaya çalışırım.

 

[yyhy]

Sayın @52779 17. mesajı güncelledim. Harici dosya linki ekledim.

 

[52779]

Aylara Gore Kac Gun - Filemail

Click here to view and download these shared files from Filemail.com

www.filemail.com

Vermiş olduğunuz kodları yukarıya eklemiş olduğum Excel çalışma sayfasında yeni bir sayfa açmak suretiyle oluşturdum.

Tarihleri de mesajdaki tablodan kopya ile aldığınızdan dolayı tarihler METİN... Sayı biçimlendirme Tarih olarak yapılınca formüller çalıştı....

Not : Dosyaya extra bir sayfa eklendi. İncelersiniz... (Klasik formüllerle yapıldı ve formüller sağa ve aşağıya doğru kopyalandı)
Eklenen bu sayfada,
*** Çoklu başlangıç ve bitiş tarihleri var.
*** Bu tarihlerin tamamını içerecek şekilde Aylar, kolonlarda formülle gelmekte.
*** Her bir satırdaki başlangıç ve bitiş tarihlerine göre aylardan kaçar gün varsa sayımları da ilgili satır ve kolonlarda...

Ekleme :
Dosyaya 1 sayfa daha eklendi. Bu sayfada ise, çoklu tarihlere göre ilgili aylardan kaçar gün olduğu, Excel365 formülleriyle tek hücrede bir formül ile komple dökülmeli olarak sonuçlar elde ediliyor.
Dosya ekte... incelersiniz...

Aylara Gore Kac Gun 365 - Filemail

Click here to view and download these shared files from Filemail.com

www.filemail.com