parçaal,soldan

[RALKAN]

İyi geceler arkadaşlar ,

Mümkün olup olamayacağımdan emin değilim fakat eğer çözüm getirilebilinirse beni uzun bir uğraştan beni kurtarmış olacaksınız.

Sorunum şu şekilde ;

Bir cümle içerisinde " / " işaretinden öncekileri başka bir sütuna parçaal ile almaya çalıştım fakat " / " işaretinden önceki metinin uzunluğu değişkenlik gösterdiğinden yapamadım .Belki başka bir fonksiyonla mümkünse yardımcı olabilirmisiniz.

Yardımlarınız için şimdiden teşekkür ederim.

 

[Ömer]

Merhaba,

=SOLDAN(A1;BUL("/";A1)-1)

İstediğiniz bu mu?

.

 

[Ali]

=SOLDAN(A1;MBUL("/";A1)-1)

şeklinde deneyiniz.

 

[RALKAN]

Merhaba,

=SOLDAN(A1;BUL("/";A1)-1)

İstediğiniz bu mu?

.

Hocam çok teşekkür ederim ,sorunum her zamanki imdada yetişmenizle çözülmüştür.

İyi geceler

 

[RALKAN]

=SOLDAN(A1;MBUL("/";A1)-1)

şeklinde deneyiniz.

Sayın Ali Hocam,

Sizin çözümünüzüde kullanabileceğim ve de her cevabınızı daha sonra rahatsızlık vermemek için arşivliyorum.

Sizlere tüm hocalarımıza inanın çok ama borçlu kalıyoruz, size ve tüm hocalara çok teşekkür ediyorum.

İyi geceler

 

[RALKAN]

Merhaba,

=SOLDAN(A1;BUL("/";A1)-1)

İstediğiniz bu mu?

.

Sayın espiyonajl,

Yukarda ki örneğin tam tersinde formül (sağdaki metini) nasıl oluşturulmalı bilgi verebilirmisiniz.

 

[Ömer]

Sayın espiyonajl,

Yukarda ki örneğin tam tersinde formül (sağdaki metini) nasıl oluşturulmalı bilgi verebilirmisiniz.

=SAĞDAN(A1;UZUNLUK(A1)-BUL("/";A1))

Bu şekilde kullanabilirsinz..

 

[RALKAN]

=SAĞDAN(A1;UZUNLUK(A1)-BUL("/";A1))

Bu şekilde kullanabilirsinz..

Hocam çok teşekkür ederim.

 

[Ömer]

Rica ederim, iyi çalışmalar..

 

[scarlmd]

çok güzel bir çözüm gerçekten. benimde bir süredir uğraştığım bir konu için çözüm konusunda yönlendirdi beni. emeğinize sağlık.

ama benim ek bir sorum daha olacak;
acaba bu örneği (aynı kelimede aynı işaretten birden fazla olmasından dolayı) "-" işaretini ilk gördüğün yerden sonraki tüm karakterleri al şeklinde uygulayabilirmiyiz?

 

[Ali]

çok güzel bir çözüm gerçekten. benimde bir süredir uğraştığım bir konu için çözüm konusunda yönlendirdi beni. emeğinize sağlık.

ama benim ek bir sorum daha olacak;
acaba bu örneği (aynı kelimede aynı işaretten birden fazla olmasından dolayı) "-" işaretini ilk gördüğün yerden sonraki tüm karakterleri al şeklinde uygulayabilirmiyiz?

=PARÇAAL(A1;MBUL("-";A1)+1;UZUNLUK(A1))

olarak deneyiniz.

.

 

[scarlmd]

anlatamadım.
örnek ; vega-legal-04 olsun . bu etiketin içinden sağdan başlayıp ilk "-" karakterini gördükten sonra kalan bütün karakterleri almasını sağlamaya çalışıorum. çünkü bazı örnekte sadece "vega-04" şeklinde olabiliyor. ya da "legal-rw-01" v.s.
Ali beyin yazdığı örneği denediğimde sadece sondaki "04" rakamlarını alıyor.
umarım ne demek istediğimi anlatabilmişimdir.

 

[Ali]

vega-legal-04 ise olması gereken sonuç nedir.

 

[scarlmd]

vega-legal-04 ise olması gereken sonuç nedir.

vega-legal-04 ise sağdan ilk "-" işaretini gördüğü yerden sonraki tüm karakterleri alacak yani ; sonuç (vega-legal) olacak. aslında en güzeli fraklı sütunlarda vega ve legal sonucunu vermesi olurdu ama bunu sağlayabileceğimizi sanmıorum. mümkün görünen yeterli olacaktır. diğer adım için başka birşey düşünmeye çalışacağız.

 

[Ali]

A1 hücresinde

vega-legal-04

olsun.

B1 hücresine

=SOLDAN(A1;BUL("#";YERİNEKOY(A1;"-";"#";UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;"-";""))))-1)

C1 hücresine

=SOLDAN(B1;MBUL("-";B1)-1)

D1 hücresine

=SAĞDAN(B1;UZUNLUK(B1)-BUL("-";B1))

yazıp aşağı doğru çekiniz.

 

[scarlmd]

ali bey, ellerinize sağlık, beklentilerimin de ötesinde çok güzel oldu. yalnızca 2. ve 3. formülde çift grup olmayan satırlar için"değer" hatası çıkıyor. bunun "değer" olarak değil de boş olmasını veya hiç değilse "0" (sıfır) olmasını sağlayabilirmiyiz.
sonuçları içeren bir örneği ekliyorum.
tekrar tekrar emeğinize sağlık. kocaman birkaç adım birden atmamı sağladınız.

 

[Ali]

=EĞER(EHATALIYSA(Formül);"";Formül) şeklinde düzenleyiniz.

Yani

=EĞER(EHATALIYSA(SOLDAN(B5;MBUL("-";B5)-1));"";SOLDAN(B5;MBUL("-";B5)-1))

şeklinde düzenleyiniz.

 

[scarlmd]

:bravo:

budur..
ellerinize , aklınıza sağlık....
teşekkür..teşekkür..teşekkür....

 

[scarlmd]

HATA?

EĞER(EHATALIYSA(DÜŞEYARA($C23;DOLAYLI("'TAPU-AKKOZA "&PARÇAAL($C23;3;1)&"'!h:j");2;0));" ";DÜŞEYARA($C23;DOLAYLI("'TAPU-AKKOZA "&PARÇAAL($C23;3;1)&"'!h:j");2;0))


Hocam...
nerde yanlış yapıyorum? her iki taraftada değer yoksa boş geçsin istiyorum.galiba yine bir mantık hatası yapıyorum değil mi?

 

[Ömer]

Merhaba,

Boşluk değilde boş gözükmesi için, " " yerine "" bu şekilde deneyiniz. Bunun dışında herhangi bir hata gözükmüyor, hatalı dosyanızı ekleyerek tekrar açıklarsanız yardımcı olmaya çalışırız..

Not : Farklı konularla ilgili sorularınız için yeni konu başlığı açmanız daha doğru olacaktır..

.