ETOPLA Makro ile olur mu ?

[TUNCA ERSİN]

Sy. Hocalarım ;
=ETOPLA(Sayfa1!$E$2:$E$1500;AA2;Sayfa1!$T$2:$T$1500)
=ETOPLA(Sayfa1!$E$2:$E$1500;AA2;Sayfa1!$X$2:$X$1500)

Sub süz()
On Error Resume Next
Sayfa1.Range("e1:e1500").AdvancedFilter Action:=xlFilterCopy, CopyToRange:=Sayfa2.Range( _
"aa1"), Unique:=True
End Sub

1. Yukarıda Formülleri Kod ile yapabilir miyiz .
2. Yukarıda ki süz Makronun içine olabilir mi ?

Teşekkür ederim.

 

[ÖmerFaruk]

Birinci sorunuz.
orumda aratabilirsiniz, aşağıdakini yazın
WorksheetFunction.SumIf

İkinci sorunuz
Zaten makro olarak yazmışsınız. Neyi soruyorsunuz?

 

[TUNCA ERSİN]

Sy. @ÖmerFaruk ;

Hocam
1. sorumda bir çok örnekleri buldum ama kendime uygulayamadım.
2. Sorumda ise tek tuş ile iki makroyu çalıştırmak için yukarıda ki makronun içinde talep etmiş idim.

 

[Korhan Ayhan]

Aşağıdaki gibi deneyiniz.

Option Explicit

Sub Pivot_Table()
    Dim Son As Long

    Application.ScreenUpdating = False

    Sheets("Sayfa1").Range("E1:E1500").AdvancedFilter Action:=xlFilterCopy, _
    CopyToRange:=Sheets("Sayfa2").Range("AA1"), Unique:=True
    
    Sheets("Sayfa2").Range("AA1:AA" & Rows.Count).Sort Sheets("Sayfa2").Range("AA2"), Header:=xlYes
    
    Son = Sheets("Sayfa2").Range("AA" & Rows.Count).End(3).Row
    
    With Sheets("Sayfa2").Range("AB2:AB" & Son)
        .Formula = "=SUMIF(Sayfa1!$E$2:$E$1500,AA2,Sayfa1!$T$2:$T$1500)"
        .Value = .Value
    End With

    With Sheets("Sayfa2").Range("AC2:AC" & Son)
        .Formula = "=SUMIF(Sayfa1!$E$2:$E$1500,AA2,Sayfa1!$X$2:$X$1500)"
        .Value = .Value
    End With

    Application.ScreenUpdating = True

    MsgBox "Your transaction is complete.", vbInformation
End Sub

 

[TUNCA ERSİN]

Sy. @Korhan Ayhan ;

Hocam ellerinize sağlık Allah razı olsun teşekkür ederim. çok güzel oldu.