Çözüldü Eski tarihi fonksiyon ve makro ile silme

[cavanoos]

Merhaba;

Ekteki örnek dosyada B sütununda aynı ürün kodu olan varsa eğer A sütunundaki en ufak tarihin olduğu satırdaki C sütununa ESKİ yazması için formül yazabilir misiniz ?
Bir de aynı işlemi makro ile yapabilir miyiz ?

 

[ÖmerFaruk]

C2 hücresine

=EĞER(VE(EĞERSAY($B$2:$B$6;B2)>1;A2=MİN(EĞER($B$2:$B$6=B2;$A$2:$A$6;"")));"ESKİ";"")

 

[ÖmerFaruk]

Sub Eski()
    Dim Dic, Veri
    Veri = Range("A2:B" & Range("A2").End(xlDown).Row).Value
    ReDim Liste(1 To UBound(Veri), 1 To 1)
    Set Dic = CreateObject("Scripting.Dictionary")
    For i = 1 To UBound(Veri)
        If Not Dic.Exists(Veri(i, 2)) Then
            Dic.Add Veri(i, 2), i & "-x"
        ElseIf Veri(i, 1) < Veri(Split(Dic(Veri(i, 2)), "-")(0), 1) Then
            Dic(Veri(i, 2)) = i & "-z"
        End If
    Next i
    For i = 1 To UBound(Veri)
        If i & "-z" = Dic(Veri(i, 2)) Then Liste(i, 1) = "ESKİ"
    Next i
    Range("C2").Resize(UBound(Veri), 1) = Liste
End Sub

 

[cavanoos]

ÖmerFaruk Bey;

İlginiz için teşekkür ederim.
Fonksiyon ile yaptığınız sonuç döndürmedi.
Makro ile yaptığınız oldu.
Makro ile yaptığınızda benim için uygundur, fonksiyon olmasa da olabilir.
Dosya ektedir.

Sizden birşey daha rica edeceğim.
Örneklerimizde iki kod vardı. Farkettim ki asıl tablomda ikiden daha fazla kayıt var.
Fonksiyonu aynı kodun en büyük tarihi kalacak ve diğerlerinde eski yazacak şekilde yapılabilir mi ?
Ya da makro ile yine aynı mantık yazılabilir mi ?

 

[ÖmerFaruk]

Bu ilk çalışmayan formül

=EĞER(VE(EĞERSAY($B$2:$B$7;B2)>1;A2=MİN(EĞER($B$2:$B$7=B2;$A$2:$A$7;"")));"ESKİ";"")

Bu en büyüğünü boş geçer diğerlerine eski yazar.

=EĞER(VE(EĞERSAY($B$2:$B$7;B2)>1;A2<MAK(EĞER($B$2:$B$7=B2;$A$2:$A$7;"")));"ESKİ";"")

Kod ila aşağıdaki gibi

Sub Eski2()
    Dim Dic, Veri
    Veri = Range("A2:B" & Range("A2").End(xlDown).Row).Value
    ReDim Liste(1 To UBound(Veri), 1 To 1)
    Set Dic = CreateObject("Scripting.Dictionary")
    For i = 1 To UBound(Veri)
        If Not Dic.Exists(Veri(i, 2)) Then
            Dic.Add Veri(i, 2), Veri(i, 1)
        ElseIf Veri(i, 1) > Dic(Veri(i, 2)) Then
            Dic(Veri(i, 2)) = Veri(i, 1)
        End If
    Next i
    For i = 1 To UBound(Veri)
        If Veri(i, 1) < Dic(Veri(i, 2)) Then Liste(i, 1) = "ESKİ"
    Next i
    Range("C2").Resize(UBound(Veri), 1) = Liste
End Sub

 

[cavanoos]

Kod ile olan oldu, emeğinize sağlık
Formül ile olan olmadı.
Ekte gönderiyorum ama benim için kod ile olan da yeterli, tekrar teşekkür ederim.

 

[ÖmerFaruk]

Formül dizi formüldüür. Ctrl+Shift+Enter ile girerseniz olacaktır.

 

[cavanoos]

Oldu
Peki aşağıdaki formülün dizi formül olduğunu nasıl anlarım ?
İşareti nedir ?


=EĞER(VE(EĞERSAY($B$2:$B$7;B2)>1;A2<MAK(EĞER($B$2:$B$7=B2;$A$2:$A$7;"")));"ESKİ";"")

 

[ÖmerFaruk]

EĞER($B$2:$B$7=B2;$A$2:$A$7;"")