Eğer ile Ve fonksiyonu kullanımı

[maestrocan77]

Excelim de A1 hücresinde Bir katsayım B1 hücresinde ise bir yüzde ifadem var.
C1 hücresine iç içe eğerli bir formül yazmak istiyorum ama formülüm hata veriyor.
Kurmak istediğim Formül B1 hücresindeki değer 85 altında ise 0, B1 hücresindeki değer 85 ile 100 arasında ise A1 hücresindeki değerin yarısı, B1 hücresindeki değer 100 ile 115 arasında ise A1 hücresindeki değeri B1 hücresindeki değer 115 den büyük ise A1 hücresindeki değerin 1,2 ile çarpımını veren bir formül yazmak istiyorum.

Fakat her seferinde hatalarla karşılaşıyorum.

Bu konu ile ilgili yardımlarınızı bekliyorum.
iyi çalışmalar

 

[muratboz06]

C1 e aşağıdaki formülü yazınız.

=EĞER(B1<0,85;0;EĞER(B1<1;A1/2;EĞER(A1<1,15;A1*B1;A1*1,2)))

 

[uzmanamele]

Merhaba
Deneyiniz.

=ARA(B1;{0;86;101;116};{0;0,5;1;1,2})*A1

 

[AdemCan]

Merhaba, alternatif Eğer ile Ve formülü.

=EĞER(B1<=85;0;EĞER(VE(B1>85;B1<=100);A1/2;EĞER(VE(B1>100;B1<=115);A1;EĞER(B1>115;A1*1,2))))

 

[Necdet]

Merhaba,

Bu tip fonksiyon yazımında aşama aşama yazarak kontrollü bir şekilde fonksiyonu yazmak gerek.

Açıklamanızda 1. şart için :

=EĞER(B1<85;0;"Bir")

Formülde "Bir" diye yazdığım ikinci şartı sağlamak için kontrol amaçlı yazılan bir değer.
Formülde Sadece 2. şart için : =EĞER(B1<100;A1/2;"İki")
Yine formülde "İki" ikinci şartın dışındaki şartı kontrol etmek için
3. şart için :

=EĞER(B1<=115;A1;A1*1,2)

Şimdi ilk Formülde yazılan "Bir" değerini silip 2. formülde yazılan değeri kopyalamak olacaktır.
1 ve 2. şart için :

=EĞER(B1<85;0;EĞER(B1<100;A1/2;"İki"))

formül bu aşamaya geldi
bu formüle artık 3. şartı da eklemek için formülde kalan "İki" değerini 3. şartta yazılan formülü kopyalamak olacaktır.
Sonuç : =EĞER(B1<85;0;EĞER(B1<100;A1/2;EĞER(B1<=115;A1;A1*1,2))) olacaktır.

 

[Necdet]

Ve formülün en kısa yolu da : Sayın UzmanAmele'nin formülüdür, bu tür çarpmalı bölmeli işlemler için.
Benimkisi ise genel açıklama olarak kalsın.

 

[uzmanamele]

Merhaba
Başka bir alternatif.
Bu şekilde basite indirgeyerek yüzlerce kriter belirleyebilirsiniz.

=(B1<85)*0+VE(B1>=85;B1<100)*0,5+VE(B1>=100;B1<115)*1+(B1>115)*1,2