Küme Parantezi Kullanımı / Çoklu seçim

[walabi]

Merhaba,

Aşağıda görünen formülde küme parantezi içinde olan kriterleri belli bir hücreyi adres göstererek hücreden aldırmak mümkün müdür?

=TOPLA.ÇARPIM(($C$2:$C$30={"XXX. A.Ş.";"YYY LTD";"ZZZ ADİ ORTAKLIĞI"})*($E$2:$E$30))

 

[Korhan Ayhan]

Merhaba,

Deneyiniz.

=TOPLA.ÇARPIM(($C$2:$C$30=DEVRİK_DÖNÜŞÜM(L13:L15))*($E$2:$E$30))

 

[walabi]

=TOPLA.ÇARPIM(($C$2:$C$30={"XXX. A.Ş.";"YYY LTD";"ZZZ ADİ ORTAKLIĞI"})*($E$2:$E$30)) , sonuç 17.594.239,15

=TOPLA.ÇARPIM(($C$2:$C$30=DEVRİK_DÖNÜŞÜM(L13:L15))*($E$2:$E$30)) , sonuç 1.486.339,93

aynı sonucu vermedi Korhan bey,

 

[Korhan Ayhan]

Bendeki sonuç bu şekilde..

Siz bir de DEVRİK_DÖNÜŞÜM fonksiyonunu kaldırarak deneyiniz.

 

[walabi]

Bende sadece 2. Kriterin verisini baz alıyor anladığım kadarı ile. İngilizce - Türkçe den kaynaklanan bir farklılık olabilir mi?.

1. ve 3. kriterler değişiklik yaptığımda sonuç tutarda değişiklik olmuyor. Sadece 2. kriterde değişiklik olursa sonuç tutarda değişim oluyor.

 

[Korhan Ayhan]

Aşağıdaki gibi deneyiniz.

=TOPLA.ÇARPIM(($C$2:$C$30=L13:L15)*($E$2:$E$30))

 

[walabi]

Aşağıdaki gibi deneyiniz.

=TOPLA.ÇARPIM(($C$2:$C$30=L13:L15)*($E$2:$E$30))

Bunu denedim. #YOK hatası veriyor.

 

[Korhan Ayhan]

Birde ilk önerdiğim formülü DİZİ formülü olarak deneyiniz.

 

[walabi]

Birde ilk önerdiğim formülü DİZİ formülü olarak deneyiniz.

Korhan bey tüm önerilerinizi denedim. Hem şahsi hem iş bilgisayarında. Ama sonuçlar aynı bende. Sizin ulaştığınız sonuçlara ulaşamadım. Excelin versiyon farkından kaynaklı birşey olabilir mi?

 

[Korhan Ayhan]

Ben Ofis 365 sürümünde deniyorum. Versiyondan dolayı farklılık olabilir.

Görselde 3 alternatifin sonuçlarını görebilirsiniz. 3. alternatifi deneyebilirsiniz.

 

[walabi]

Bu formül aradığım sonucu veriyor. Teşekkürler Korhan bey,

=TOPLA.ÇARPIM(ESAYIYSA(KAÇINCI($C$2:$C$30;M13:M15;0))*$E$2:$E$30)

 

[walabi]

Merhaba, konular benzer olduğu için farklı bir konu açmak istemedim.

=TOPLA.ÇARPIM(ESAYIYSA(KAÇINCI($C$2:$C$30;I2:I5;0))*ESAYIYSA(KAÇINCI($D$2:$D$30;J2:J4;0))*ESAYIYSA(KAÇINCI($A$2:$A$30;K2;0))*($E$2:$E$30))

>>> ESAYIYSA(KAÇINCI($A$2:$A$30;K2;0)) Bu kısımda K2 Tarih içermekte. Bunu K2:K3 aralığı şeklinde uyarlamam gerekiyor.

Formülde K2 hücresinde tekbir tarihe göre hesaplama yapılabiliyor. Ancak İlk Tarih - Son Tarih şeklinde iki tarih aralığında hesaplama yaptırcak bir formüle ihtiyaç duydum. Kaçıncı fonksiyonu içinde tarih aralığı verilebiliyor mu?

 

[Korhan Ayhan]

İki tarih aralığı için aşağıdaki gibi kurgulamanız gerekir...

ESAYIYSA(KAÇINCI($A$2:$A$30;K2;0)) bunu silin..

($A$2:$A$30>=K2)*($A$2:$A$30<=K3) bunu ekleyin.

 

[walabi]

Teşekkürler Korhan bey,

=TOPLA.ÇARPIM(ESAYIYSA(KAÇINCI($C$2:$C$30;I2:I5;0))*ESAYIYSA(KAÇINCI($D$2:$D$30;J2:J4;0))*($A$2:$A$30>=K2)*($A$2:$A$30<=K3) *($E$2:$E$30))

Birileri faydalanabilir diye örnek dosyamı ekliyorum.