Soru iki sütundaki sayıları karşılaştırma

[NADİR YILDIZ]

İki sütundaki sayıları karşılaştırıp renklendirme yapmak istiyorum.
koşullu biçimlendirme yaptığımda iki sütunda aynı sayıların hepsini renklendiriyor
C sütununda 7500 3 tane var
B sütununda 7500 1 tane var

ben bu gibi durumda sadece 1 tane 7500 renklendirmesini istiyorum

teşekkürler & iyi çalışmalar

 

[Korhan Ayhan]

Ben böyle durumlarda iki sütunu kendi içinde büyükten küçüğe sıralayıp karşılaştırıyorum. Zaten eşleşmeyenler direkt belli oluyor.

Sütunların yanına EĞERSAY fonksiyonu ile tutarların tekrar sayılarınıda alırsanız sorunun hangi tutardan oluştuğunu direkt görebilirsiniz. Sonrasında özet tablo ile verileri hızlıca karşılaştırabilirsiniz.
Hatta iki sütun altında toplam alınca fark çıkacağı için buradan da sonuca gidilebilir.

 

[NADİR YILDIZ]

üstad teşekkürler
ancak benim istediğim her iki sütunu karşılaştırıp.
bir sütunda aynı sayıdan 3 tane diğer sütunda 2 tane var ise her iki sütunda 2 tanesi renklendirmesi
1 tanesini renklendirmesin.
bu tam bir çözüm olmadı çünkü tablo geniş bir kısmını paylaştım..
başka öneriniz varmı

 

[Korhan Ayhan]

Elbette renklendirmede yapılabilir.

Ben sadece hızlı şekilde nasıl karşılaştırma yaptığımı paylaştım.

Zaten iki sütunu kendi içinde küçükten büyüğe sıraladığınızda tutarlar yan yana gelmiyorsa fark var demektir.

 

[NADİR YILDIZ]

üstada dediğinizi anladım zatende

iki sütundan ibaret değil tablonun sadece orta kısmındaki bir kısmı paylaştım büyükten küçüğe sıralama imkanı yok.

 

[Korhan Ayhan]

Deneyiniz.

Option Explicit

Sub Eslesen_Tutarlari_Renklendir()
    Dim S1 As Worksheet, Son As Long, Say As Long, Say_B As Long, Say_C As Long
    Dim Alan As Range, Aranan As Range, Hedef_Alan As Range, Bul As Range, Adres As String
    
    Application.ScreenUpdating = False
    
    Set S1 = Sheets("Zirve")
    
    Son = S1.Cells(S1.Rows.Count, 2).End(3).Row
    
    S1.Range("B2:C" & Son).Interior.ColorIndex = xlNone
    
    Say_B = WorksheetFunction.CountIf(S1.Range("B2:B" & Son), ">0")
    Say_C = WorksheetFunction.CountIf(S1.Range("C2:C" & Son), ">0")
    
    Set Alan = IIf(Say_B < Say_C, S1.Range("B2:B" & Son), S1.Range("C2:C" & Son))
    Set Hedef_Alan = IIf(Say_B < Say_C, S1.Range("C2:C" & Son), S1.Range("B2:B" & Son))

    For Each Aranan In Alan
        If Aranan.Value > 0 Then
            Set Bul = Hedef_Alan.Find(Aranan.Value, LookAt:=xlWhole)
            If Not Bul Is Nothing Then
                Adres = Bul.Address
                Do
                    If Bul.Interior.ColorIndex <> 6 Then
                        Aranan.Interior.ColorIndex = 6
                        Bul.Interior.ColorIndex = 6
                        Say = Say + 1
                        Exit Do
                    End If
                    Set Bul = Hedef_Alan.FindNext(Bul)
                Loop While Not Bul Is Nothing And Bul.Address <> Adres
            End If
        End If
    Next

    Set Alan = Nothing
    Set Hedef_Alan = Nothing
    Set Bul = Nothing
    Set S1 = Nothing

    Application.ScreenUpdating = True

    If Say > 0 Then
        MsgBox "Eşleşen tutarlar renklendirilmiştir.", vbInformation
    Else
        MsgBox "Eşleşen tutar bulunamadı!", vbExclamation
    End If
End Sub