Aynı Kod ve Aynı Mağaza olan Satırları Toplamak

[ufo2020]

Merhaba,

Aşağıdaki tabloda kodu ve mağazası aynı olan satırlar bulunuyor,bu tablodaki böyle hücrelerin toplamını almak ve diğer tekil olanlarla beraber görebileceğim bir tablo hazırlamak istiyorum.Pivot tablo yapınca veya alt toplam yaptıgımda istediğim sonuca ulaşamadım,istediğim görüntüyü sayfa en altta örnek olması için kısaca gösterdim,teşekkür ederim

Kod	Ad	Mağaza	Satış Adedi
KIG-5005	Ultrasonik Hava Nemle	MERKEZ DEPO-3000	30​
KIG-5005	Ultrasonik Hava Nemle	ANKARA GIMART-1205	1​
KIG-5003	Angle Ultrasonik Hava Neml	OPTIMUM AVM-1626	11​
KIG-5004	Lore Ultrasonik Hava Nemle	ANTALYA ERASTA-1317	1​
KIG-5005	Ultrasonik Hava Nemle	VIAPORT ASIA OUTLET AVM-1909	-1​
KIG-5005	Ultrasonik Hava Nemle	CEVAHIR AVM-1908	1​
KIG-5005	Ultrasonik Hava Nemle	ERZINCAN PARK AVM-1901	1​
KIG-5005	Ultrasonik Hava Nemle	MERKEZ DEPO-3000	1​
KIG-5005	Ultrasonik Hava Nemle	MARMARA FORUM AVM-1911	1​
KIG-5004	Lore Ultrasonik Hava Nemle	DENIZLI TERASPARK-1209	1​
KIG-5005	Ultrasonik Hava Nemle	CORLU MERKEZ-1731	4​
KIG-5005	Ultrasonik Hava Nemle	ALANYA CADDE-1419	1​
KIG-5003	Angle Ultrasonik Hava Neml	MERKEZ DEPO-3000	1​
KIG-5003	Angle Ultrasonik Hava Neml	MEZITLI CADDE-1507	-1​
KIG-5003	Angle Ultrasonik Hava Neml	OPTIMUM AVM-1626	1​
KIG-5003	Angle Ultrasonik Hava Neml	ANKARA SOGUTOZU-1602	1​
KIG-5080	Ultrasonik Hava Nemle	MEZITLI CADDE-1507	6​

örnek

Kod	Ad	Mağaza	Satış Adedi
KIG-5005	Ultrasonik Hava Nemle	MERKEZ DEPO-3000	31​
KIG-5003	Angle Ultrasonik Hava Neml	MERKEZ DEPO-3000	1​

 

[uzmanamele]

Merhaba

Bunlardan birini deneyin.

=ÇOKETOPLA($D$2:$D$18;$A$2:$A$18;A25;$B$2:$B$18;B25;$C$2:$C$18;C25)
=TOPLA.ÇARPIM(($A$2:$A$18=A25)*($B$2:$B$18=B25)*($C$2:$C$18=C25)*($D$2:$D$18))

 

[ufo2020]

Hocam merhabalar,
bunu özet tablo gibi hale getirmem lazım,bu kodu yazmak için,tekrarlanan malzeme kodlarını bir yere yapıştırıp,tekrarlananları silmem gerekiyor sanırım,özet tablo gibi bir ekranda hem kod hem de içerik geliyor fakat mağaza kodları yanına gelmiyor

 

[Ömer]

Merhaba,

Deneyiniz.
A: D arasındaki verileri F:I arasına özet alarak listeler.

Sub ozet_al()
   
    Dim d As Object, i As Long, deg As String, son As Long, s As Long, veri, j As Byte
   
    Set d = CreateObject("Scripting.Dictionary")
    son = Cells(Rows.Count, "A").End(xlUp).Row
    veri = Range("A2:D" & son).Value
   
    ReDim dizi(1 To UBound(veri, 1), 1 To 4)

    For i = LBound(veri, 1) To UBound(veri, 1)
        deg = veri(i, 1) & "|" & veri(i, 2) & "|" & veri(i, 3)
        If Not d.exists(deg) Then
            s = s + 1
            d.Add deg, s
            For j = 1 To 4
                dizi(s, j) = veri(i, j)
            Next j
        Else
            dizi(d.Item(deg), 4) = dizi(d.Item(deg), 4) + veri(i, 4)
        End If
    Next i
   
    Range("F2:I" & Rows.Count).ClearContents
    Range("F2").Resize(s, 4) = dizi
    [F:I].EntireColumn.AutoFit
   
End Sub

 

[ufo2020]

hocam harikasın,teşekkür ederim
veri = Range("A2" & son).Value
[F:I].EntireColumn.AutoFit


buradaki içeriği değiştirince aralıkta değişiyormu?

 

[Ömer]

Evet fakat birden fazla bölümde aralığı etkileyen kısımlar var. Daha detaylı inceleyip dosyanıza uyarlamaya dikkat ediniz.