Aynı hücrelerin satırlarında seçim yapmak

[turkuaz81]

B sutununda aynı olan hücrelerin , C sutununda enbüyük olanının , D sutunundaki değerini alıp , E sutununa 1 yıl ekleyerek yazacak.

Dosyada daha net anlaşılabilir sanırım.

Bu bahsettiğim düşeyara ile yapılabilir mi?

 

[Ömer]

Merhaba,

Sorunuzu anlayamadım,

=TARİH(YIL(DOLAYLI("D"&MAK(C3:C15)+2))+1;AY(DOLAYLI("D"&MAK(C3:C15)+2));GÜN(DOLAYLI("D"&MAK(C3:C15)+2)))

İstediğiniz bu mu?

Eğer tam olarak 1 yıl değil 365 gün eklenecekse,

=DOLAYLI("D"&MAK(C3:C15)+2)+365

bu şekilde kullanınız..

.

 

[turkuaz81]

Cevap için teşekkür ederim. Ama istediğim tam olarak bu değil.

Bu fonksiyonu B sutunundaki aynı değerli hücrelerin satırlarına uygulayacak ve sadece C deki en büyük değerin yanındaki hücreye (E sutununa) tarihi yazacak.E sutununda sadece C sutunundaki en büyük değerlerin karşılıklarında tarih yazılmış olacak.

Şimdiden teşekkür ederim..

 

[Ömer]

Ben soruyu anlayamadığımı söylemiştim fakat siz yine aynı açıklamayı yapmışsınız. Tablo üzerinde 3-4 örnek vererek sonuçları manuel yazarak daha detaylı açıklayınız..

.

 

[turkuaz81]

Dosyaya açıklamayı ekledim, umarım anlatabilmişimdir. Belki de makro yazmak gerekiyordur.
İlginiz için teşekkür ederim

 

[Ömer]

Dosyaya açıklamayı ekledim, umarım anlatabilmişimdir. Belki de makro yazmak gerekiyordur.
İlginiz için teşekkür ederim

Merhaba,

E3 hücresine yazarak alt satırlara kopyalayınız..

=EĞER(MAK(EĞER($B$3:$B$15=B3;SATIR($C$3:$C$15)))=SATIR();D3+365;"")

Dizi formülüdür, formülü hücreye yazdıktan sonra entera basmadan ctrl sihft enter tuş kombinasyonuna basarak formülün girişini tamamlayınız. Bu işlemden sonra formülün başına ve sonuna { } ayıraçları otomatik eklenecektir..

Formülü uyguladığınız sütunun biçimini tarih olarak biçimlendiriniz..

.

 

[Necdet]

Merhaba,

Sayın espiyonajl'ın formülünü gerçek tarih olarak algılanmasını istersek eğer aşağıdaki şekilde değiştirmek gerek

=EĞER(MAK(EĞER($B$3:$B$15=B3;SATIR($C$3:$C$15)))=SATIR();TARİH(YIL(D3)+1;AY(D3);GÜN(D3));"")

Anımsatalım formül yine dizi formüldür, yani formül yazıldıktan sonra Ctrl+Shift+Enter tuşu ile bitirilmelidir.

 

[turkuaz81]

espiyonajl ve Necdet Yeşertener ,

Arkadaşlarım yardımınız ve ilginiz için çok teşekkür ederim.

Sorunum çözüldü ama verdiğiniz formüller benim kastetdiğim işi yapmıyor. Bu formuller son eklenen hasan ın değerlerini alıyor. 7-8 arasına bir satır ekleyin ve hasan yazın , tarih alta kayacak.

Veya C deki değerlerin sırasını değiştirin gene en son hasanın D değerini alacak. Burada C sutununu dikkate almıyor. Benim istediğim Hasan ların arasında C si en büyük olanın D sini(tarihini) almaktı.

 

[Ömer]

espiyonajl ve Necdet Yeşertener ,

Arkadaşlarım yardımınız ve ilginiz için çok teşekkür ederim.

Sorunum çözüldü ama verdiğiniz formüller benim kastetdiğim işi yapmıyor. Bu formuller son eklenen hasan ın değerlerini alıyor. 7-8 arasına bir satır ekleyin ve hasan yazın , tarih alta kayacak.

Veya C deki değerlerin sırasını değiştirin gene en son hasanın D değerini alacak. Burada C sutununu dikkate almıyor. Benim istediğim Hasan ların arasında C si en büyük olanın D sini(tarihini) almaktı.

Haklısınız o kısma dikkat etmemişim.

+ 365 için,

=EĞER(TOPLA.ÇARPIM(KAÇINCI(MAK(($B$3:$B$15=B3)*($C$3:$C$15));($B$3:$B$15=B3)*($C$3:$C$15);0))+2=SATIR();D3+365;"")

+ 1 yıl için,

=EĞER(TOPLA.ÇARPIM(KAÇINCI(MAK(($B$3:$B$15=B3)*($C$3:$C$15));($B$3:$B$15=B3)*($C$3:$C$15);0))+2=SATIR();TARİH(YIL(D3)+1;AY(D3);GÜN(D3));"")

.

 

[turkuaz81]

k:: İşte bu. Şimdi harika oldu. Ellerine sağlık.