Benzer sayfaları bulmak

[serkol64]

Merhaba, Çalışma kitabında ; yüzde yüz birbirinin aynısı sayfaları nasıl bulabilirim ? örneğin ''2024 bütçesi'' diye yazdığım fakat sayfa altında isim kullanmadığım bir sayfayı daha sonra aynı kitabın diğer sayfalarında da olduğunu fark etsem ve sayfaların genel toplamı da örneğin 389 olsa ; ctr+f fonksiyonundaki çalışma kitabında ara yı kullanmadan nasıl bulabilirim ?

 

[catalinastrap]

Direk bu şekilde yapacak bir excel fonksiyonu yok ancak ; makro ile kontrol edebileceğin alternatif bir çözüm üretilebilir.

 

[catalinastrap]

Sub sayfakontrol()
Dim ws1 As Worksheet, ws2 As Worksheet
Dim sameSheets As String
Dim i As Integer, j As Integer

For i = 1 To ThisWorkbook.Worksheets.Count - 1
For j = i + 1 To ThisWorkbook.Worksheets.Count
If CompareWorksheets(ThisWorkbook.Worksheets(i), ThisWorkbook.Worksheets(j)) Then
sameSheets = sameSheets & ThisWorkbook.Worksheets(i).Name & " - " & ThisWorkbook.Worksheets(j).Name & vbCrLf
End If
Next j
Next i

If sameSheets <> "" Then
MsgBox "Aynı olan sayfa çiftleri:" & vbCrLf & sameSheets
Else
MsgBox "Tamamen aynı olan sayfa bulunamadı."
End If
End Sub

Function CompareWorksheets(ws1 As Worksheet, ws2 As Worksheet) As Boolean
Dim r1 As Range, r2 As Range
Dim i As Long, j As Long

Set r1 = ws1.UsedRange
Set r2 = ws2.UsedRange

If r1.Rows.Count <> r2.Rows.Count Or r1.Columns.Count <> r2.Columns.Count Then
CompareWorksheets = False
Exit Function
End If

For i = 1 To r1.Rows.Count
For j = 1 To r1.Columns.Count
If r1.Cells(i, j).Value <> r2.Cells(i, j).Value Then
CompareWorksheets = False
Exit Function
End If
Next j
Next i

CompareWorksheets = True
End Function

 

[serkol64]

teşekkürler bir deneyeyim

 

[serkol64]

evet benzer sayfaları buldu fakat imleç sürekli dönüyor yani beklememi, daha da fazla da olabileceğini mi ? söylüyor acaba

 

[serkol64]

Tekrar teşekkürler büyük bir sıkıntıdan kurtuldum

 

[catalinastrap]

Rica ederim kolay gelsin