Klasörden Dosya İsimlerini Almak

[1Al2Ver]

Merhaba,

Aşağıdaki kod ile, seçilen klasörden, klasörde mevcut dosyaları listeleye biliyorum,

İsteğim ; Kod'da hedef belirleyerek dosyaları almak,

Örneğin ; "C" sürücüsünde "YEDEKLER" klasörü'ndeki dosya isimlerini listelemek,

Teşekkür ederim.

Sub Dosya_Listeleme()
Application.ScreenUpdating = False
    Dim I As Long
    Dim xFileName As String
    Dim xFileDlg As FileDialog
    Dim xFileDlgItem As Variant
    On Error Resume Next
  I = 1
    Cells(I, 1).Value = "Dosya Adı"
    With Cells(I, 1).Font
    .Name = "Arial"
    .FontStyle = "Bold"
    .Size = 10
    End With
    Cells(I, 1).EntireColumn.AutoFit
    Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)
 
    If xFileDlg.Show = -1 Then
        xFileDlgItem = xFileDlg.SelectedItems.Item(1)
        xFileName = Dir(xFileDlgItem & "\")
        Do While xFileName <> ""
                I = I + 1
                Cells(I, 1).Value = xFileName
                xFileName = Dir
        Loop
    End If
    Columns("A").AutoFit
    Application.ScreenUpdating = True
End Sub

 

[Korhan Ayhan]

Deneyiniz.

Option Explicit

Sub Klasordeki_Dosya_Isimlerini_Listele()
    Dim Klasor As String, Dosya As String
    
    Klasor = "C:\YEDEKLER\"
    
    Dosya = Dir(Klasor & "*.*")
    
    Range("A:A").Clear
    Range("A1") = "Dosya Adı"
    Range("A1").Font.Bold = True
    
    While Dosya <> ""
        Cells(Rows.Count, 1).End(3)(2, 1) = Dosya
        Dosya = Dir
    Wend
    
    Range("A:A").EntireColumn.AutoFit
    
    MsgBox "Klasördeki dosya isimleri listelenmiştir.", vbInformation
End Sub

 

[tevfik657]

Merhaba,
ekteki dosyada, klasör içindeki dosya isimlerini listeleyebilir, toplu isim değştirebilirsiniz. Seçim yaparken istediğiniz klasörü seçme imkanı tanıyor.

Not: Dosya bana ait değil, yine burada bulmuştum.


Syg.

 

[1Al2Ver]

Sayın Korhan Ayhan merhaba,

İlginiz ve çözüm için çok teşekkür ederim, sağ olun.

Saygılarımla.

 

[1Al2Ver]

Sayın tevfik657 merhaba,

İlginiz ve alternatif çözüm için çok teşekkür ederim, sağ olun.

Saygılarımla.