ARANAN DEĞERİN BULUNDUĞU SATIR BAŞLIK ADRESİ

[meslek5]

Merhaba iyi bayramlar.
Ekte yer alan Örnek dosyada alt-alta iki adet tablo var üstteki tablo kişilerin hangi günler hangi ilden sorumlu olduğunu gösteriyor. Alttaki tabloda kişilerin üstteki tabloda yerleştikleri illeri ilgili hücrelerde göstermek için nasıl bir formül yazılabilir? Soruyu tam anlatamamış olabilirim örnek dosyada çok net anlaşılıyor. Şimdiden teşekkür ederim.

İndir ÖRNEK

Dosyayı indir ÖRNEK

dosya.co

 

[YUSUF44]

C19 hücresinde aşağıdaki formülü kullanıp sağa ve aşağı kopyalayın:

=İNDİS($B$3:$B$15;KAÇINCI($B19;C$3:C$15;0))

 

[meslek5]

C19 hücresinde aşağıdaki formülü kullanıp sağa ve aşağı kopyalayın:

=İNDİS($B$3:$B$15;KAÇINCI($B19;C$3:C$15;0))

Yusuf bey teşekkür ederim bir kaç defadır yardımcı oluyorsunuz eksik olmayın
Bir şey daha rica etsem.. diyelimki üstteki tabloda ("C3") te "Aslı Dağcı_İletişim" yazılı olsun ve alttaki ("C19") da "Ankara_İletişim" yazdırabilirmiyiz. bu hücreleri örnek olarak verdim diğer hücrelerde de aynısı olacak. Eğer böyle bir formül mümkün değilse önemli değil.

 

[YUSUF44]

Sadece bu örnek için şağıdaki formül olur ama seçenekler farklılaşacaksa başka çözüm bulmak gerekir:

=EĞERHATA(İNDİS($B$3:$B$15;KAÇINCI($B19;C$3:C$15;0));İNDİS($B$3:$B$15;KAÇINCI($B19&"_İletişim";C$3:C$15;0))&"_İletişim")

 

[meslek5]

Sadece bu örnek için şağıdaki formül olur ama seçenekler farklılaşacaksa başka çözüm bulmak gerekir:

=EĞERHATA(İNDİS($B$3:$B$15;KAÇINCI($B19;C$3:C$15;0));İNDİS($B$3:$B$15;KAÇINCI($B19&"_İletişim";C$3:C$15;0))&"_İletişim")

Çok özür dilerim sadece iletişimi örnek verdim. Görevi değişebiliyor örneğin çarşamba günü falanca ilde "Teknik Sorunlar" veya "Pazarlama" da olabiliyor.

 

[meslek5]

Çok özür dilerim sadece iletişimi örnek verdim. Görevi değişebiliyor örneğin çarşamba günü falanca ilde "Teknik Sorunlar" veya "Pazarlama" da olabiliyor.

Ama ayraç her zaman (_) alttire bu değişmiyor

 

[YUSUF44]

Deneyin:

=EĞERHATA(İNDİS($B$3:$B$15;KAÇINCI($B19;C$3:C$15;0));İNDİS($B$3:$B$15;KAÇINCI($B19&"_*";C$3:C$15;0))&YERİNEKOY(İNDİS(C$3:C$15;KAÇINCI($B19&"_*";C$3:C$15;0));$B19;""))

 

[meslek5]

Deneyin:

=EĞERHATA(İNDİS($B$3:$B$15;KAÇINCI($B19;C$3:C$15;0));İNDİS($B$3:$B$15;KAÇINCI($B19&"_*";C$3:C$15;0))&YERİNEKOY(İNDİS(C$3:C$15;KAÇINCI($B19&"_*";C$3:C$15;0));$B19;""))

Teşekkür ederim tam istediğim gibi oldu. Yusuf bey ilerde ikili hatta üçlü görevler olma ihtimali var bu gibi durumlarda bu formül yine işe yarar mı?
Yani örnek verecek olursam "Zekiye Tunç_Aslı Dağcı_İletişim" veya "Fuat Kılıç_Ali Keskin_Mehtap Yavuz_Pazarlama" ister tekli görev ister ikili veya üçlü görevler de aynı formülü kullanabiliriz değil mi?

Zekiye Tunç - Ankara_İletişim
Aslı Dağcı - Ankara_İletişim
Fuat Kılıç - Ankara_Pazarlama
Ali Keskin - Ankara_Pazarlama
Mehtap Yavuz - Ankara_Pazarlama v.s. şeklinde

 

[YUSUF44]

Sanmıyorum. Bu durumda tablo yapınızı değiştirmeniz ve muhtemelen makro kullanmanız daha uygun olacaktır.

Örneğin bu formülle Zekiye Tunç_Aslı Dağcı_İletişim'i Pazartesi için İzmir'e yazdığımda formül sonucu Zekiye Tunç için İzmir_Aslı Dağcı_İletişim oldu.

 

[meslek5]

Sanmıyorum. Bu durumda tablo yapınızı değiştirmeniz ve muhtemelen makro kullanmanız daha uygun olacaktır.

Örneğin bu formülle Zekiye Tunç_Aslı Dağcı_İletişim'i Pazartesi için İzmir'e yazdığımda formül sonucu Zekiye Tunç için İzmir_Aslı Dağcı_İletişim oldu.

Sizin daha önce eğersay formülü için bana cevaben yazmış olduğunuz bir formül vardı kelimeyi cümle içinde arıyordu - "*"&B19&"*" - bunun gibi birşey acaba bu formül içinde kullansak olmaz mı?

 

[YUSUF44]

Sanmıyorum, beni aşıyor maalesef.

 

[meslek5]

Sanmıyorum, beni aşıyor maalesef.

çok teşekkür ederim bu formül bile işime yarıyor)

 

[meslek5]

Y

Sanmıyorum, beni aşıyor maalesef.

Yusuf bey tabloyu değiştirdim ve günleri iki sütuna ayırdım. Yeni dosya aşağıdaki linktedir.
Şöylede olabilir; Pazartesi gününe ait 1. sütuna şehir adı, 2. sütuna da görevi yazdırılabilirse bu da olur. Yani ilk alttireden önceki isim ile son alttireden sonraki görev ayrılabilirse bu da olabilir

İndir ÖRNEK

Dosyayı indir ÖRNEK

dosya.co

 

[YUSUF44]

Aşağıdaki formülü deneyin:


=EĞERHATA(İNDİS($B$3:$B$15;KAÇINCI($B19;C$3:C$15;0));İNDİS($B$3:$B$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0))&"_"&KIRP(SAĞDAN(YERİNEKOY(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0));"_";":"&YİNELE(" ";38);
UZUNLUK(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0)))-UZUNLUK(YERİNEKOY(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0));"_";)));38)))


Formülün KIRP'la başlayan kısmını aşağıdaki konuda sayın @bzace'nin cevabından aldım. 38 değeri hücredeki verilerin maksimum sayısına göre değiştirilmeli anladığım kadarıyla. Denemelerimde genel olarak doğru sonucu verdiğini gördüm:

Belirli bir karakterden sonrasını almak

Merhaba aşağıdaki kod ile ilk : karakterden sonrasını alabiliyoruz. Ama Ben son : karakterden sonrasını almak istiyorum nasıl yapabilirim? A1 den alıp B1 ye yazacağını varsayarsak: =EĞER(ESAYIYSA(UZUNLUK(A1)-MBUL(":";A1));SAĞDAN(A1;UZUNLUK(A1)-MBUL(":";A1));A1) Örnek Ali:Hasan:Ahmet:Mehmet...

www.excel.web.tr

 

[meslek5]

Aşağıdaki formülü deneyin:


=EĞERHATA(İNDİS($B$3:$B$15;KAÇINCI($B19;C$3:C$15;0));İNDİS($B$3:$B$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0))&"_"&KIRP(SAĞDAN(YERİNEKOY(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0));"_";":"&YİNELE(" ";38);
UZUNLUK(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0)))-UZUNLUK(YERİNEKOY(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0));"_";)));38)))


Formülün KIRP'la başlayan kısmını aşağıdaki konuda sayın @bzace'nin cevabından aldım. 38 değeri hücredeki verilerin maksimum sayısına göre değiştirilmeli anladığım kadarıyla. Denemelerimde genel olarak doğru sonucu verdiğini gördüm:

Belirli bir karakterden sonrasını almak

Merhaba aşağıdaki kod ile ilk : karakterden sonrasını alabiliyoruz. Ama Ben son : karakterden sonrasını almak istiyorum nasıl yapabilirim? A1 den alıp B1 ye yazacağını varsayarsak: =EĞER(ESAYIYSA(UZUNLUK(A1)-MBUL(":";A1));SAĞDAN(A1;UZUNLUK(A1)-MBUL(":";A1));A1) Örnek Ali:Hasan:Ahmet:Mehmet...

www.excel.web.tr

Oldu hocam teşekkür ederim. sadece kişi olmadığı durumlarda #YOK hatası çıkıyor oda önemli değil

 

[YUSUF44]

Formülü bir eğerhata formülü içine alırsanız düzelir muhtemelen.

=EĞERHATA(eskiformül;””)

gibi.

 

[meslek5]

Formülü bir eğerhata formülü içine alırsanız düzelir muhtemelen.

=EĞERHATA(eskiformül;””)

gibi.

=EĞERHATA(İNDİS($B$3:$B$15;KAÇINCI($B19;C$3:C$15;0));İNDİS($B$3:$B$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0))&"_"&KIRP(SAĞDAN(YERİNEKOY(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0));"_";":"&YİNELE(" ";38);
UZUNLUK(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0)))-UZUNLUK(YERİNEKOY(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0));"_"));38)))

bu formülün sonuna koyuyorum ama kabul etmiyor

 

[YUSUF44]


=EĞERHATA(EĞERHATA(İNDİS($B$3:$B$15;KAÇINCI($B19;C$3:C$15;0));İNDİS($B$3:$B$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0))&"_"&KIRP(SAĞDAN(YERİNEKOY(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0));"_";":"&YİNELE(" ";38);
UZUNLUK(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0)))-UZUNLUK(YERİNEKOY(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0));"_";)));38)));””)


 

[meslek5]


=EĞERHATA(EĞERHATA(İNDİS($B$3:$B$15;KAÇINCI($B19;C$3:C$15;0));İNDİS($B$3:$B$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0))&"_"&KIRP(SAĞDAN(YERİNEKOY(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0));"_";":"&YİNELE(" ";38);
UZUNLUK(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0)))-UZUNLUK(YERİNEKOY(İNDİS(C$3:C$15;KAÇINCI("*"&$B19&"*";C$3:C$15;0));"_";)));38)));””)


Ne kadar teşekkür etsem azdır. eksik olmayın