Listview Şarta bağlı listeleme

[Ercan6321]

Listview de listeleme yaparken sadece belirli şartları taşıyanları listeleme yapmak istiyorum. yüklediğim dosyamda durumu 1 olanları listelemesini istiyorum. 1 olmayanlar listemde bulunmasın. Şimdiden teşekkur ederim.

 

[Korhan Ayhan]

Deneyiniz..

Private Sub UserForm_Initialize()
    Dim Son As Long, Veri As Variant, X As Long, Say As Long
   
    Son = Cells(Rows.Count, 1).End(xlUp).Row
    If Son < 3 Then Son = 3
   
    Veri = Range("A2:C" & Son).Value
   
    With UserForm1.ListView1
      .ListItems.Clear
        For X = LBound(Veri, 1) To UBound(Veri, 1)
            If Veri(X, 3) = 1 Then
                .ListItems.Add , , Veri(X, 1)
                Say = Say + 1
                With .ListItems(Say).ListSubItems
                    .Add , , Veri(X, 2)
                    .Add , , Veri(X, 3)
                End With
            End If
        Next
    End With
End Sub

 

[Ercan6321]

Kodlara bakma imkanım dün gece olmamıştı. Şimdi denedim Mükemmel çalışıyor. Elinize sağlık.

 

[Korhan Ayhan]

VERİ alan tanımlamasında küçük bir revize yaptım. Son halini deneyiniz.

 

[Ercan6321]

Suan Baya iyi oldu

 

[Ercan6321]

Merhaba Korhan Bey. Kodlar çok iyi çalışıyor.fakat revize etmem gerektiğinde örneğin adı ve soyadı C ve D sütununda olacak şartı ise yanı 1 ise o da O sütununda olacak şekilde nasıl revize ederim.

 

[Korhan Ayhan]

Excel tablonuzu aşağıdaki saatırda ifade ediyorsunuz.

Veri = Range("A2:C" & Son).Value

Bu satırı aşağıdaki gibi düzeltebilirsiniz.

Veri = Range("A2:O" & Son).Value


Şartı sorgulayan satırda If Veri(X, 3) = 1 Then

Bunuda aşağıdaki gibi düzeltebilirsiniz.

If Veri(X, 15) = 1 Then

Adı soyadı içinde aşağıdaki satırları düzeltebilirsiniz.

.Add , , Veri(X, 2)
.Add , , Veri(X, 3)

Koyu fontlu sayıları 1 artırıp deneyiniz. Bu sayı değerleri sütun indis değerleridir. Buna göre düzeltmeler yapabilirsiniz.

Yani;

1 = A sütunu
2 = B sütunu
3 = C sütunu
4 = D sütunu
5 = E sütunu
6 = F sütunu
7 = G sütunu
8 = H sütunu
9 = I sütunu
10 = J sütunu
11 = K sütunu
12 = L sütunu
13 = M sütunu
14 = N sütunu
15 = O sütunu

 

[Ercan6321]

Çok teşekkür ediyorum. Yaptığım projeye sizlerin sayesinde çok şey ekledim. Sizlerden çok şey öğrendim. Sorgusuz sualsız her soruma cevap aldım. Projem baya ilerledi. Öğrenci Yurdumuzda yaptığım projeyi 2 aydır kullanıyoruz ve geliştiriyoruz.