Soru 2 KRİTERLE BİRDEN SORGULAMA YAPIP SONUCU ALMAK İSTİYORUM

[umutak]

Merhaba Arkadaşlar

Elimde ekte görebileceğiniz gibi bir dosya var ben MAHALLE ve ESKİ PARSELİ beraber kullanıp yeni ada,yeni parsel,eski yüzölçüm ve yeni yüzölçümü alabilmek sonuca varabilmek istiyorum fakat kendi bilgim ışığında sadece eski parsele göre veri çekebiliyorum fakat işin içine mahalleyi de katmak ve tabloma daha profosyonel bir görünüm kazandırmak istiyorum. Sadece ESKİ PARSele göre veri çekebilmem bir işe yaramıyor çünkü bir parselden birden çok mahalleye ait olabiliyor. Örneğin Eski 2100 parsel hem GÖKÇEALİ,HEM ÇAKIL,HEM İZZETTİN gibi 3 mahellede olabiliyor ve ben burda mahalleye göre 2100 parseli çağırmalıyım. Eğer burda istediğim gibi bir sonuca varabilirsem bu seferde YENİ ADA,YENİ PARSELİ, MAHALLEYİ de dahil edip ESKİ PARSELİ bulmaya çalışıcam
dyardımlarınız için şimdiden tşkler

 

[AdemCan]

Merhaba,
Mahalle ve Eski Parsel No ya göre Yeni Ada No yu aramak için şu formülü kullanabilirsiniz.

=İNDİS('TÜM KÖYLER'!A2:G16151;KAÇINCI(1;('TÜM KÖYLER'!B2:B16151=Sayfa1!D3)*('TÜM KÖYLER'!G2:G16151=Sayfa1!I3);0);3)

-Diğer sütunlardaki verileri aramak için sadece formülün sonundaki 3 değerini değiştirmelisiniz.
Bu değer Tüm Köyler sayfasındaki A ve G sütunları arasında Yeni Ada No alanının sütun numarasıdır.
Diğer sütunlar;
- Yeni Parsel No için 4
- Eski Yüzölçümü için 5
- Yeni Yüzölçümü için 6 olmalıdır.

-Formül, Dizi Formülü olduğu için, hücreye yapıştırdıktan sonra Ctrl + Shift + Enter ile formülün başına ve sonuna { } simgelerinin eklenmesini sağlayınız.
- Kaçıncı formülündeki eşleştirme alanlarını değiştirerek Eski Parsel No yu da bulabilirsiniz.

 

[umutak]

merhaba
İlk olarak emeğiniz ve ayırdığınız vakit için şimdiden tşk ederim

1-) 3 ü 4 yaptım ama bir sütun sonrası için yani YENİ PARSEL NO da #YOK hatası alıyorum 3 ü 4 yapmama rağmen
2-) formülü copy paste yaparken neden ctrl+shift+enter kullanmam gerekti. İlk kez böyle bir kombinasyon yaptım.
3-) Eski parsel no için gereken formülü açık yazmanız mümkünse rica edicem

tşkler

 

[turist]

Merhaba Arkadaşlar

Elimde ekte görebileceğiniz gibi bir dosya var ben MAHALLE ve ESKİ PARSELİ beraber kullanıp yeni ada,yeni parsel,eski yüzölçüm ve yeni yüzölçümü alabilmek sonuca varabilmek istiyorum fakat kendi bilgim ışığında sadece eski parsele göre veri çekebiliyorum fakat işin içine mahalleyi de katmak ve tabloma daha profosyonel bir görünüm kazandırmak istiyorum. Sadece ESKİ PARSele göre veri çekebilmem bir işe yaramıyor çünkü bir parselden birden çok mahalleye ait olabiliyor. Örneğin Eski 2100 parsel hem GÖKÇEALİ,HEM ÇAKIL,HEM İZZETTİN gibi 3 mahellede olabiliyor ve ben burda mahalleye göre 2100 parseli çağırmalıyım. Eğer burda istediğim gibi bir sonuca varabilirsem bu seferde YENİ ADA,YENİ PARSELİ, MAHALLEYİ de dahil edip ESKİ PARSELİ bulmaya çalışıcam
dyardımlarınız için şimdiden tşkler

Dosyanız eklidir.

 

[umutak]

Tşk ederim @turist tek satır kullanmak istiyorum yani diğer köyler 2,3,4 satırdaki köyleri istemiyorum aslında. peki ilk sütun ESKİ ADA NO ilave bir ada daha olursa veya bir kaç ada yani örnekte sıfır(0) var sadece buna bir de 100 ilave edersek onu işin içine nasıl dahil ederiz
@faye_efsane , @turist
tşkler

 

[umutak]

Bir de yeni ada + yeni parsel girip eski ada ve eski parseli nasıl alırım bu konuda yardımcı olabilir misiniz @faye_efsane , @turist
=EĞERHATA(İNDİS('TÜM KÖYLER'!B$2:B$16151;KAÇINCI($D$3&$E$3&$H3;'TÜM KÖYLER'!$C$2:$C$16151&'TÜM KÖYLER'!$D$2:$D$16151&'TÜM KÖYLER'!$G$2:$G$16151;0));"")
şunu yaptım @turist ama eski parseli bulamıyorum tabii daha eski yüzölçüm ve yeni yüzölçümü de bulmam lazım
tşkler

 

[AdemCan]

Merhaba, rica ederim.

Soruların açıklaması:

1-) 3 ü 4 yaptım ama bir sütun sonrası için yani YENİ PARSEL NO da #YOK hatası alıyorum 3 ü 4 yapmama rağmen

#Yok hatası; Aradığınız değer, arama alanında bulunamadı demektir.
Formüller ve sonuçlarında çıkan bu tür hata mesajları için Microsoft'un sitesindeki Formüller ve işlevler isimli konuyu incelemeniz faydalı olacaktır. Bu hata mesajlarının yerine belirlediğimiz bir mesaj çıkmasını istersek Eğerhata formülü kullanılır. (EĞERHATA formülünün açıklaması)

-Örnek olarak Yeni Ada No formülü
=EĞERHATA(İNDİS('TÜM KÖYLER'!A2:G16151;KAÇINCI(1;('TÜM KÖYLER'!B2:B16151=Sayfa1!D3)*('TÜM KÖYLER'!G2:G16151=Sayfa1!I3);0);3);"Kayıt Yok!") formülün en sonundaki tırnak "" içindeki ifade #Yok hata mesajı yerine çıkmasını istediğimiz mesajdır. Tırnak içini boş bırakırsanız, #Yok hatası yerine hücre boş görünür.

2-) formülü copy paste yaparken neden ctrl+shift+enter kullanmam gerekti. İlk kez böyle bir kombinasyon yaptım.

Dizi formüllerinin açıklaması için;
- Sn. İdris SERDAR 'ın hazırlamış olduğu Dizi – Array Formülleri isimli konu ile Microsoft'un sitesindeki Dizi formülleriyle ilgili yönergeler ve örnekler isimli konuyu incelemeniz faydalı olacaktır.

3-) Eski parsel no için gereken formülü açık yazmanız mümkünse rica edicem

Yeni Ada, Yeni Parsel ve Mahalle kriterlerine göre
Eski Parsel No için

=İNDİS('TÜM KÖYLER'!A2:G16151;KAÇINCI(1;('TÜM KÖYLER'!C2:C16151=Sayfa1!E3)*('TÜM KÖYLER'!D2:D16151=Sayfa1!F3)*('TÜM KÖYLER'!G2:G16151=Sayfa1!I3);0);2)

Eski Ada No için

=İNDİS('TÜM KÖYLER'!A2:G16151;KAÇINCI(1;('TÜM KÖYLER'!C2:C16151=Sayfa1!E3)*('TÜM KÖYLER'!D2:D16151=Sayfa1!F3)*('TÜM KÖYLER'!G2:G16151=Sayfa1!I3);0);1)

formüllerini kullanabilirsiniz.

 

[umutak]

tşk ederim hallettim @turist size de tşkler @faye_efsane

 

[AdemCan]

Merhaba,
Rica ederim, iyi çalışmalar.

 

[turist]

tşk ederim hallettim @turist size de tşkler @faye_efsane

Sağ olun, iyi çalışmalar.