Dosyayı her açtığımda otomatik filtreleme

[eterr]

Merhaba Arkadaşlar;

dosyayı her açtığımda sırasıyla şu filtrelemeler yapılmış olarak açılmasını istiyorum ;

1. A Sütünu A dan Z ye
2. B Sütünu A dan Z ye
3. C Sütünu A dan Z ye
4. D Sütünu A dan Z ye
5. J Sütunu " 0 olan değerleri gösterme "
6. J Sütunu " Büyükten küçüğe sırala "

Yardımlarınız için şimdiden teşekkür ederim.
Saygılarımla

 

[mancubus]

ThisWorkbook kod modülüne kopyalanacak. dosya xlsm olarak kaydedilecek

Private Sub Workbook_Open()

    With Worksheets("Stok")
        .Select
        If .FilterMode Then .ShowAllData
    
        With .ListObjects("Tablo1").Sort.SortFields
            .Clear
            .Add Key:=Range("Tablo1[Marka]"), Order:=xlAscending
            .Add Key:=Range("Tablo1[Kategori]"), Order:=xlAscending
            .Add Key:=Range("Tablo1[Alt Kategori]"), Order:=xlAscending
            .Add Key:=Range("Tablo1[Alt Kategori 2]"), Order:=xlAscending
            .Add Key:=Range("Tablo1[Stok]"), Order:=xlDescending
        End With
    
        With .ListObjects("Tablo1").Sort
            .Header = xlYes
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
    
        .ListObjects("Tablo1").Range.AutoFilter Field:=10, Criteria1:=">0", Operator:=xlAnd
    End With

End Sub

 

[eterr]

ThisWorkbook kod modülüne kopyalanacak. dosya xlsm olarak kaydedilecek

Private Sub Workbook_Open()

    With Worksheets("Stok")
        .Select
        If .FilterMode Then .ShowAllData
   
        With .ListObjects("Tablo1").Sort.SortFields
            .Clear
            .Add Key:=Range("Tablo1[Marka]"), Order:=xlAscending
            .Add Key:=Range("Tablo1[Kategori]"), Order:=xlAscending
            .Add Key:=Range("Tablo1[Alt Kategori]"), Order:=xlAscending
            .Add Key:=Range("Tablo1[Alt Kategori 2]"), Order:=xlAscending
            .Add Key:=Range("Tablo1[Stok]"), Order:=xlDescending
        End With
   
        With .ListObjects("Tablo1").Sort
            .Header = xlYes
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
   
        .ListObjects("Tablo1").Range.AutoFilter Field:=10, Criteria1:=">0", Operator:=xlAnd
    End With

End Sub

Çalışıyor, çok teşekkür ederim