PDF'ten Sayfa Yazdırma

[Astalavista58]

Öncelikle herkese merhaba,

Excel dosyamda A1 hücresinde yazan değer (111) PDF dosyamın ismi, B1 hücresinde yazan değer (10) ise PDF dosyamdaki sayfa numarası.
Örneğin, makroya tıkladığımda "111.pdf" isimli dosyanın, 10. Sayfadan 2 adet çıktı alsın istiyorum. Nasıl yapılabilir

 

[Korhan Ayhan]

Merhaba,

Sisteminizde ADOBE yüklü mü?

 

[Astalavista58]

Doğrudur yüklü

 

[Astalavista58]

ADOBE Reader DC yüklü

 

[Korhan Ayhan]

Yazdırma işlemi sadece A1-B1 hücreleri için mi geçerli olacak?

 

[Astalavista58]

Verilerimi düşeyara ile A1 ve B1 hücresine çektiriyorum onlar sabit kalıyor

 

[Korhan Ayhan]

Aşağıdaki kodu boş bir modüle uygulayınız.

Kodun çalışması için VBA editöründe REFERENCES menüsünden aşağıdaki isimdeki kütüphane aktif hale getirilmelidir.

• Adobe Acrobat XX.X Type Library

Ek olarak A1 hücresinde PDF dosyası yolu ile beraber yazılmalıdır. Örnek ; C:\Belgelerim\PDF Dosyaları\111.pdf

Option Explicit

Sub PDF_Dosya_Yazdir()
    Print_PDF Range("A1").Value, Range("B1").Value, Range("B1").Value
    Print_PDF Range("A1").Value, Range("B1").Value, Range("B1").Value
End Sub

Public Sub Print_PDF(Dosya_Adi As String, Baslangic_Sayfa_No As Integer, Bitis_Sayfa_No As Integer)
    Dim AcroApp As AcroApp
    Dim AcroAVDoc As AcroAVDoc
    Dim AcroPDDoc As AcroPDDoc
    
    Set AcroApp = CreateObject("AcroExch.App")
    Set AcroAVDoc = CreateObject("AcroExch.AVDoc")
    Const PostScript_Level = 2
    
    If AcroAVDoc.Open(Dosya_Adi, vbNull) <> True Then
        Exit Sub
    End If
    
    Set AcroAVDoc = AcroApp.GetActiveDoc
    Set AcroPDDoc = AcroAVDoc.GetPDDoc
    
    AcroAVDoc.PrintPages Baslangic_Sayfa_No - 1, Bitis_Sayfa_No - 1, PostScript_Level, True, False
    AcroAVDoc.Close True
    AcroApp.Exit
    
    Set AcroAVDoc = Nothing
    Set AcroPDDoc = Nothing
    Set AcroApp = Nothing
End Sub

 

[Astalavista58]

Dediğiniz gibi VBA editöründe Tools>References sekmesinden, Adobe Acrobat Browser Control Type Libary ve Adobe Reader File Prewiew Type Libary sekmelerinin tiklerini aktif ettim. Execelimde A1 hücresine PDF'in bulunduğu konumu yazdım, b1 sütununa çıktı almak istediğim sayfa sayısını yazıp kodu çalıştırmaya çalıştığımda;
"Compile error:
User defined type not defined" şeklinde hata verip, "
Public Sub Print_PDF(Dosya_Adi As String, Baslangic_Sayfa_No As Integer, Bitis_Sayfa_No As Integer)" bu kod sarı renk ile yandı. Acaba nerde hata yapıyorum

 

[Korhan Ayhan]

Kodu netten buldum ve biraz düzenleyip paylaştım. Bende ADOBE yüklü olmadığı için deneme şansım olmadı.

Kodun çalışması için görselde ki gibi bir referans olması gerekiyor.

 

[Astalavista58]

Resimdeki tüm tikleri seçenekleri bende işaretledim, sadece bende "Adobe Acrobat 10.0 Type Libary" yok, onun yerine "Adobe Acrobat Browser Control Type Libary" ve "Adobe Reader File Prewiew Type Libary 1.0" seçenekleri var. İki seçeneği de ayrı ayrı ve ikisi aynı anda olacak şekilde seçtim ancak yine aynı hatayı verdi.

 

[Korhan Ayhan]

O referansın olması için ADOBE ACROBAT yüklemeniz gerekebilir.

 

[Astalavista58]

Acrobat problemini çözdüm bu sefer başka hata verdi, bu iş olacak gibi değil, ilgi alakanız için çok teşekkür ederim Korhan bey

 

[Korhan Ayhan]

Hemen pes etmeyin...

Nerede hata veriyor?

 

[Astalavista58]

Bu şekilde hata veriyor tamam dediğimde "Public Sub Print_PDF(Dosya_Adi As String, Baslangic_Sayfa_No As Integer, Bitis_Sayfa_No As Integer)" sarı yanıp, "Set AcroDoc = Nothing" kodunda ise "AcroDoc" seçili kalıyor

 

[Korhan Ayhan]

O kısmı ben düzenlerken hatalı bırakmışım.

#7 nolu mesajımı revize ettim. Tekrar deneyiniz.

 

[Astalavista58]

Korhan hocam, Run-Time error "429" ActiveX compeant cant create object hatası verdi, debuga bastığımda; "Set AcroApp = CreateObject("AcroExch.App")" kodunu sarıya boyuyor

 

[Korhan Ayhan]

Peki sisteminize ADOBE ACROBAT kurdunuz mu?

 

[Astalavista58]

Korhan hocami çok teşekkür ederim, kod çalıştı, Adobe Acrobat'ı yeniden yükledim. Tekrardan çok teşekkür ederim

 

[Korhan Ayhan]

Ek olarak bende çalışmama durumuna karşı SendKeys metodu ile aşağıdaki şekilde sonuca gidebildim.

Aşağıdaki kodlama Foxit Reader 8.2.0.2051 versiyon ile denenmiştir ve olumlu sonuç alınmıştır. Sisteme göre tuş basışları değişkenlik gösterebilir. Bu sebeple uyarlama yapmak gerekebilir.

Option Explicit

Sub PDF_Yazdir()
    Dim Adet As Variant
   
    If Range("A1").Value = "" Then
        MsgBox "Lütfen PDF dosyasının adını giriniz!", vbCritical
        Range("A1").Select
        Exit Sub
    End If

    If Range("B1").Value = "" Then
        MsgBox "Lütfen yazdırmak istediğiniz sayfanın numarasını giriniz!", vbCritical
        Range("B1").Select
        Exit Sub
    End If

    Adet = InputBox("Çıktı sayısını giriniz...", "ÇIKTI ADEDİ", 2)
   
    If Adet = "" Then
        MsgBox "Yazdırma işlemi iptal edilmiştir.", vbExclamation
        Exit Sub
    End If
   
    If Not IsNumeric(Adet) Or Adet <= 0 Then
        MsgBox "Lütfen sıfırdan büyük sayısal bir değer giriniz!", vbCritical
        Exit Sub
    End If
   
    CreateObject("Shell.Application").Open "C:\Users\Downloads\Sayfa1.pdf"
    Application.Wait Now + TimeSerial(0, 0, 3)
    SendKeys "^p", True
    SendKeys "{Tab 2}", True
    SendKeys Adet, True
    SendKeys "{Tab 4}", True
    SendKeys "{Down 1}", True
    SendKeys "{Tab 1}", True
    SendKeys Range("B1").Value & "-" & Range("B1").Value, True
    SendKeys "{Tab 10}", True
    Application.Wait Now + TimeSerial(0, 0, 3)
    SendKeys "{Enter}", True
    Application.Wait Now + TimeSerial(0, 0, 3)
    SendKeys "%{F4}", True
End Sub

 

[Astalavista58]

Korhan hocam Allah sizden razı olsun, Key ile vermiş olduğunu formül PDF açıp, yazdırma ekranına kadar açıp yazıcı seçme yerinde, yazıcı olmadığından kafası karışıyor. Yarın sabah büroda yazıcılı bilgisayardan gerekli tuş ayarlamalarını yapıp deneyeceğim. O kadar işimi kolaylaştırdınız ki size ne kadar dua etsem azdır. Tekrardan çok çok teşekkür ederim.