Sütunun en altındaki hücreden değer alma

[emre1905]

A sütununda alt alta rakamlar listeli, başka bir hücrede formül yazıcam bu formülde A sütunundaki rakamların en altta yazan rakamı formülde kullansın istiyorum.

Bir örnek yaptım umarım anlaşılır, teşekkürler.

 

[Ömer]

Merhaba,

=ARA(2;1/(A1:A65535<>"");A1:A65535)-B1

Denermisiniz..

 

[emre1905]

Çok teşekkür ederim işe yaradı.

 

[Ömer]

Rica ederim.

&#304;yi &#231;al&#305;&#351;malar..

 

[Merhum İdris SERDAR]

http://www.excel.web.tr/showthread.php?t=18290

Bir de buradaki dosyay&#305; inceleyin.

.

 

[betoncu]

Merhaba,

=ARA(2;1/(A1:A65535<>"");A1:A65535)-B1

Denermisiniz..

Merhaba.
Bu formülde bulunan 2 rakamı neyi ifade ediyor acaba?
Açıklarmısınız.

 

[Merhum İdris SERDAR]

Merhaba.
Bu formülde bulunan 2 rakamı neyi ifade ediyor acaba?
Açıklarmısınız.

=LOOKUP(2,1/(1-ISBLANK(A1:A65535)),A1:A65535)

Veya

=LOOKUP(2;1/(A1:A65529<>"");A1:A65529)

Formülünün açıklanması:

1. Bu formüllerde LOOKUP fonksiyonunun vektör olarak söz dizimi formatı kullanılmaktadır.

Vektör biçiminin sözdizimi:

=LOOKUP(lookup_value;lookup_vector;result_vector)
=ARA(aranan_değer;aranan_vektör;sonuç_vektör)

Aranan_değer ARA fonksiyonunun ilk vektörde aradığı değerdir. Aranan_değer bir sayı, metin, mantıksal bir değer ya da bir değere başvuruda bulunan bir ad ya da başvuru olabilir.

Aranan_vektör yalnızca bir satır ya da bir sütun içeren aralıktır. Aranan_vektördeki değerler metin, sayı ya da mantıksal değer olabilir.

Sonuç_vektör yalnızca bir satır ya da sütun içeren bir aralıktır. Aranan_vektörle aynı büyüklükte olması gerekir.

2. Burada 2 (1’den farklı herhangi bir değer girilebilir.) aranan_değer olarak formülün birinci parametresini oluşturur.

3. Formülde ilginç olan ise ikinci parametrede yer alan
1/(1-ISBLANK(A1:A65535)) aranan_vektördür.

bu dizi değerlenirken;
{1;1;1;1;1;1;1;#DIV/0!;1;1;#DIV/0!;#DIV/0!;…;#DIV/0!} şeklinde olur. Burada ISBLANK fonksiyonu boş hücre için True- Doğru -1, dolu hücre için False-Yanlış – 0’a dönüşür. Bunları 1’den çıkardığımızda dizi 0 (boş) or 1 (dolu) değerlerini alır. Bu diziyi de 1’e bödüğümüzde dizi #DIV/0 (boş) veya 1 (dolu) değerlerini alır.

1/(A1:A65529<>"") aranan_vektöründe ise; bu dizi değerlenirken;
{1;1;1;1;1;1;1;#DIV/0!;1;1;#DIV/0!;#DIV/0!;…;#DIV/0!} şeklinde olur.

4. LOOKUP aranan_değer 2’yi dizide ararken bulamayacak ve buna yakın en son değer olan 1’i alacaktır. Bu da son dolu hücrenini değeri olacaktır.


.

 

[betoncu]

Sn yurtta&#351;, bu konuda uzman olmad&#305;&#287;&#305;mdan verdi&#287;iniz bilgileri tam olarak anlamasamda faydal&#305; oldu.
Te&#351;ekk&#252;r ederim...