Parti Numarasından Üretim Tarihi Hesaplama

[mcharun]

Herkese merhaba, gıda mühendisiyim.
Ürünlerimize 5 basamaklı rakamdan oluşan bir parti numarası veriyoruz, üretim tarihini gösteren.
Örnek olarak;
16443 olan partideki
16, 2016 yılını
44, 44. haftayı
3 ise günü(Pazartesi gününden itibaren sayarsak üretim gününü, Çarşamba) veriyor.
Yani 16443 => 26.10.2016 tarihini ifade ediyor.

Kontrol ve depo stoklarımızdaki tüm ürünlerin periyodik tarih kontrolünü yapabilmem için(300 kalemden fazla ürün var), verilen parti numarasından üretim tarihini gösteren excell formülüne ihtiyacım var.

Yardımcı olur musunuz?

 

[1Al2Ver]

Merhaba,

Öneri ;

Sonuçları elle girilmiş, örnek bir dosyayı, Dosya.tc ve benzeri dosya yükleme sitelerine ekleyip, orada verilen linki burada paylaşırsanız,

çözüm almanız çabuklaşacaktır.

Şöyle de olabilir ; Parti no.yu kayıt ederken bir yan sütuna da tarihi kayıt edebiliyorsanız, farklı bir sayfada, yada sütunda yada hücrede parti no.dan tarihi çağırmak (bulmak) düşeyara ile olabilir.

Kolay gelsin.

 

[Ömer BARAN]

Merhaba.

Aşağıdaki formülü (parti numarasının A1 hücresinde olduğu varsayıldı) dener misiniz?
İstediğiniz sonucu alamıyorsanız cevabımın altındaki İMZA bölümünde yer alan açıklamalara göre bir örnek belge ekleyiniz.
.

=TARİH(2000+SOLDAN(A1;2)-1;12;31)+(PARÇAAL(A1;3;UZUNLUK(A1)-3)-1)*7-1-(HAFTANINGÜNÜ(TARİH(2000+SOLDAN(A1;2)-1;12;31)+(PARÇAAL(A1;3;UZUNLUK(A1)-3)-1)*7-1;2)-SAĞDAN(A1;1))

 

[mcharun]

Ömer bey,
Verdiğiniz formül çalışıyor, hem de mükemmel şekilde.
Öncelikle size ve yardımcı olan herkese çok teşekkür ederim

 

[mcharun]

Konuyla ilgili ilave bir sorum daha olacak.
Parti no uygulamamız, diğer fabrikamızda ilk rakam farklı olarak aynı mantıkla veriliyor.
Örnekteki 16443 olan parti 36443 şekilde ifade ediliyor.
Ömer bey,
Mevcut formülü buna da uyarlayabilir miyiz? Farklı bir formül de olabilir.
Simdiden cok tesekkurler

 

[Ömer BARAN]

Tekrar merhaba.

Ancak 36443 değerinde hangi rakam neyi gösteriyor net şekilde açıklar mısınız?

Eğer ilk karakter kullanılmayacak, 2'nci karakter yıl ve başlangıç da 2010 ise formülü aşağıdakiyle değiştirebilirsiniz.
.

=TARİH(20[B][COLOR="Red"]1[/COLOR][/B]0+[COLOR="red"]PARÇAAL(A1;2;1)-1[/COLOR];12;31)+(PARÇAAL(A1;3;UZUNLUK(A1)-3)-1)*7-1-(HAFTANINGÜNÜ(TARİH(20[COLOR="red"][B]1[/B][/COLOR]0+[COLOR="red"]PARÇAAL(A1;2;1)[/COLOR]-1;12;31)+(PARÇAAL(A1;3;UZUNLUK(A1)-3)-1)*7-1;2)-SAĞDAN(A1;1))

 

[mcharun]

Ömer bey,
36443 şeklindeki partide ilk rakam(3) sabit kalacak.
İkinci rakam(6) 2016 yılını ifade ediyor. 44 ve 3 aynı zaten diğer partiyle.

2017 yılındaki üretimlerimizde örnek olarak şu partileri kullanacağız ;
17443 ve 37443.

 

[Ömer BARAN]

O zaman son verdiğim formülün işinizi görmesi lazım.

 

[mcharun]

Ömer bey,
Şimdi denedim, çalışıyor.
Çok teşekkür ederim, sağolun.

 

[Ömer BARAN]

Kolay gelsin.

 

[mcharun]

Kolay gelsin.

Ömer Bey tekrar merhaba. Hazırladığınız formülü yaklaşık 5 aydır kullanıyorum fakat 2017 yılına ait verilerde bir hata fark ettim. Parti numarası 16 ve 36 ile başlayan 2016 üretim tarihli ürünlerimizde sorun yok fakat 17 ve 37 ile başlayan partilerde formül üretim tarihini hatalı veriyor. Kullanmakta olduğum dosyayı aşağıdaki siteye yükledim. Orada kırmızı ile işaretlediğim, 1701101 partisi, 2017 yılının ilk haftası ve ilk Pazartesi günü olan 2 Ocak tarihine tekabül etmesi lazım fakat rapor 26.12.2016 tarihini gösteriyor. Farklı bir örnek için 1709401 veya 3709401 tarihleri 2 Mart olması lazım ancak 23 Şubat gösteriyor.

Formülde nerede hata olabilir, bakabilirseniz çok mutlu olurum.

Çok teşekkürler



http://s3.dosya.tc/server11/2cmrl4/PARTI_NO-URETIM_TARIHI_RAPORU.xlsx.html

 

[merakli_72]

Selam;
Önceki sayfadaki kodlarınız 5 karakter iken burda verdiğiniz örnek kodlar 7 karakter olmuş,
formül bu yüzden hatalı çalışır
7 karakterlik kodlamada neyin neyi ifade ettiğini yazabilirseniz, yardımcı olmaya çalışırım

 

[mcharun]

Merhaba. Size de kısaca anlatayım konuyu. Üretimde parti numaralarını 7 rakamdan oluşacak şekilde veriyoruz: 1709401

17: 2017 yılını

09: 9. haftayı

4: Haftabaşından itibaren üretim gününü, yani Perşembe

01: O günkü üretim parti sırasını, bu bizim için önemsiz.



1709401=17094 oluyor, kodlar tabloda 5 rakam. 7 rakam olanı 5 rakama çeviriyorum. Ömer beyin hazırlamış olduğu formüş bu 5 rakamlık koda uygulanıyor.



Birde 37 ile başlayan partiler var, diğer fabrikamızdaki üretimi ayırmak ve takibini sağlamak için baştaki 1 rakamı 3 oluyor, mantık aynı.

1709401=3709401=17094=37094

 

[merakli_72]

Bu durumda sorulması gereken soru şu:
size göre ocak ayının ilk haftasının tarihleri nedir:
26 aralık 01 ocak mı (Ocak ayına ilk girilen hafta)
02 Ocak 08 Ocak mı (Ocak ayının full geçtiği ilk hafta)
yada başka bir kriteriniz mi var,
hangi tarih başlangıç kabul edilerek hafta sayılacak bu sonucu etkiler

 

[mcharun]

2017 yılı takvimlerinde olduğu şekilde yazılıyor hafta. Yani 2017 nin 1. Haftası 2/8 Ocak tarihlerini içeren hafta.
Teşekkürler

 

[merakli_72]

Tekrar merhaba
aşağıdaki formülün 2017 için doğru çalışacağını tahmin ediyorum,

=TARİH(2010+PARÇAAL(A1;2;1);1;1+7-HAFTANINGÜNÜ(TARİH(2010+PARÇAAL(A1;2;1);1;1);2)+1)+(PARÇAAL(A1;3;2)-1)*7+(PARÇAAL(A1;5;1)-1)

fakat 2016 yılının ilk haftasını ne kabul ediyorsunuz
4-10 ocak ise doğru çalışması lazım 2017 standardıyla tutuyor
fakat
28 aralık 03 ocak kabul ediyorsanız yanlış çalışır (1 hafta eksik)
bu burumda öncelikle ilk hafta konusunun netleşmesi gerekir

 

[mcharun]

Öncelikle çok teşekkür ederim, verdiginiz formül 2017 yılı için doğru çalışıyor fakat 2016 yılında hata veriyor. Örnek olarak 16304 pn için 28.07.2016 çıkıyor üretim tarihi fakat 21.07.2016 olması lazım. Dediğiniz gibi 1 haftalık hatalı sonuç oluyor.
Sizin yazdığınız formül ile Ömer beyin formüllerini birleştirme şansımız var mı?

 

[merakli_72]

Sizin yazdığınız formül ile Ömer beyin formüllerini birleştirme şansımız var mı?

İnanın bana bu çözüm olmaz, önümüzdeki yıllardan birisinde ocağın ilk haftasının durumuna göre yine hatalı sonuç alabilirsiniz.
Daha öncede bir çalışma için hafta noları ile uğraşmıştım, bazı yıllarda farklı takvimlerde bile hafta noları farklı görünüyordu
Örnek olarak 9. hafta dediğinizde ilk haftadan itibaren 9 hafta sayılacağı için anahtar ilk haftanın ne zaman başlayacağı oluyor

Bu konudaki genel görüş aşağıdaki gibidir
kaynak: http://www.takvim.com/yillik_takvim.php
Bu durumda aslında benim yazdığım formül 2016 içinde doğru çalışıyor
yani 2016 ilk haftası 28 aralık 03 ocak olmaması lazım,
Yinede ilk haftayı belirlemede standart bir kriteriniz varsa yardımcı olmaya çalışırım
Formüldede bir düzeltme yaptım bu şekilde kullanırsanız daha doğru olur
Birde aklıma takıldı soramadan edemeyeceğim
Üretim tarihini niye 20170317 şeklinde direkt yazmıyorsunuz

=TARİH(2010+PARÇAAL(A1;2;1);1;1+7-HAFTANINGÜNÜ(TARİH(2010+PARÇAAL(A1;2;1);1;1);2)+1)+((PARÇAAL(A1;3;2)+EĞER(HAFTANINGÜNÜ(TARİH(2010+PARÇAAL(A1;2;1);1;1);2)<=4;0;-1))*7+(PARÇAAL(A1;5;1)-1))

HAFTALARIN NUMARALANDIRILMASI

Açıklamalar...

ISO 8601 standartlarına göre yılın ilk haftasının hangi gün başlayacağı aşağıdaki birbirine yakın açıklamalarla belirlenmiştir. Buna göre;
- Yılın ilk perşembe gününün içinde olduğu hafta yılın ilk haftasıdır (resmi ISO tarifi)
- 4 Ocak gününün içinde olduğu hafta yılın ilk haftasıdır
- Yeni yılda, haftanın 7 gününden çoğu günün (4 veya fazlasının) bulunduğu ilk hafta, yılın ilk haftasıdır
- 29 Aralık - 4 Ocak arasında pazartesi ile başlayan hafta yılın ilk haftasıdır (28 Aralık daima önceki yılın son haftasındadır)

Eğer 1 Ocak günü; pazartesi, salı, çarşamba veya perşembe gününe denk gelmişse, 1 Ocak günü yılın ilk haftasındadır. Eğer 1 Ocak günü; cuma, cumartesi veya pazar gününe denk gelmişse, 1 Ocak günü biten yılın 52 veya 53. haftasındadır.

Kaynak: Wikipedia

 

[mcharun]

2 formülü birleştirme şansımız yoksa, mecburen elimdekilerle yetinecegim. Stok kontrolünde 2016 ve 2017 üretimlerini ayırarak kontrolü sağlayacağım, sizin ve Ömer beyin formülleriyle. Parti no uygulaması sizin yazdığınız şekilde de olabilir aslında fakat hafta/gün olarak kodlama yapılmış, o şekilde devam ediyor.
Her ikinize de çok teşekkür ederim.