çizimleri nesneleri silme

[modoste]

merhaba sayın hocalarım

F5/ÖZEL/NESNELER seçildiğinde silebiliyorum çalışma sayfamdan nesne yada çizgileri
ancak mesela ben A1:W20 arasındaki çizgileri nesneleri silmeyi nasıl yapabilirim.

 

[Necdet]

Merhaba,

Aşağıdaki kodları deneyiniz. Her türlü şekli siler.

Sub AraliktaSekilSil()
    
    Dim Sh As Shape
    
    With ActiveSheet
    
        For Each Sh In .Shapes
            If Not Application.Intersect(Sh.TopLeftCell, .Range("A1:W20")) Is Nothing Then Sh.Delete
        Next Sh
        
    End With
    
End Sub

 

[modoste]

sayın nejdet hocam
çizim adı altındaki nesneler değişik yerlerde olduğu ,için bu çözümlemeniz bir aralığı kapsıyo gibi
başka bir yolu yokmudur hocam.

 

[Necdet]

sayın nejdet hocam
çizim adı altındaki nesneler değişik yerlerde olduğu ,için bu çözümlemeniz bir aralığı kapsıyo gibi
başka bir yolu yokmudur hocam.

merhaba sayın hocalarım

F5/ÖZEL/NESNELER seçildiğinde silebiliyorum çalışma sayfamdan nesne yada çizgileri
ancak mesela ben A1:W20 arasındaki çizgileri nesneleri silmeyi nasıl yapabilirim.

Şimdi ne denir ki buna? olsa olsa dalga geçiyorsunuz diye düşünebilirim.

 

[modoste]

hocam estağfurullah benim sorumun asıl amacı herhangi bir aralıktaki bir çizimi silebilmek bir aralık örnek vermiştim sadece birkaç yerde olabiliyo mouse ile seçip silebilmek amacım tek tek silmektense o aralıkta ne varsa silebilmeyi sormuştum.
yanlış yönlendirdiysem özür dilerim.

 

[Necdet]

Merhaba,

mesela lafını da ben atlamışım siz kusura bakmayınız.

Önce bölgeyi seçip, sonra kodları çalıştırınız.

Sub AraliktaSekilSil()
    
    Dim Sh As Shape
    
    With ActiveSheet
    MsgBox Selection.Address
    
        For Each Sh In .Shapes
            If Not Intersect(Sh.TopLeftCell, Selection) Is Nothing Then Sh.Delete
        Next Sh
        
    End With
    
End Sub

 

[modoste]

teşekkürler hocam emeğinize sağlık

 

[Necdet]

Güle güle kullanınız. Bana da bir fikir verdiniz, bu olayı fare sağ tık olayına bağlamak güzel bir eklenti olur.

 

[Ömer]

Merhaba,

Kodlar Necdet bey'den, sağ klik benden olsun.
--------------------------------------------------------------

Kodları module kopyalayın ve çalışma kitabını kaydetip kapatın.

Bu işlemden sonra kitabı açtığınız zaman, fare sağ kilik menüsüne "Yeni--->Nesneleri Sil" adın da yeni bir seçenek eklendiğini görebilirsiniz.

Herhangi bir alanı seçip sağ klik yaptıktan sonra bu seçeneği işaretlediğiniz de seçili alandaki nesneler silinir.

Sub Auto_Open()
     FareMenu
End Sub
 
Sub FareMenu()
 
    Dim cb As CommandBar, MenuObject
 
    Set cb = Application.CommandBars("Cell")
    Set MenuObject = cb.Controls.Add(Type:=msoControlButton, Temporary:=True)
 
    With MenuObject
        .OnAction = "AraliktaSekilSil"
        .FaceId = 9
        .Caption = "Yeni--->Nesneleri Sil"
    End With
 
    Set cb = Nothing: Set MenuObject = Nothing
 
End Sub
 
Sub AraliktaSekilSil()
 
    Dim Sh As Shape
 
    Application.ScreenUpdating = False
        For Each Sh In ActiveSheet.Shapes
            If Not Application.Intersect(Sh.TopLeftCell, _
                Selection) Is Nothing Then Sh.Delete
        Next Sh
    Application.ScreenUpdating = True
 
End Sub
 
Sub Auto_Close()
     Application.CommandBars("Cell").Reset
End Sub

 

[uzmanamele]

Merhaba

Excel 2007 ve üzeri için;

Giriş / düzenleme / bul ve seç / nesneleri seç
Nesnelerini silmek istediğiniz alanı fareyle seçin ve silin.

Excel 2003 için; sanırım çizim araçları menüsünde bu ikonu bulabilirsiniz.
Silme işiniz bittiğinde ikonu pasif yapmayı unutmayın.

 

[modoste]

hocam bu çözüm çok iyi oldu tam aradığım bu idi makroyu da arşivime aldım ama bu tam istediğimdi.

Silme işiniz bittiğinde ikonu pasif yapmayı unutmayın. bunu anlayamadım hocam
bu sadece excel 2003 için mi

 

[Necdet]

Merhaba

Excel 2007 ve üzeri için;

Giriş / düzenleme / bul ve seç / nesneleri seç
Nesnelerini silmek istediğiniz alanı fareyle seçin ve silin.

Excel 2003 için; sanırım çizim araçları menüsünde bu ikonu bulabilirsiniz.
Silme işiniz bittiğinde ikonu pasif yapmayı unutmayın.

Evet 2007 ve sonrası için güzel özellik ama her türlü nesneyi silmedi, ya da ben beceremedim

Bunu karşılıklı görüşerek halletmek gerek