hücreye karşılık gelen satırı almak

myefsane · 28 Ocak 2007

hocam elimde şöle bir tablo var
1.satır 2. satır
rıfat 10 14
recep 20 23
ayşe 30 32

ben bunların toplamının max. değerini isimle birlikte yapmak istiyorum ama max. göre sıraladım ancak en büyük burda 62 ile ayşe söyle olmasını istiyorum.

ayşe 62

umarım derdimi anlatabildim. hangi fonksiyon en büyük değerin adını yazabilir.

Kolay gelsin teşekkürler.

Ali · 28 Ocak 2007

İstediğiniz ekteki gibi birşeymi

a.akyurek · 29 Ocak 2007

myefsane' Alıntı:
hocam elimde şöle bir tablo var
1.satır 2. satır
rıfat 10 14
recep 20 23
ayşe 30 32

ben bunların toplamının max. değerini isimle birlikte yapmak istiyorum ama max. göre sıraladım ancak en büyük burda 62 ile ayşe söyle olmasını istiyorum.

ayşe 62

umarım derdimi anlatabildim. hangi fonksiyon en büyük değerin adını yazabilir.

Kolay gelsin teşekkürler.

D3, aşa kopyala:

=SUM(B3:C3)

G2:

=MAX(D3 : D6)

G3:

=COUNTIF(D3 : D6,G2)

G5:

=IF(ROWS($G$5:G5)<=$G$3,INDEX($A$3:$A$6,SMALL(IF($D$3:$D$6=$G$2,ROW($D$3:$D$6)-ROW($D$3)+1),ROWS($G$5:G5))),"")

Control+shift+enter irdele ve aşa kopyala.

myefsane · 29 Ocak 2007

ali bey şöle açıklamak istiyorum keşke burda tablo yapabilsem

benim amacım grafikte ki en yükse 50 kişi almak istiyorum toplamları alıyorum ama en yüksek değer ve kime ait olduğunu yazmak istiyorum buna benzer ama bu değil

Ali · 29 Ocak 2007

Sanırım A.Akyürek Beyin eklediği dosyayı görmediniz. EĞERSAY ile tüm maksimumlar sayıldığı için sizin ihtiyacınızı görecektir.

Not:Sorunuzu biraz daha net sorabilirseniz daha etkin cevap verebiliriz.

myefsane · 29 Ocak 2007

hocam ekte açok iyi anlattığıma inaıyorum buyrun

Ali · 29 Ocak 2007

Aşağıdaki linki inceleyiniz.

http://www.excel.web.tr/showthread.php?t=23962

Merhum İdris SERDAR · 29 Ocak 2007

myefsane' Alıntı:
hocam ekte açok iyi anlattığıma inaıyorum buyrun

Dosyanız ekte.

myefsane · 29 Ocak 2007

yurttas' Alıntı:
Dosyanız ekte.

Hocam sen bi harikasın eline sağlık keşke burda puan verme olayı olsa.

Hocam baya bi baktım ama mantığı çözemedim zaten bu işin mantığı önemli değil mi mantığını nasıl anlayabilirim bu örnek işimi gördü ama mantığını sökemedim. Yani böle bişe gelse gene yapamıcam ama mantığını öğrenmek istiyorum arkadaşlara yardımları için teşekkür ediyorum.

a.akyurek · 30 Ocak 2007

D2:

=SUM(B2:C2)

I2, control+shift+enter:

=IF(ISNUMBER(J2),INDEX($A$2:$A$5,SMALL(IF($D$2:$D$5=J2,ROW($D$2:$D$5)-ROW($D$2)+1),COUNTIF($J$2:J2,J2))),"")

J2:

=LARGE($D$2:$D$5,ROWS($J$2:J2))

Merhum İdris SERDAR · 30 Ocak 2007

myefsane' Alıntı:
Hocam sen bi harikasın eline sağlık keşke burda puan verme olayı olsa.

Hocam baya bi baktım ama mantığı çözemedim zaten bu işin mantığı önemli değil mi mantığını nasıl anlayabilirim bu örnek işimi gördü ama mantığını sökemedim. Yani böle bişe gelse gene yapamıcam ama mantığını öğrenmek istiyorum arkadaşlara yardımları için teşekkür ediyorum.

İşni mantığını anlamak için formülü parçalamak ve kullanılan işlevin ne işe yaradığını ve sözdizilimini bilmekgerekir.

1. F2'yazılan bu formül, =EĞER(D2="";"";D2-SATIR()/10^10) D2 ve aşağı hücrelerde eşitlik olması durumunda çok ince bir farklılık yaratmak amacına yöneliktir. Ve D2 ve aşağısında değer yoksa boş yazılması amaçlanmıştır.

2. I2'de yer alan =EĞER(EHATALIYSA(BÜYÜK($F:$F;SATIR(A1)));"";İNDİS(A:A;KAÇINCI(BÜYÜK($F:$F;SATIR(A1));$F:$F;0))) formülünü parçalayalım.

BÜYÜK($F:$F;SATIR(A1))) formül parçası F:F aralığında 1. büyük sayıyı verir. 1. SATIR(A1)'den elde edilir. Bu formül parçacığının sonucu 80 bulunur. Eğer bunun sonucu değer olmadığı zaman bize hata verecekse o zaman EĞER(EHATALIYSA formül parçası ile "" yani boşluk bırakmasını sağlarız. Bu nedenle de formülün ikinci parçası devreye girmeyecektir.

2. Yukarıdaki formül parçacığı 80 çıktı. O zaman formülümüzün ikinci parçacığı devreye girecek. Şimdi bu 80'inin kaçıncı satırda yer aldığını bulmak için KAÇINCI fonksiyonu yardımı ile şu formül parçasını elde ederiz. =KAÇINCI(BÜYÜK(F:F;SATIR(A1));F:F) Bunun sonucu 5'tir. Yani bizim 1. büyük sayımız olan 80 sayısı 5 satırda yer aldığını bulduk. Bu sayı A:A'da kime ait olduğunu bulmak için İNDİS fonksiyonundan yararlanırız. Böylece bizim formülümüzün 2. parçası = İNDİS(A:A;KAÇINCI(BÜYÜK($F:$F;SATIR(A1));$F:$F;0)) şeklini alır. Bunun sonucu "iso"dur.

3. I2'de yer alcak formülümüz tamamlanmış ve şu şeklini =EĞER(EHATALIYSA(BÜYÜK($F:$F;SATIR(A1)));"";İNDİS(A:A;KAÇINCI(BÜYÜK($F:$F;SATIR (A1));$F:$F;0))) almıştır. Bunu yana yani, J2'ye kopyalarsak =EĞER(EHATALIYSA(BÜYÜK($F:$F;SATIR(A1)));"";İNDİS(D

;KAÇINCI(BÜYÜK($F:$F;SATIR(A1));$F:$F;0))) D

aralığına bakıp değeri getireceği için bunun sonucu 80 olacaktır.

4. I2 ve J2'de yer alan formüllerimizi aşağıya doğru kopyaladığımızda SATIR(A1) 1.' yi SATIR(A2) 2.yi, SATIR(A3) 3'üncüyü ...... ifade edeceği için veriler büyüklük sırasına girmiş olacaklar.

Umarım anlatabildim.

myefsane · 30 Ocak 2007

yurttas' Alıntı:
Dosyanız ekte.

hocam bunu ingilizceye çevirmeye kalktım ama "EHATALIYSA" bunun karşılığı ne bulamadım

Merhum İdris SERDAR · 30 Ocak 2007

myefsane' Alıntı:
hocam bunu ingilizceye çevirmeye kalktım ama "EHATALIYSA" bunun karşılığı ne bulamadım

ISERROR = EHATALIYSA

hücreye karşılık gelen satırı almak

myefsane

Ali

Uzman

a.akyurek

myefsane

Ali

Uzman

myefsane

Ali

Uzman

Merhum İdris SERDAR

Moderatör

myefsane

a.akyurek

Merhum İdris SERDAR

Moderatör

myefsane

Merhum İdris SERDAR

Moderatör