koşullu benzersiz formülleri

[modoste]

koşullu benzersiz sayısını bulan formüller arasındaki fark
merhaba sayın hocalarım
ekli dosyamda 2 adet doğru sonucu veren formül bulunmakta
F5:F16 arasındaki sayı verilerinden birini "Ali" olarak değiştirdiğimde (ekli dosyamda "Ali" ekli olmayacak ama F10 hücresine "Ali" yazıp sonuçlara bakılınca
G5 formülü doğru sonuç verip 6 cevabını bulurken diğer formül H5 ise değişiklik olmuyor ve 5 de kalıyor.

diğer formülünce doğru sonucu vermesi için formül nasıl değiştirilir ve başla alternatif formüller varmıdır.


not: bir abime bu formülleri attım ama o anlamadı. ilk kez gördü sıklık ve ctrl+shift+enter formüllerini bunlardan başka formüllerle çözülür mü dedi bende o bakımdan size soruyorum

 

[modoste]

koşullu benzersiz sayısını bulan formüller arasındaki fark
merhaba sayın hocalarım
ekli dosyamda 2 adet doğru sonucu veren formül bulunmakta
F5:F16 arasındaki sayı verilerinden birini "Ali" olarak değiştirdiğimde (ekli dosyamda "Ali" ekli olmayacak ama F10 hücresine "Ali" yazıp sonuçlara bakılınca
G5 formülü doğru sonuç verip 6 cevabını bulurken diğer formül H5 ise değişiklik olmuyor ve 5 de kalıyor.

diğer formülünce doğru sonucu vermesi için formül nasıl değiştirilir ve başla alternatif formüller varmıdır.


not: bir abime bu formülleri attım ama o anlamadı. ilk kez gördü sıklık ve ctrl+shift+enter formüllerini bunlardan başka formüllerle çözülür mü dedi bende o bakımdan size soruyorum

 

[modoste]

ilk mesajımdan sonrakileri yanlışlıkla ekledim nasıl silebiliyorum.

 

[Korhan Ayhan]

Deneyiniz.

=TOPLA(EĞER(SIKLIK(EĞER((C5:C15="AAA")*(D5:D15="BBB")*(E5:E15="CCC");KAÇINCI(F5:F15;F5:F15;0));SATIR(F5:F15)-4)>0;1))

 

[modoste]

denedim korhan hocam çözüm doğru
teşekkür ederim.

 

[Korhan Ayhan]

Bu da normal fonksiyon;

=TOPLA.ÇARPIM((C5:C15="AAA")*(D5:D15="BBB")*(E5:E15="CCC")*(1/ÇOKEĞERSAY(F5:F15;F5:F15&"")))

 

[Korhan Ayhan]

Ayrıca linki inceleyiniz.

https://www.excel.web.tr/threads/tekrarsiz-adedi.117420/

 

[modoste]

sayın korhan hocam
6 nolu mesajınzdaki formülü
ekli dosyama ekledim sarı dolgu renkli cevabı buldu. küsüratlı bir cevap buldu.

 

[Korhan Ayhan]

Aşağıdaki gibi deneyince doğru sonucu veriyor.

=TOPLA.ÇARPIM(($D$9:$D$100>=$J$3)*($D$9:$D$100<=$K$3)*($E$9:$E$100=$H5)*1/ÇOKEĞERSAY($D$9:$D$100;$D$9:$D$100&"";$E$9:$E$100;$E$9:$E$100&"";$F$9:$F$100;$F$9:$F$100&""))

 

[modoste]

evet hocam denedim bende teşekkür ederim

 

[modoste]

sayın korhan hocam
az önce detaylı formüle baktığımda ekli dosyamda sarı dolgulu yerdeki cevap yanlış buluyo. bakabilir misiniz

 

[Korhan Ayhan]

Tarih kriterini değişken olduğu için ÇOKEĞERSAY içinden sanırım elemek gerekiyor. Aşağıdaki gibi deneyiniz.

=YUVARLA(TOPLA.ÇARPIM(($D$9:$D$100>=$I$2)*($D$9:$D$100<=$J$2)*($E$9:$E$100=$H5)*1/ÇOKEĞERSAY($E$9:$E$100;$E$9:$E$100&"";$F$9:$F$100;$F$9:$F$100&""));0)

 

[Korhan Ayhan]

Sanıyorum doğru yöntem aşağıdaki gibi olması gerekiyor. Deneyiniz.

=TOPLA.ÇARPIM(($D$9:$D$100>=$I$2)*($D$9:$D$100<=$J$2)*($E$9:$E$100=$H5)*($D$9:$D$100<>"")/ÇOKEĞERSAY($D$9:$D$100;$D$9:$D$100&"";$E$9:$E$100;$E$9:$E$100&"";$F$9:$F$100;$F$9:$F$100&""))

 

[modoste]

yanlış sonuç veriyor hocam doğru formül değil
crl+shift+enter ile olan 4 nolu mesajınızdaki formülü ben kullanıyorum ama arkadaşım topla.çarpım lı olanı kullanmak istiyo

 

[Korhan Ayhan]

En son önerdiğimi denediniz mi?

 

[modoste]

denedim hocam elbette ama olmadı hatalı sonuç veriyo

 

[Korhan Ayhan]

Şu şekilde DİZİ formül olarak çözüme gidebildim.

=TOPLA(($D$9:$D$100>=$I$2)*($D$9:$D$100<=$J$2)*($E$9:$E$100=$H5)*EĞERHATA(1/ÇOKEĞERSAY($D$9:$D$100;">="&$I$2;$D$9:$D$100;"<="&$J$2;$E$9:$E$100;H5;$F$9:$F$100;$F$9:$F$100&"");0))

 

[modoste]

en son formülü denedim sonuç tam
teşekkür ederim

 

[Murat OSMA]

@korhan Bey'in formülünden anladığım kadarıyla Office 365 kullananlar için çözüm üretmiş olayım;

=BAĞ_DEĞ_SAY(BENZERSİZ(FİLTRE($F$9:$F$98;($D$9:$D$98>=$J$3)*($D$9:$D$98<=$K$3)*($E$9:$E$98=H5);"")))