Soru metin içinden % değer ayırma

[sirkülasyon]

Hayırlı Akşamlar diliyorum
B6 hücremde metin var ve metnin içinde 80% gibi bir değerim var
bu metnin içinde sadece 80% değerini C6 hücresine almak istiyorum.
Bu değerde ki % oranı değişken olduğu için oran değiştikçe de C6 hücresindeki oranda değişmesi lazım
Bu işlemi sağlayacak formül için rica etsem yardımcı olabilir misiniz?

 

[Korhan Ayhan]

İyi akşamlar,

B6 hücresindeki verilerde ondalıklı yüzdesel değer olma durumu var mı?

 

[sirkülasyon]

Korhan abi yüzdesel alınacak

 

[KuTuKa]

ben şöyle anladım
b6 hücresinde Performans oranı 100% tamamlandı yazısı var ise c6 da bu formül yazarsam =YERİNEKOY(PARÇAAL(B6;BUL("%";B6)-3;4);" ";"")*1 sonuca ulaşırım %100 gelir

 

[sirkülasyon]

Elerine sağlık KuTuKa teşekkür ederim

 

[Korhan Ayhan]

Peki değer 90,25% olursa ne olacak?

 

[sirkülasyon]

Korhan Abi
Ben düz mantık ile gittim. Hedef değeri almaktı. Senin gibi hiç düşünmemiştim.
Yardımcı olacağını düşünüyorum

 

[Korhan Ayhan]

B6 için örnek metin aşağıdaki gibiyse;

Performans değeri 90,25% dir.
Performans değeri %90,25 dir.

Bu formülü deneyebilirsiniz. DİZİ formüldür.

=--PARÇAAL(B6;MİN(EĞERHATA(BUL({0;1;2;3;4;5;6;7;8;9};B6);""));MAK(EĞERHATA(BUL({0;1;2;3;4;5;6;7;8;9};B6);""))-MİN(BUL({0;1;2;3;4;5;6;7;8;9};B6&"0123456789"))+1)%

Ofis 365 için;

=--REGEXEXTRACT(B6;"%?\d{1,3},\d+%?")

 

[Rulemaster]

Korhan Bey, elinize sağlık.
Office 2019 TR excelde bu formül çalışmadı. Ama Office 2021 de çalıştı.
Ne yapmam gerekir?

 

[Korhan Ayhan]

Hangi formül için bu söyleminiz.

 

[Rulemaster]

Hangi formül için bu söyleminiz.

=--PARÇAAL(B6;MİN(EĞERHATA(BUL({0;1;2;3;4;5;6;7;8;9};B6);""));MAK(EĞERHATA(BUL({0;1;2;3;4;5;6;7;8;9};B6);""))-MİN(BUL({0;1;2;3;4;5;6;7;8;9};B6&"0123456789"))+1)%

Bu formül 2019 TR excelde çalıştıramadım

 

[Korhan Ayhan]

DİZİ formül olarak uygulamanız gerekiyor.

 

[Rulemaster]

DİZİ formül olarak uygulamanız gerekiyor.

Tamamdır. Bu şekilde çalıştırabildim. Çok teşekkür ederim.

 

[sirkülasyon]

Korhhan Abi
Ellerine, emeğine sağlık. Teşekkür Ederim. Hakkını helal et

 

[Ali]

Eski versiyonlar da çalışır Alternatif

=SAYIYAÇEVİR(KIRP(SAĞDAN(YERİNEKOY(SOLDAN(B6; BUL("%"; B6)-1); " "; YİNELE(" "; 100)); 100)))/100

% olarak gözükecekse hücre Yüzde Oranı şeklinde biçimlendirilmelidir.