excel sayfasından ağ üzerindeki bilgisayara mesaj yollama

[imdatsaral]

sevgili arkadaşlar
ağ üzerinde ortak kullandığımız salt okunur excel dosyamız. dosya düzenlenip farklı kaydet ile ortak bir klasöre farklı isimlerle kaydediyoruz. benim sorunum bundan sonra başlıyor dosya kaydedildikten sonra bana haber verilmesi gerekiyorki işlem yapabileyim. Haber vermeler hep unutuluyor ve zor durumda kalıyorum. farklı kaydet yapıldıktan sonra bilgisayarlar mesaj göndermek mümkünmü

teşekkür ederim

 

[tansel]

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
 Dim Mesaj As String
 Mesaj = "Dosya " & Application.UserName & " tarafından farklı kaydedildi."
    If SaveAsUI Then
        x = Shell("NET SEND PC_Adı " & Mesaj)
    End If
End Sub

 

[Haluk]

Mrb;

Þu anda yerel ağ'a bağlı olmadığım için deneme şansım yok ama, aşağıdakileri bir ara denersiniz.

Kodlardaki Who = "raider" satırında, raider yerine, mesajın gönderileceği sizin yerel ağ üzerindeki bilgisayarınızın adını yazacaksınız.

Belki kullanılan işletim sistemine göre Txt = "NET SEND " & Who & " " & Msg satırını revize etmek gerekebilir.

ThisWorkbook modulune yerleştirilecek satırlar:

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    If SaveAsUI = True Then SendMsg
End Sub

Yeni bir module yerleştirilecek satırlar:

Sub SendMsg()
    Dim FName As String
    Dim FNo As Integer
    Dim Msg As String, Txt As String, Who As String
    Dim x
        Msg = "Dosya birazdan farkli kaydedilecek ...."
        Who = "raider"
        FName = ThisWorkbook.Path & Application.PathSeparator & "NetMsg.BAT"
        FNo = FreeFile
        Txt = "NET SEND " & Who & " " & Msg
        Open FName For Output As #FNo
            Print #FNo, Txt
        Close #FNo
        x = Shell(FName, 0)
    Kill FName
End Sub

İlave: tansel'in kestirme kodu daha güzel görünüyor, ben mesajımı post ettikten sonra o mesajı görebildim.

 

[imdatsaral]

bigisayarımın işletim sistemi win98 ve net send diye komut tanımadığını belirtiyor.
Peki arkadaşlar şöyle bir öneride bulunsam benim masa üstünü paylaşıma açsam excel formuna kısayol atmak için ilave birşeyler yapamazmıyız farklı kaydet yapıldığında benim makinama kısayol oluşturulabilirmi

İlginiz için teşekür ederim

imdat saral

 

[Haluk]

Win98 ile bahsettiğin problemi yaşayabilirsin...

Masa üstüne kısayol işiyle ilgili olarak eğer kodun çalıştırılacağı PC'de WSH yüklüyse, aşağıdakileri bahsettiğin dosyaya yerleştir.

ThisWorkbook Modulü:

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    If SaveAsUI = True Then CreateShortcut
End Sub

Aşağıdaki kodda MyFolder = "\\Raider\ortak\MyFolder\" satırında, "kırmızı" yazılı masaütü dosya yolunu kendi bilgisayarına göre değiştirirsin.

Yeni bir Modul:

Sub CreateShortcut()
    Dim WSscr As Object, NwShrtCut As Object
    Dim MyFolder As String
    Set WSscr = CreateObject("WScript.Shell")
    MyFolder = "\\Raider\ortak\MyFolder\"
    On Error Resume Next
    If Len(Dir(MyFolder)) = 0 Then MkDir (MyFolder)
    On Error GoTo 0
    Set NwShrtCut = WSscr.CreateShortcut _
                    (MyFolder & Application.PathSeparator & _
                    ThisWorkbook.Name & ".lnk")
    With NwShrtCut
        .TargetPath = WSscr.ExpandEnvironmentStrings(ThisWorkbook.FullName)
        .WorkingDirectory = WSscr.ExpandEnvironmentStrings(ThisWorkbook.Path)
        .WindowStyle = 4
        .IconLocation = WSscr.ExpandEnvironmentStrings _
                        (Application.Path & "\excel.exe , 0")
        .Save
    End With
    Set WSscr = Nothing
    Set NwShrtCut = Nothing
End Sub

 

[Fenomen]

ORTAK EXCEL SAYFASI KULLANMA

Araçlarda çalışma kitabını paylaştır seçeneğinden aynı anda kullanıcılaın değişiklik yapmasına izin ver seçeneği ile kullana bilirsin böylece okişiler değişiklik yaptığı ve kaydettiği anda değişikliği görebilirsin

 

[imdatsaral]

.save satırında hata veriyor

 

[Haluk]

\\imdat\c ile ifade ettiğiniz dosya yolu ile ilgili olarak;

1) "imdat" sizin bilgisayarın LAN üzerindeki adı mı ?

2) c 'i şifresiz olarak paylaşıma açtınız mı ?

3 ) hata mesajında ne diyor ?

 

[imdatsaral]

sorduğunuz sorulardan cevabımı buldum teşekür ederim.

makro çalışıyor ama saltokunur olduğu isimle kısayol atıyor yeni ismiyle yapamazmıyız. Þu haliylede işimi görüyor yardımlarınız için sağolun

 

[Haluk]

Eğer oluşturulan kısayolun, dosyanın yeni ismiyle yaratılmasını istiyorsanız, ThisWorkbook modulüne önceki kod yerine aşağıdaki kodu yerleştirin;

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    If SaveAsUI = True Then
        Application.OnTime Now, "CreateShortcut"
    End If
End Sub

Ama, eğer bu dosya açıksa o zaman bu kısa yola tıkladığınızda yine salt okunur olarak açılır. Sanki, daha önceki kod işinize daha çok yarayacak gibi geliyor bana.

 

[imdatsaral]

sorunum tamamen çözüldü herkese teşekkür ederim yardımlarınız için
benim isteğin sizin gibi olup benim gibi yardım isteyenlere yardıncı olmak yinede sorulan soruları okuyorum belki faydam olur diye

kendinize iyi bakın.

İmdat Saral
izmir