MAC Adresi Biçimlerini Sütunlarda Türetmek

[mdagistanli]

Merhabalar.
Birden fazla ağ tarama uygulamasından elde ettiğim MAC adreslerini aynı sütuna kopyalıyorum ve biçimleri farklı olduğu için, diğer sütunlarda her türlü yazılış biçiminde bunları toplamak istiyorum.

4 çeşit MAC adresi yazma şekli var;

B0-4E-26-61-79-DD

e0:69:95:13:77:4f

000AEB-399940

18D6C76C340A

Ben bunları, boşluklu yazma şeklini de ekleyerek 5 sütuna kopyalamak istiyorum. YERİNEKOY, MBUL fonksiyonlarıyla yapmaya çalıştım, beceremedim.

Kaynak	Tip A	Tip B	Tip C	Tip D	Tip E
B0-4E-26-61-79-DD	B04E266179DD	B0:4E:26:61:79D	B0-4E-26-61-79-DD	B04E26-6179DD	B0 4E 26 61 79 DD
e0:69:95:13:77:4f	e0699513774f	e0:69:95:13:77:4f	e0-69-95-13-77-4f	e06995-13774f	e0 69 95 13 77 4f
000AEB-399940	000AEB399940	00:0A:EB:39:99:40	00-0A-EB-39-99-40	000AEB-399940	00 0A EB 39 99 40
18D6C76C340A	18D6C76C340A	186:C7:6C:34:0A	18-D6-C7-6C-34-0A	18D6C7-6C340A	18 D6 C7 6C 34 0A

Kaynak sütununa metin yapıştıracağım, diğer sütunlar fonksiyonla, tabloda gördüğünüz biçimi alsın istiyorum.

Makrosuz olur mu?

 

[Muzaffer Ali]

Merhaba.
TipA =YERİNEKOY(A2;"-";"")
TipB =YERİNEKOY(A2;"-";":")
TipC =A2
TipD =YERİNEKOY(YERİNEKOY(A2;"-";"");SOLDAN(YERİNEKOY(A2;"-";"");6);SOLDAN(YERİNEKOY(A2;"-";"");6)&"-" )
TipE =YERİNEKOY(A2;"-";" ")

 

[DoğanD]

Merhaba,

Kaynak verinin A sütununda olduğunu varsayarak;

TipA = B2 =YERİNEKOY(YERİNEKOY(YERİNEKOY(A2;"-";"");":";"");" ";"")
TipB = C2 =PARÇAAL(B2;1;2)&":"&PARÇAAL(B2;3;2)&":"&PARÇAAL(B2;5;2)&":"&PARÇAAL(B2;7;2)&":"&PARÇAAL(B2;9;2)&":"&PARÇAAL(B2;11;2)
TipC = D2 =PARÇAAL(B2;1;2)&"-"&PARÇAAL(B2;3;2)&"-"&PARÇAAL(B2;5;2)&"-"&PARÇAAL(B2;7;2)&"-"&PARÇAAL(B2;9;2)&"-"&PARÇAAL(B2;11;2)
TipD = E2 =SOLDAN(B2;6)&"-"&SAĞDAN(B2;6)
TipE = F2 =PARÇAAL(B2;1;2)&" "&PARÇAAL(B2;3;2)&" "&PARÇAAL(B2;5;2)&" "&PARÇAAL(B2;7;2)&" "&PARÇAAL(B2;9;2)&" "&PARÇAAL(B2;11;2)

 

[hamitcan]

Sırayla kullanıp dener misiniz ?

=YERİNEKOY(A2;"-";"")
=YERİNEKOY(A2;"-";":")
=A2
=YERİNEKOY(SOLDAN(A2;8);"-";"")&"-"&YERİNEKOY(PARÇAAL(A2;10;UZUNLUK(A2));"-";"")
=YERİNEKOY(A2;"-";" ")

 

[mdagistanli]

Teşekkür ederim Muzaffer Bey ama bu olmadı çünkü A sütununda olabilecek 4 farklı şekli çevirmek için 4 parametre gerekli. @DoğanD 'nin cevabını uyguladım, istediğim tam olarak budur.

 

[mdagistanli]

Merhaba,

Kaynak verinin A sütununda olduğunu varsayarak;

TipA = B2 =YERİNEKOY(YERİNEKOY(YERİNEKOY(A2;"-";"");":";"");" ";"")
TipB = C2 =PARÇAAL(B2;1;2)&":"&PARÇAAL(B2;3;2)&":"&PARÇAAL(B2;5;2)&":"&PARÇAAL(B2;7;2)&":"&PARÇAAL(B2;9;2)&":"&PARÇAAL(B2;11;2)
TipC = D2 =PARÇAAL(B2;1;2)&"-"&PARÇAAL(B2;3;2)&"-"&PARÇAAL(B2;5;2)&"-"&PARÇAAL(B2;7;2)&"-"&PARÇAAL(B2;9;2)&"-"&PARÇAAL(B2;11;2)
TipD = E2 =SOLDAN(B2;6)&"-"&SAĞDAN(B2;6)
TipE = F2 =PARÇAAL(B2;1;2)&" "&PARÇAAL(B2;3;2)&" "&PARÇAAL(B2;5;2)&" "&PARÇAAL(B2;7;2)&" "&PARÇAAL(B2;9;2)&" "&PARÇAAL(B2;11;2)

İstediğim tam olarak budur, teşekkür ederim Doğan Bey.

 

[mdagistanli]

Sırayla kullanıp dener misiniz ?

=YERİNEKOY(A2;"-";"")
=YERİNEKOY(A2;"-";":")
=A2
=YERİNEKOY(SOLDAN(A2;8);"-";"")&"-"&YERİNEKOY(PARÇAAL(A2;10;UZUNLUK(A2));"-";"")
=YERİNEKOY(A2;"-";" ")

A sütununda sadece - veya : karakteri varsa bunlar işe yarıyor hocam.