Metinsel,Sayısal Değer İçeren Veriden Sayıları Ayırma

[bzace]

Farklı bir alternatif;

=TOPLA(PARÇAAL(0&A1;BÜYÜK(ESAYIYSA(--PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1))
  *SATIR(DOLAYLI("1:"&UZUNLUK(A1)));SATIR(DOLAYLI("1:"&UZUNLUK(A1))))+1;1)
    *10^SATIR(DOLAYLI("1:"&UZUNLUK(A1)))/10)
[COLOR="Blue"]Formül Dizi Formülüdür.CTRL + SHİFT + ENTER ile tamamlayınız.[/COLOR]

 

[bzace]

Farklı bir alternatif;
#9 ve #16 mesajdaki uygulamara benzer bir uygulama.

Veriden sayıları ayırmak için;

=EĞER(EHATA(--PARÇAAL($A2;D$1;1));"";--PARÇAAL($A2;D$1;1))

Çıkan sayıları birleştirmek için;

=--M(D2&E2&F2&G2&H2&H2&I2&J2&K2&L2&M2&N2&O2&P2&Q2&R2&S2&T2&U2&V2&W2)

yada

=BİRLEŞTİR(D2;E2;F2;G2;H2;I2;J2;K2;L2;M2;N2;O2;P2;Q2;R2;S2;T2;U2;V2;W2)*1

İlgili dosya :BURADAN

 

[Erdem Akdemir]

alternatifim,

=TOPLA(PARÇAAL(F3;BÜYÜK(EĞER(--ESAYIYSA(--PARÇAAL(F3;SATIR(DOLAYLI("1:"&UZUNLUK(F3)));1));SATIR(DOLAYLI("1:"&UZUNLUK(F3))));SATIR(DOLAYLI("1:"&BAĞ_DEĞ_SAY(--PARÇAAL(F3;SATIR(DOLAYLI("1:"&UZUNLUK(F3)));1)))));1)*10^(SATIR(DOLAYLI("1:"&BAĞ_DEĞ_SAY(--PARÇAAL(F3;SATIR(DOLAYLI("1:"&UZUNLUK(F3)));1))))-SATIR(A1)))

 

[Murat OSMA]

Ellerinize, zihninize sağlık Erdem Bey, sayı nerede olursa olsun topluyor. :bravo: k::
Keşke metinler için de bir çözüm olsa. :dusun:

 

[Erdem Akdemir]

Murat bey teşekkür ederim, sizin gibi bir üstatdan takdir almak çok güzel birşey.

Metinler için bu kullanılabilir.

=YERİNEKOY(YERİNEKOY(YERİNEKOY(YERİNEKOY(YERİNEKOY(YERİNEKOY(YERİNEKOY(YERİNEKOY(YERİNEKOY(YERİNEKOY(A1;"0";"");"1";"");"2";"");"3";"");"4";"");"5";"");"6";"");"7";"");"8";"");"9";"")

 

[Murat OSMA]

Estağfurullah.
Tabir-i caizse boynuz kulağı geçer derler.

YERİNEKOY fonksiyonu ile basitçe yapılabilir evet onu biliyorum ama Dizi formülü içerisinde Metinleri ayırma nasıl olabilir onu bilmiyorum. Belki de mümkün değil. :dusun:

 

[Erdem Akdemir]

Estağfurullah.
Tabir-i caizse boynuz kulağı geçer derler.

YERİNEKOY fonksiyonu ile basitçe yapılabilir evet onu biliyorum ama Dizi formülü içerisinde Metinleri ayırma nasıl olabilir onu bilmiyorum. Belki de mümkün değil. :dusun:

Formüldeki dizileri malesef birleştiremiyoruz, bu konuda araştırma yapmıştım.

 

[Murat OSMA]

Bir gün çözümünü bulduğunuzda paylaşırsanız sevinirim.

Bu yüzden makroyu seviyorum.

 

[bzace]

Merhabalar,
Sadece sağ yada solda sayılar olduğu durumlarda kullanılabilir.Veri kümesi içerisinde karışık durumlar olduğunda çalışmayacaktır.

Diğer husus için üzerinde araştırma yapmak gerekir.

=KIRP(SOLDAN(A1;MİN(BUL({1\2\3\4\5\6\7\8\9\0};A1&1234567890)-1)))

Not: Metinsel değerleri almak için kullanılır.