Düşeyara formül isteği

[cavanoos]

Merhaba arkadaşlar;

Ekli dosyamda bordro maaş sayfasında B sütununda formüller mevcut.B3 hücresine değer gelmiyor.Gelmesini istediğim değer 300 tl.

Düşeyara fonksiyonu ile beraber başka hangi fonksiyon kullanmalıyım ki istediğim sonucu alayım.Yardım edebilir misiniz ?

 

[excelci1]

bordro maaş sayfasında B2 hücresine yazıp aşağıday doğru kopyalayın.

=EĞER(EHATALIYSA(İNDİS(Maaş!$B$2:$B14;KAÇINCI(A2;Maaş!$A$2:$A14;0)));0;İNDİS(Maaş!$B$2:$B14;KAÇINCI(A2;Maaş!$A$2:$A14;0))+EĞER(EHATALIYSA(İNDİS(Avans!$B$2:$B17;KAÇINCI(A2;Avans!$A$2:$A19;0)));0;İNDİS(Avans!$B$2:$B17;KAÇINCI(A2;Avans!$A$2:$A19;0))))

aynı isim olmadığı zaman 0 değerini getirecek. o yüzden isimleri aynı yazın.

 

[Merhum İdris SERDAR]

Merhaba arkadaşlar;

Ekli dosyamda bordro maaş sayfasında B sütununda formüller mevcut.B3 hücresine değer gelmiyor.Gelmesini istediğim değer 300 tl.

Düşeyara fonksiyonu ile beraber başka hangi fonksiyon kullanmalıyım ki istediğim sonucu alayım.Yardım edebilir misiniz ?

.

Dosyanız ekte.

İki yöntemle yapılmış.

Ayrıca, buraya bakın.

http://www.excel.web.tr/f60/3b-3d-formulleri-t68265.html

.

 

[excelci1]

sn. yurttaş çok güzel olmuş
bu formülü açıklama şansınız var mı acaba ?

 

[Merhum İdris SERDAR]

sn. yurttaş çok güzel olmuş
bu formülü açıklama şansınız var mı acaba ?

.

=IF(ISERROR(VLOOKUP($A2;Avans!A2:B892;2;0));0;VLOOKUP($A2;Avans!A2:B892;2;0))+IF(ISERROR(VLOOKUP($A2;Maaş!A2:B892;2;0));0;VLOOKUP($A2;Maaş!A2:B892;2;0))

Açıklama:

IF(ISERROR(VLOOKUP($A2;Avans!A2:B892;2;0));0

Eğer Avans sayfasında değeri bulmazsan 0 ver.

VLOOKUP($A2;Avans!A2:B892;2;0)) Bulursan değeri al.

Bu değerler toplanacağından aralarına + koyduktan sonra aynı mantıkla diğer sayfalardan veriyi çekmek için aynı formülü kullanıyoruz.

Ne kadar sayfa varsa, hücre limitleri içersinde kalmak kaydıyla, çoğaltarak götürmek mümkündür.


.

 

[cavanoos]

Arkadaşlar;

Verdiğiniz cevaplar için teşekkür ederim.Sorunum çözülmüştür.Saolun...

 

[excelci1]

.

=IF(ISERROR(VLOOKUP($A2;Avans!A2:B892;2;0));0;VLOOKUP($A2;Avans!A2:B892;2;0))+IF(ISERROR(VLOOKUP($A2;Maaş!A2:B892;2;0));0;VLOOKUP($A2;Maaş!A2:B892;2;0))

Açıklama:

IF(ISERROR(VLOOKUP($A2;Avans!A2:B892;2;0));0

Eğer Avans sayfasında değeri bulmazsan 0 ver.

VLOOKUP($A2;Avans!A2:B892;2;0)) Bulursan değeri al.

Bu değerler toplanacağından aralarına + koyduktan sonra aynı mantıkla diğer sayfalardan veriyi çekmek için aynı formülü kullanıyoruz.

Ne kadar sayfa varsa, hücre limitleri içersinde kalmak kaydıyla, çoğaltarak götürmek mümkündür.

anlatımınız için teşekkür ederim. söylemeyi unuttum yazdığınız 2. formül de takıldığım yer oldu.

şu formülde
=TOPLA.ÇARPIM((ETOPLA(DOLAYLI("'"&{"Avans";"Maaş"}&"'!A2:A892");$A2;DOLAYLI("'"&{"Avans";"Maaş"}&"'!B2:B892"))))

kafamı karıştıran şey şurası oldu
DOLAYLI("'"&{"Avans";"Maaş"}&"'!A2:A892")

{"Avans";"Maaş"} bu şekilde yazdığınız için mi acaba önce
Avans!A2:A892
Maaş!A2:A892 şeklinde veri aralığını üretti ? sonrada etopla formülü ile toplattınız. ama etopla formülünü neden topla.çarpım içinde kullandınız? etopla formülü tek başına neden eksik topluyor ?

son olarakta
"'"&{... devam eden formülde bu işareti ' neden kullandınız ?

 

[Merhum İdris SERDAR]

anlatımınız için teşekkür ederim. söylemeyi unuttum yazdığınız 2. formül de takıldığım yer oldu.

şu formülde
=TOPLA.ÇARPIM((ETOPLA(DOLAYLI("'"&{"Avans";"Maaş"}&"'!A2:A892");$A2;DOLAYLI("'"&{"Avans";"Maaş"}&"'!B2:B892"))))

kafamı karıştıran şey şurası oldu
DOLAYLI("'"&{"Avans";"Maaş"}&"'!A2:A892")

{"Avans";"Maaş"} bu şekilde yazdığınız için mi acaba önce
Avans!A2:A892
Maaş!A2:A892 şeklinde veri aralığını üretti ? sonrada etopla formülü ile toplattınız. ama etopla formülünü neden topla.çarpım içinde kullandınız? etopla formülü tek başına neden eksik topluyor ?

son olarakta
"'"&{... devam eden formülde bu işareti ' neden kullandınız ?

.

1. SUMPRODUCT – TOPLA.ÇARPIM formülü yalnız başına 3 boyutlu işlemlerde çalışmaz. Yani sayfalardan veri alırken çalışmaz. Onun için SUMIF - ETOPLA formülü kullanıldı. SUMIF’te yeterli değil, bunu da dizi formülü şeklinde kullanmamız gerekir. Yani ya SUM dizi veya SUMPRODUCT’ı devreye sokmamız gerekir.
2. O zaman temel fonsiyonumuz burada SUMIF. SUMIF’in s öz dizimine bakarsak;
=SUMIF(range; criteria; [sum_range]) şeklindedir.
Range:A2:A892
Creteria: $A2
sum_range:B2:B892
Creteia hariç diğer alanlar sayfalarda bulunuyorlar. Ya sayfa adlarını hücrelere yazar oradan aralık olarak alırız. Veya bunun için alan adı tanımlar alan adını kullanırız. Yada sayfa adı az ise şimdiki yaptığım şekilde {"Avans";"Maaş"} ayraçların içine yazarız.

3. Bunlar işler hale getirmek için INDIRECT - DOLAYLI fonksiyonunukullanmamız gerekir Bunu kullanırken:
'.....' Tek Tırnak: Sayfa (worksheet) adını gruplamak.
"....." Çift Tırnak: Formülde metin dizesini gruplamak.

Ve dolayısıyla formül parçası '"&{"Avans";"Maaş"}&"'! şeklini alır."

Bakınız:
http://www.excel.web.tr/f60/excelde-kullanylan-operator-i-aret-ve-simgeler-t73780.html
http://www.excel.web.tr/f60/indirect-dolayly-fonksiyonu-t68405.html





.

 

[excelci1]

sn. yurttaş teşekkür ederim sağolun