Soru Karisik sayilarin baska bir hicre icinde kucukten buyuge dogru 1=1..1=5..2=2..3=4......seklinde ayni hucrenin icinde gösterilmesi

[netzone]

Merhaba,

Sorularınız ve tablonuz çok karışık gelse de son vermiş olduğunuz tabloda AX sütununa gelecek olan veriler için formülü şu şekilde yazdığınızda örneğinizdeki verileri elde edebilirsiniz.
*Excel 2003 de çalışacak mı test edemedim ancak Yapay zekaya sorduğumda Kesinlikle çalışır cevabı aldığımdan paylaşıyorum, deneyiniz.

=EĞER(B1="";"";TOPLA.ÇARPIM((B$1:B$24<=B1)/EĞERSAY(B$1:B$24;B$1:B$24)) & "=" & (RANK(B1;B$1:B$24;1)+EĞERSAY(B$1:B1;B1)-1))

Çalışırsa yatay ve dikey olarak hücre kulpundan çoğaltarak diğer sütunlar içinde kullanabilirsiniz.

İyi çalışmalar.

 

[Muzaffer Ali]

Sayın @netzone soruyu bir kez de ben anlatayım.
Formül ile çözüm bulamadım. Eğer formül ile çözüm bulunsa sayın azadem için daha iyi olacak.

Sizin yazdığınız formülde eğer sütundaki rakamlar küçükten büyüğe sıralı olsaydı çözüm olabilirdi ama sıralı değil.

Soru şu; Sütundaki rakamları küçükten büyüğe doğru sıralayıp sıra numarası verilecek.
Örnek B sütunu için 10 = 1, 20 = 2 gibi
Ardından 10 rakamının bulunduğu A sütunundaki rakam bulunacak.

Örnek: 10 rakamı 1., 2. ve 21. satırda geçiyorsa formül sonucu sırası ile 1=1, 1=2, 1=21 şeklinde dönmeli.
Sonra 20 rakamına bakılacak eğer 20 3. satırda bulunuyorsa formül sonucu 4. satıra 2=3 dönmeli.

Benim eklediğim dosyayı incelerseniz değerler doğru dönüyor.

 

[netzone]

Merhaba Muzaffer Bey,
Yukarıda da belirttiğim gibi örneklemeden yada tablonun sadece sayılardan oluşuyor olması, sonucun belirsizliği kafamda tam olarak oturmasına hala engel oluyor.

Netleşmesi açısından şu şekilde bir soru sormam gerekiyor, o zaman kurgu ve sonuçlar böylemi olmalı?

Elimizdeki dizi:
B1B24={5\5\5\5\5\10\10\10\10\10\15\15\15\15\15\20\20\20\20\20\25\25\30\30}

1. işlem: B1:B24 aralığında bulunan sayılar Küçükten büyüğe bir dizi oluşturuyor.
KüçüktenBüyüğeSıralıListe={5\5\5\5\5\10\10\10\10\10\15\15\15\15\15\20\20\20\20\20\25\25\30\30}

2.işlem: Bu yeni oluşan listeyi benzersiz olarak yeniden düzenlememiz gerekiyor.
BenzersizKBSıralıListe={5\10\15\20\25\30}

3.İşlem: İlgili satırın B sütununda bulunan değer Benzersiz küçükten büyüğe sıralı son listemizin kaçıncı sırasında yer alıyor bunu bulmamız gerekiyor.
=EĞER(B1="";"";TOPLA.ÇARPIM(($B$1:$B$24<=B1)/EĞERSAY($B$1:$B$24;$B$1:$B$24))) Bu formül işimizi görür diye düşünüyorum.

4. İşlem: Sizin de belirttiğiniz gibi 21. satırdaki değer eğer en küçük rakam ise ve 1=21 olarak sonuç almamız gerekiyor ise, bulunduğu satır zaten eşitliğin sağ tarafında gelecek olan rakamı verecektir.
=SATIR()

5. İşlem: 3 ve 4. işlem sonuçlarını "=" ile birleştirmemiz hücreye istenen veriyi yazacaktır.
=EĞER(B1="";"";TOPLA.ÇARPIM((B$1:B$24<=B1)/EĞERSAY(B$1:$B$24;B$1:B$24)))&"="&SATIR()

*Soruyu soran arkadaşımızın (Azadem) söyleminden ben eşitliğin sağında bulunduğu kısım satırdan değil de sizin (Muzaffer Bey) örneğinizdeki 1=21 yerine 1=3 olması gerektiğini düşünüyorum. Yani En küçük sayının 3. eşleşmesi gibi düşündüm.

Yanlış anladığım yer var ise bunu tekrar belirtirseniz yardımcı olmaya çalışırım.

*Ekleme:
Muzaffer Bey, söz konusu sizin dediğiniz gibi olması için işin içinden çıkamayınca Yapay Zeka ya epey soru yönelttim, genel olarak 2003 için VBA önerisinde bulunuyor. Formül ile yapmakta ısrarcı olduğumda yardımcı sütunlar kullanarak sonuca ulaştırmaya çalışıyor.

İyi çalışmalar.

 

[azadem]

Sayin hocam ve hocalarim, verdiginiz formulleri
tek tek ve tane tane yaptım daha önceki verdiğiniz ve sonraki eklediğiniz 3 ve 5 işlemler de dahil hocam şimdi bu 5 işlemde formülleri girdiğimde
1=1
1=2
1=3
Gibi giris yapiyor formulde diger asagiya dogru hepsi yaziliyor ama hocalarim, boyle B1 ve B 24 satirlarina baska sayilar girdigimde E1 sutununda degerlendirmelerde siralama islemi tam olarak calismiyor.
Simdi sevgili degerli hocalarim ben kendi aklimin erdigi kadariyla
Şu şekilde olayı anlatmaya calisacagim,
Örnegin, B1 ve B24 sutunlarinda da ayni A1 ve A24 deki gibi 1 den 24 kadar,
B1 ve B24 satirindada ayni sekilde 1 den 24 kadar sayilar olmus olsaydi,
E 1 ve E 24 sutunundada,

1=1
2=2
3=3
4=4
5=5
6=6
7=7
8=8
9=9
10=10
11=11
12=12
13=13
14=14
15=15
16=16
17=17
18=18
19=19
20=20
21=21
22=22
23=23
24=24
Ayni bu sekilde 24 tane deger ve 24 tane birbirine benzer olmayan 24 tane degisik sayilar olmus olucakti,..


Benim yapmak istedigim,bu B1 ve B 24 sutunlarinda bazen boyle tek olan sayilar oldugu gibide, bazende boyle ayni sayilardan 2 tane,3 tane, 4 tane, 5 tane,6 tane,7 tane, v.ss oolabiliyor,
ben bu E1 sutununda, "=" esittirin sol tarafina en kucuk kac tane 1= ci olarak B1 deki hangi sayilar en kucuk gelmisse onun A1 deki numarasini da, esittirin sag tarafina =24 numara A1 deki sayiyi temsil etsin istiyorum,
yani en kucuk sayi A1 deki numaraya gore 24 ise
1=24
Yazmak istiyorum..
B1 ve B24 te hangi sayilar gelmis onemli digil, B deki sayilarin en kucugu A1 ila A24 satirinda hangi numarayi temsil ediyorsa onu yapmak istiyorum...
B1 ve B 24 satirlarinda tek tek 24 tane islem olsa kucukten buyuge dogru siralama yapilir, ama ayni benzer sayilardan diyelim ki , 24 u , 3 e bolsek 8 er tane ayni benzer sayilar olucak, boyle 8 er tane benzer sayilar oldugunda, E 1 satirinada o zaman, 3 tane derecelendirme yapilmis sayilicak.

24 sayi icinde diyelimki 6 şar tane benzer sayilar olursa, E1 hucresine esittirin sol tarafina 4 tane derecelendirme yapilmis olucak.

Yani hocam, esittirin sol taraflari kac tane en kucuk sayilari derecelendirme yeri,
sag taraf ise, B1 deki sayilarin ,A1 deki temsil ettihi numarasini gosteren yer olmus olucak,.esittirin sol tarafi her zaman deresini kacinci en kucuk olduklarini belirleyen yer,
sag tarafta hangi numarayi temsil ettigi yeri olmus olucak.

 

[azadem]

@netzone hocamin yazdigi formulleri tek tek yazdim girdim, taplodaki gibi ayni sekilde oldu , lakin B1 ve B 24 satirlarina degisik yeni farkli sayilar girdigimde,bu sefer B1 satirinda en buyuk bir sayi girdigimde onu en son en alt satirda yani E24 cu satirda gostermesi gerekirken gene en ustte E 1 satirinda gosteriyor,
en alt satirda kacinci dereceyi temsil ediyorsa o derecesiyle beraber en son satirda gostermesi gerekiyor bu sekilde yapmiyor hocan, gene en ust satirinda gosteriyor,

B formuller cok yaklasti ama uzerinde bir kac duzenleme yapilirsa tam olarak duzenlenmis olucak insalah.


Sayın hocam böyle size attığım tabloda Siz o yeşil alandaki B1 ve B 24 satırlarında kendinize göre değişik sayılar girin en küçükten büyüğe birbirine benzer ikişer üçer beşer tane aynı şekilde formül değişiyorsa gene sıralamayı en küçükten büyüğe derecelendirme yapıyorsa olmuş olur yapmıyorsa formülde o eksik bir iki nokta var artık onu da size benim yön vermek haddime değil kendini zaten hemen görüp onu hemen yapacağınıza inanıyorum Benim buradaki eksikliğim sadece şu Ben sizin gibi tecrübeli ve Bilgi sahibi olmadığım için ne yapmak istediğimi kısa bir şekilde anlatamıyorum ondan dolayı size de böyle anlatmaya çalışırken sizi de böyle belki bıktırıyorum Hakkınızı helal edin lütfen Ben de sizin gibi tecrübeli olup şu kadar şurada eksiğim var kısa özet yaparak anlatmayı çok isterdim ama anca böyle tane tane adım adım bu şekilde anlatabiliyorum beni de mazur görün hoşgörünüze sığınıyorum Teşekkür ederim Sevgili Hocam Allah razı olsun yardımcı olmak için bıkmadan üşenmeden değişik formüllerle yardımcı olmaya çalıştığınız için Hepinizden Allah razı olsun İnşallah şimdi bu anlattığım şekilde tam istediğimi anlatabilmişimdir inşallah tablo üzerinde yeşil alanda değişiklik yaparak daha iyi formülü düzenlemiş olursunuz İnşallah hocam Ben böyle inanın o verdiğini formüller hep denedim Tek Tek İşte çok yaklaşmış o kadar yakın ki bir iki şey değiştiğinde formül tam oturacak inanıyorum canım hocam hepinizden ayrı ayrı Allah razı olsun

 

[azadem]

Yeşil alanda B1 hücresinde sayıları girdiğinizde formülünü zaten çalışıp derecelendirme yaptığınız çok rahat görürsünüz sayın hocam Ben birkaç kere yaptım formül en büyük sayıları da 1 2 3 sıralarda gösteriyor Halbuki en sonlarda göstermesi lazımken böyle ters çalışan bir yeri var Onu da düzeltemedim beceremedim hocam

 

[netzone]

Merhaba,

Söyleminize göre Muzaffer Bey'in belirttiği şekilde örneğin sonucu 3.satırda 1=21 olarak gelmesi gerekiyor. Söz konusu eski bir sürüm kullanmış olduğunuz için gelişmiş formülleri kullanamadığınızdan VBA kodları ile yapılması yada tablonuzunda müsaitlik durumuna göre farklı sütunlara çekilecek olan eşleşmeler sonrası yeni verilere dayanarak istedikleriniz çekilebilir.

(?)- Kullanım dışı olan sütununuz var ise bu sütunları belirtirseniz bu sütunlarda kullanılacak formülü ve buna bağlı söz konusu sarı renkli sütununuza yazılacak yeni formüller oluşturulabilir.

(?)- Yeşil renkli sütunlarınız dışında kalan sütunlar sadece sarı sütuna yazacağınız değeri oluşturma çabası için mi yapılmış durumda, yoksa herhangi bir kullanım için mi hazırlandı.

İyi çalışmalar.

 

[Muzaffer Ali]

Sayın @netzone 23. mesajda paylaştığınız formül doğru sonuç döndürüyor. Tek eksiği sonuçların alfabetik sıralanması gerekiyor.

=EĞER(B1="";"";TOPLA.ÇARPIM((B$1:B$24<=B1)/EĞERSAY(B$1:$B$24;B$1:B$24)))&"="&SATIR()

Doğru Sonuç	Formül Sonucu
1=1	1=1
1=2	1=2
1=21	2=3
2=3	2=4
2=4	2=5
2=5	8=6
3=8	8=7
3=23	3=8
3=24	4=9
4=9	4=10
4=10	5=11
5=11	6=12
5=20	7=13
5=22	8=14
6=12	8=15
6=17	9=16
7=13	6=17
7=18	7=18
8=6	10=19
8=7	5=20
8=14	1=21
8=15	5=22
9=16	3=23
10=19	3=24

 

[netzone]

Sayın @netzone 23. mesajda paylaştığınız formül doğru sonuç döndürüyor. Tek eksiği sonuçların alfabetik sıralanması gerekiyor.

=EĞER(B1="";"";TOPLA.ÇARPIM((B$1:B$24<=B1)/EĞERSAY(B$1:$B$24;B$1:B$24)))&"="&SATIR()

...

Merhaba Muzaffer Bey, belirttiğiniz gibi sıralama yaptırmadan önce SATIR() ile çekilen dinamik veri yerine yardımcı sütun kullanarak bağlı veriler çektirilebilir, sonrasında sıralama yapılır ancak örneğe göre A-Z sıralaması yaptırdığımızda; 1 den sonra 10, sonra 2,3... diye devam edecektir. bu duruma da çözüm bulunması gerekir.

Pek vakıf değilim ama dizi formülleriyle belki yardımcı sütuna gerek kalmadan da yapılabilir. Komplike formüller yazmak konusunda forumda uzman arkadaşlarımız var belki onlar bu duruma bir çözüm üretebilirler.

İyi çalışmalar

 

[52779]

Formülle çözüm için, Uzunca bir Dizi formül çalışması
Veriler : B2:B25 aralığında
D2 hücresine yazılan DİZİ Formül
(Not : Dizi formülün hücreye girişi sadece Enter ile değil CTRL + SHIFT + ENTER tuşlarının 3 üne aynı anda basılarak yapılmalıdır)

=TOPLA.ÇARPIM(($B$2:$B$25<TAMSAYI(İNDİS($B$2:$B$25+(SATIR($B$2:$B$25)-SATIR($B$2)+1)/10^3;KAÇINCI(KÜÇÜK($B$2:$B$25+(SATIR($B$2:$B$25)-SATIR($B$2)+1)/10^3;SATIR($B1));$B$2:$B$25+(SATIR($B$2:$B$25)-SATIR($B$2)+1)/10^3;0))))/EĞERSAY($B$2:$B$25;$B$2:$B$25))+1&"="&YUVARLA(MOD(İNDİS($B$2:$B$25+(SATIR($B$2:$B$25)-SATIR($B$2)+1)/10^3;KAÇINCI(KÜÇÜK($B$2:$B$25+(SATIR($B$2:$B$25)-SATIR($B$2)+1)/10^3;SATIR($B1));$B$2:$B$25+(SATIR($B$2:$B$25)-SATIR($B$2)+1)/10^3;0));1);3)*10^3

Örnek aşağıdaki şekilde

	A​	B​	C​	D​	E​
1​		Değerler		Sıralama	Sıralama
2​		5		1=1	1=1
3​		5		1=2	1=2
4​		10		1=21	1=21
5​		10		2=3	2=3
6​		10		2=4	2=4
7​		40		2=5	2=5
8​		40		3=8	3=8
9​		15		3=23	3=23
10​		20		3=24	3=24
11​		20		4=9	4=9
12​		25		4=10	4=10
13​		30		5=11	5=11
14​		35		5=20	5=20
15​		40		5=22	5=22
16​		40		6=12	6=12
17​		45		6=17	6=17
18​		30		7=13	7=13
19​		35		7=18	7=18
20​		50		8=6	8=6
21​		25		8=7	8=7
22​		5		8=14	8=14
23​		25		8=15	8=15
24​		15		9=16	9=16
25​		15		10=19	10=19

Eğer Ad Tanımlaması yaparak formüle edilirse formül hem normal standart formül (sadece Enter ile girilebilen formül) olacak ve hem de kısalacaktır.
Ad Tanımlaması için
Formüller >>> Tanımlı Adlar >>> Ad Tanımla yolunu takip ederek
Ad kutucuğuna a yazın
Başvuru yerine ise (üstteki uzun formülde tekrarlanan kısım olan aşağıdaki formülü kopyalayın ve Tamam deyin. (Ad tanımlamalarında, sayfa adları gereklidir, ancak siz bu şekilde sayfadayken kopyaladığınızda sistem otomatik olarak sayfa adlarını da ekleyecektir.)

=İNDİS($B$2:$B$25+(SATIR($B$2:$B$25)-SATIR($B$2)+1)/10^3;KAÇINCI(KÜÇÜK($B$2:$B$25+(SATIR($B$2:$B$25)-SATIR($B$2)+1)/10^3;SATIR($B1));$B$2:$B$25+(SATIR($B$2:$B$25)-SATIR($B$2)+1)/10^3;0))

ve D2 hücresine aşağıdaki formülü kopyalayın.

=TOPLA.ÇARPIM(($B$2:$B$25<TAMSAYI(a))/EĞERSAY($B$2:$B$25;$B$2:$B$25))+1&"="&10^3*YUVARLA(MOD(a;1);3)

Örnek dokuman ektedir. İncelersiniz...

Sıralama - Filemail

Click here to view and download these shared files from Filemail.com

www.filemail.com

 

[Korhan Ayhan]

Bende ekteki gibi bir çözüm dosyası hazırladım. Sayfayı klonladım ve sıralama işlemini klon sayfada yaptım. Siz DATA sayfasına verilerinizi girdikten sonra SIRALAMA sayfasındaki sütunları dilediğiniz gibi çoğaltabilirsiniz.

Örnek olması açısından sayıları rastgele ürettim. F9 tuşuna bastıkça sıralamalar değişecektir.

 

[52779]

Bu arada
Excel 2021, 2024 ya da 365 kullanıyorsanız eğer
F2 hücrsine (boş bir kolonun hücresine) aşağıdaki gibi bir formülü yazın, sonuçlar dökülmeli gelecektir.

=LET(a;B2:B25;b;SIRALA(BENZERSİZ(a));c;SIRALI(SATIRSAY(a));KAÇINCI(SIRALA(a);b;)&"="&SIRALAÖLÇÜT(c;a))

 

[azadem]

Sayın hocam ben Excel 2003 kullanıyorum. O yüzden böyle bu 2024-25 dediğiniz sistem ve formüller Bendeki Excel'de çalışmaz muhtemelen..
Ama bir tane sağ olsun bir hocamız Dün bir formül yapıp yolladı o formülü yaptım ama bu formülde derecelendirmedeki sıra dizilişi karışık oluyor ilk yaptığım B1 B24 sıralamasında normal yapılıyor,
Ama diger C 1 ve D1 gibi,
Yan yana devam eden işlemler yapmaya çalıştığımda diziliş sırası karışıyor yani 1 derecedekiler 2 derece 3 derece sırasıyla gitmesi gerekirken 5 sıradan başlıyor 4 sıra 6 7 sıra sonra 1 sırayı altlara bırakıyor böyle karışık bir diziliş derecelendirme sırası yapıyor yoksa formülü o hocamız yaptı sağ olsun Ama sadece sıralamada düzene girmiyor şimdi sizi o tabloyu atacağım hocam bu formülü de atacağım üzerinde düzenleme yapabilirseniz bu sıralama ile ilgili ona göre tam oturmuş olacak yardımlarınız için şimdiden teşekkür ederim sayın hocam

 

[azadem]

Hocam formülü burada yazacağım tablo üzerinde yapamadım yazılmadı cep telefonundan düzenliyorum O yüzden formülü tabloda yapamıyorum burada yazacağım sizlere zahmet üzerinde yapar denersiniz eksik olan düzensizliği yaparsınız inşallah

 

[azadem]

=eger(B1=" " ;" ";topla.carpim((B$1:B$24<=B1)/egersay(B$1:$B$24;B$1:B$24)))&"="&satir( )

 

[azadem]

Formül bu hocam tablo üzerinde ilk B1'deki sıralamayı
Düzgün yapıyor ama C1 ve D1'e devam ettiğimde sıralama karışık oluyor 5.ci dereceden başlıyor 3.cu derece 8.ci derece gibi rastgele diziliş yapıyor hocam.
Normalde en küçük ilk günün mutlu derecelendirmeden en son kaçıncı derecelendirme oluyorsa ona,1 den 24 tane olan sayilarin ,,
Kaç tane aynı benzer sayılar denk de gelse,1ci dereceden en kucukten buyuge kac tane derecelendirmeyi yapmak istiyorum hocam.

Yani şu şekilde anlatmak isterim hocam 1'den 24'e kadar olan karışık sayılarda kaç tane derece lendirme denk geliyorsa onu yapmak,
2 şer 2 ser tane aynı sayı denk gelse 12 tane derecelendirme olmuş olacak,

3 er 3 er tane
Aynı sayılar denk gelse bu sefer 8 tane derecelendirme olacak.

4der 4 der, tane aynı sayılar denk gelse 6 tane derecelendirme olacak.

6 sar 6 sar tane benzer sayılar olmuş olsa bu seferde 4 tane derecelendirme olacak.

Bunun gibi formülde yapmak istediğim derecelendirme sırasında karışık şekilde derecelendirme yapıyor Bunu normal düzenleyebilinirse formul tam olarak calismis olucak insalah hocam.

 

[Korhan Ayhan]

Belki bu çözüm işinize yarayabilir...

Soru - Karisik sayilarin baska bir hicre icinde kucukten buyuge dogru 1=1..1=5..2=2..3=4......seklinde ayni hucrenin icinde gösterilmesi

Merhaba, Sorularınız ve tablonuz çok karışık gelse de son vermiş olduğunuz tabloda AX sütununa gelecek olan veriler için formülü şu şekilde yazdığınızda örneğinizdeki verileri elde edebilirsiniz. *Excel 2003 de çalışacak mı test edemedim ancak Yapay zekaya sorduğumda Kesinlikle çalışır cevabı...

www.excel.web.tr