excell veriyi ikiye bölme

[sevensuleyman]

merhaba; güncelleme yaptıgım bir excell dosyam var. burada< yaklaşıuk 50.000 adet veri mevcuttur. buy excell dosyasını 25.000 - 25.000 oolarak ikiye bölüp ayrı ayrı excell dosyası olarak kaydetmesini istiyorum. excell dosya isimleri güncelleme1 güncelleme 2 şekilnde olabilir. bunu vba excell içerisinde buton oluşturarak yapmak istiyopru. yardımcı olursanız sevinirim şimdiden teşekkürler

 

[Haluk]

Sub Test()
'   Haluk - 30/03/2022
    Dim myRng As Range, lngStart As Long, lngStop As Long, iCount As Long
    Dim xRng As Range, newWB As Workbook
    
    Set myRng = ActiveSheet.UsedRange
    lngStart = 2
    
    Do Until lngStop >= myRng.Rows.Count
        iCount = iCount + 1
        
        lngStop = lngStart + 24998
        
        Set xRng = myRng.Range(myRng.Cells(lngStart, 1), myRng.Cells(lngStop, myRng.Columns.Count))
        
        Set newWB = Workbooks.Add
        
        myRng.Rows(1).Copy newWB.Sheets(1).Rows(1)
        newWB.Sheets(1).Range("A2").Resize(xRng.Rows.Count, xRng.Columns.Count) = xRng.Value
        newWB.Sheets(1).Name = "Güncelleme Bilgileri"
            
        newWB.SaveAs ThisWorkbook.Path & Application.PathSeparator & "Güncelleme-" & iCount & ".xlsx", FileFormat:=xlOpenXMLWorkbook
        newWB.Close
        
        lngStart = lngStop + 1
    Loop
    
    MsgBox "İşlem tamam !"
    
    Set newWB = Nothing
    Set xRng = Nothing
    Set myRng = Nothing
End Sub

.

 

[Haluk]

Soruyu sormanızdan 3 saat sonra size çözümü sağlayan kodu vermiştim ama aradan 3 gün geçti sizden olumlu veya olumsuz bir cevap gelmedi.

Bunun özel bir nedeni var mı?

.

 

[sevensuleyman]

Şuan telefondan yazıyorum bilgisayar başına geçip detaylı kontrol etme fırsatım olmadı. O yüzden dönemedim. Kusura bakmayın . Mutlaka olmuştur şimdiden teşekkürler

 

[sevensuleyman]

haluk bey çok teşekkürler muhteşem olmuş