Çözüldü Koşula göre veri aktarma

[savasizgeneral]

Merhaba veri giriş çıkışlarını ilgili sayfalara aktarmak istiyorum. Veri sayfasındaki veri türüne ( GİRİŞ ve ÇIKIŞ ) göre ilgili sayfasına aktarmak ve veri sayfasındaki verileri temizlemek istiyorum. Bazı satırlar boş onları o şekilde boş atmalı. Ayrıca aktarılan verilerin sürekli olarak son satırdan itibaren eklenmesini istiyorum.
Şimdiden yardımlarınıza teşekkür ederim.



https://dosya.co/syg3drwmqfzp/MAKRO_İLE_AKTARMA.xlsx.html

 

[ÖmerBey]

Merhaba,
Deneyiniz...

Sub kod()
Dim V As Worksheet, G As Worksheet, C As Worksheet
Dim a As Long, s As Long, g1 As Long, g2 As Long, c1 As Long, c2 As Long
Dim b As Byte
Set V = Sheets("Veri")
Set G = Sheets("Giriş")
Set C = Sheets("Çıkış")
g1 = Application.CountIf(V.Range("A:A"), "GİRİŞ")
c1 = Application.CountIf(V.Range("A:A"), "ÇIKIŞ")
If g1 > 0 Then ReDim dzG(1 To g1, 1 To 9)
If c1 > 0 Then ReDim dzC(1 To c1, 1 To 9)
g2 = 1
c2 = 1
s = V.Cells(Rows.Count, "A").End(3).Row
For a = 5 To s
    If V.Cells(a, "A") = "GİRİŞ" Then
        For b = 1 To 9
            dzG(g2, b) = V.Cells(a, b)
        Next
        g2 = g2 + 1
    ElseIf V.Cells(a, "A") = "ÇIKIŞ" Then
        For b = 1 To 9
            dzC(c2, b) = V.Cells(a, b)
        Next
        c2 = c2 + 1
    End If
Next
If g1 > 0 Then G.Cells(Rows.Count, "A").End(3)(2, 1).Resize(UBound(dzG), UBound(dzG, 2)).Value = dzG
If c1 > 0 Then C.Cells(Rows.Count, "A").End(3)(2, 1).Resize(UBound(dzC), UBound(dzC, 2)).Value = dzC
V.Range("A5:I" & s).ClearContents
End Sub

 

[savasizgeneral]

Teşekkür ederim Ömer bey,
tam istediğim gibi olmuş.

 

[savasizgeneral]

Ömer Bey küçük bir sorunla karşılaştım. Veri satırına sadece giriş veya sadece çıkış olarak veri ekleyince makro hata veriyor.

 

[ÖmerBey]

Yukarıdaki kodu güncelledim, deneyiniz.