Soru Eğer Ve Yada

[iucfatih]

Merhabalar.
kodun devamını getiremedim beynim durdu, neyi nereye yazacağımı çözemedim. Yardım edebilirmisiniz?

burada H4 400 den büyükse ve f1 konaklama amaçlı binalar kurumsal binalar ...... dan biriyse sayfa2 den a1528 i getir, değilse boş bırak diyor.

=EĞER(VE(YADA(F1="konaklama amaçlı binalar";F1="kurumsal binalar";F1="büro binaları";F1="ticaret amaçlı binalar";F1="endüstriyel yapılar";F1="toplanma amaçlı binalar";F1="depolama amaçlı tesisler";F1="yüksek tehlikeli yerler";F1="karışık kullanım amaçlı binalar");H4>400);Sayfa2!A1528;"")

buraya kadar düzgün çalışıyor. Bu ilk olasılıktı.
(F1="konaklama amaçlı binalar";F1="kurumsal binalar";F1="büro binaları";F1="ticaret amaçlı binalar";F1="endüstriyel yapılar";F1="toplanma amaçlı binalar";F1="depolama amaçlı tesisler";F1="yüksek tehlikeli yerler";F1="karışık kullanım amaçlı binalar")
bunlardan biri seçilmişse ve k4>4 ise gene sayfa2 den a1528 i getirsin

f1 boş değilse ve h2>21.5 yada f1 boş değilse ve h3>30.5 yada f1 boş değilse ve k4>10 ise gene sayfa2den a1528 i getirsin





F1 de Yapı türü
h2 de bina yüksekliği (21.5 den büyükse yüksek bina),
h3 de yapı yüksekliği (30.5 den büyükse yüksek bina),
k4 de kat sayısı (10 dan fazla ise yüksek bina),
h4 de kat alanı ,
girilen hücreler var.

Yönetmelikte yazan aşağıdadır. Daha anlaşılabilir olacağından onuda ekledim.

a) Konutlar hariç, kat alanı 400 m2’den fazla olan iki kat ile dört kat arasındaki bütün binalarda,
b) Konutlar hariç, kat sayısı dörtten fazla olan bütün binalarda,
c) Konutlar dâhil bütün yüksek binalarda.
(3) Yapı yüksekliği veya toplam kapalı alanı Ek-7’deki değerleri aşan binalara otomatik yangın algılama cihazları tesis edilmesi mecburidir.

 

[iucfatih]

Yönetmelikte konutlar hariç kat alanı 400m2'den fazla olan İKİ KAT İLE DÖRT KAT arasındaki bütün binalarda diyormuş ben o iki katla dört katı atlamışım onuda yapabilirsek çok memnun olurum

 

[Ömer BARAN]

Merhaba.
Sorunuzu, muhtemel tüm seçeneklerin gerçekleştiği ve bunlara göre olması gereken sonuçların elle yazılarak gösterildiği
bir örnek belge üzerinden sorarsanız, kolaylıkla sonuca ulaşabilirsiniz gibi görünüyor.

Örnek belge özellikleri ve örnek belge yükleme yöntemine ilişkin açıklamalar cevabımın altındaki İMZA bölümünde var.
.

 

[iucfatih]

Merhaba.
Sorunuzu, muhtemel tüm seçeneklerin gerçekleştiği ve bunlara göre olması gereken sonuçların elle yazılarak gösterildiği
bir örnek belge üzerinden sorarsanız, kolaylıkla sonuca ulaşabilirsiniz gibi görünüyor.

Örnek belge özellikleri ve örnek belge yükleme yöntemine ilişkin açıklamalar cevabımın altındaki İMZA bölümünde var.
.

aynen hocam çok karışık oldu ama çözdüm olayı. İlginiz için çok teşekkür ederim sayenizde baya ilerlettim kendimi, kodlama mantığı kafamda oturmaya başladı.
belki birine fikir oluşturur diye yazdığım kodu atıyorum buraya, cümleten hayırlı geceler dilerim..

=EĞER(YADA(VE(YADA(F1="konaklama amaçlı binalar";F1="kurumsal binalar";F1="büro binaları";F1="ticaret amaçlı binalar";F1="endüstriyel yapılar";F1="toplanma amaçlı binalar";F1="depolama amaçlı tesisler";F1="yüksek tehlikeli yerler";F1="karışık kullanım amaçlı binalar");H4>400;YADA(K4=3;K4=2;K4=4));VE(YADA(F1="konaklama amaçlı binalar";F1="kurumsal binalar";F1="büro binaları";F1="ticaret amaçlı binalar";F1="endüstriyel yapılar";F1="toplanma amaçlı binalar";F1="depolama amaçlı tesisler";F1="yüksek tehlikeli yerler";F1="karışık kullanım amaçlı binalar");K4>4);H2>30,5;H3>21,5;K4>10);Sayfa2!A1528;"")

 

[Ömer BARAN]

Meseleyi kendinizin çözmesi elbette en güzeli ve faydalı olanı.
Ben de bir varsayıma göre aşağıdaki iki alternatif formülü oluşturdum. Birincisi aslında sizin formülünüz, ikincisi ise farklı bir bakış açısı.
Varsayım: F1 hücresinde, kaynak listesi AA1:AA9 aralığında (konaklama amaçlı binalar, kurumsal binalar,....) olan veri doğrulama uygulanmıştır.

SONRADAN EKLENEN NOT (03.02.2019 02:50): İkinci formül güncellendi.

=EĞER(YADA(VE(EĞERSAY($AA$1:$AA$9;F1)>0;H4>400;YADA(K4=3;K4=2;K4=4));VE(EĞERSAY($AA$1:$AA$9;F1)>0;K4>4);H2>30,5;H3>21,5;K4>10);Sayfa2!A1528;"")
=EĞER((((H2>30,5)+(H3>21,5)+(K4>10))+EĞERSAY($AA$1:$AA$9;F1)*((H4>400)+((K4=3)+(K4=2)+(K4=4))+(K4>4)))>0;Sayfa2!A1528;"")

 

[Ömer BARAN]

Önceki cevabımda tekrar değişiklik yapmak yerine yeni bir cevap olarak yazayım dedim.

Önceki cevabımda verdiğim ikinci formül yerine aşağıdakini de bir deneyin bakalım (veri doğrulama ile ilgili varsayım yine aynı elbette).
Aşağıdaki veya bundan önceki cevabımda verdiğim ikinci formülün istediğiniz sonucu vermesi lazım.
Formül mantığı kabaca: VE işlevindeki koşulları x şeklinde, YADA işlevindeki koşullar + olarak yazıldığında bunların toplamı 0'dan büyükse....

=EĞER(((H2>30,5)+(H3>21,5)+(K4>10)+EĞERSAY($AA$1:$AA$9;F1)*((H4>400)*((K4=3)+(K4=2)+(K4=4))+(K4>4)))>0;Sayfa2!A1528;"")